Die Erfassung und die Ausgabe von STDOUT an der gleichen Zeit

Ich habe den folgenden code zu erfassen und zu verarbeiten, den Run-Befehl ausgegeben.
Wie kann ich es ändern, so dass der Befehl "Ausführen" - Fenster zeigt output und gleichzeitig die Ausgabe wird protokolliert? Ersetzen @SW_HIDE mit @SW_SHOW (oder gleichwertig) zeigt nur ein leeres Befehlsfenster.

Etwas ähnliches wie die linux tee Befehl, die logs auf Datei, während es druckt die Ausgabe auf STDOUT.

$CurrentPID = Run(@ComSpec & ' /c ' & $CurrentLogCmd, "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

If Not ProcessWaitClose($CurrentPID,60) Then
    WriteLog("[Warning] Timed-out.Finding date in current hour raw log -" & $CurrentLogFileName)
    $F_LogWarningExist = 1
    Return $C_SUCCESS ; Take chances and proceed with parsing raw logs
EndIf

$CurrentOutput = StdoutRead($CurrentPID)
InformationsquelleAutor Siva | 2013-05-09
  1. 4
    ConsoleWrite(_getDOSOutput('ipconfig /all') & @CRLF)

Func _getDOSOutput($command)
    Local $text = '', $Pid = Run('"' & @ComSpec & '" /c ' & $command, '', @SW_HIDE, 2 + 4)
    While 1
            $text &= StdoutRead($Pid, False, False)
            If @error Then ExitLoop
            Sleep(10)
    WEnd
    Return StringStripWS($text, 7)
EndFunc   ;==>_getDOSOutput

    Vielleicht hilft Sie aus.

    • Ich brauche den text, der gedruckt werden, die auf die Fenster in addtion zu Umleitung... kann ich beides gleichzeitig möglich?
    • Was meinst du damit?
    • Ich will den text, der gedruckt werden auf dem Bildschirm als auch umgeleitet, so dass autoit kann Lesen und analysieren. im Grunde, wenn ich auf dem monitor ich möchte sehen, was passiert sofort (mit Skripts Fortschritt) anstatt zu warten, die am Ende für die autoit einen Fehler auslösen, wenn überhaupt!
    InformationsquelleAutor Xenobiologist
  2. 1

    Etwas ähnliches wie die linux tee Befehl, die logs auf Datei, während es druckt die Ausgabe auf STDOUT.

    Umleiten von STDOUT macht die empfangende Partei (das Skript) verantwortlich für die Anzeige und Protokollierung. Als pro Dokumentation:

    StdoutRead() nicht blockiert, es wird sofort zurück. Um alle Daten, es muss in einer Schleife aufgerufen.

    Beispiel:

    #AutoIt3Wrapper_Change2CUI=Y

#include <Constants.au3>
#include <MsgBoxConstants.au3>

Global Enum  $EXIT_OK, _
             $EXIT_NOCOMPILE, _
             $EXIT_ABORT

Global Const $g_sPromptError  = 'Compile this script and run resulting executable instead.', _
             $g_sPromptInput  = 'Enter a command:', _
             $g_sInputDefault = 'ping localhost -n 10'

Global       $g_sCMD = '', _
             $g_sSTD = ''

Main()

Func Main()

    If Not @Compiled Then

        MsgBox($MB_OK + $MB_ICONERROR, @ScriptName, $g_sPromptError)
        Exit $EXIT_NOCOMPILE

    EndIf

    $g_sCMD = InputBox(@ScriptName, $g_sPromptInput, $g_sInputDefault)
    If @error Then Exit $EXIT_ABORT

    $g_sSTD = _getCmdStd($g_sCMD)
    MsgBox($MB_OK + $MB_ICONINFORMATION, $g_sCMD, $g_sSTD)

    Exit $EXIT_OK
EndFunc

Func _getCmdStd(Const $sCMD, Const $sDir = '', Const $iType = $STDERR_MERGED, Const $bShow = False, Const $iDelay = 100)
    Local       $sTMP = ''
    Local       $sSTD = ''
    Local       $sCOM = @ComSpec & ' /c ' & $sCMD
    Local Const $iWin = $bShow ? @SW_SHOW : @SW_HIDE
    Local Const $iPID = Run($sCOM, $sDir, $iWin, $iType)

    While True

        $sTMP = StdoutRead($iPID, False, False)

        If @error Then

            ExitLoop 1

        ElseIf $sTMP Then

            $sTMP  = StringReplace($sTMP, @CR & @CR, '')
            $sSTD &= $sTMP

            ConsoleWrite($sTMP)

        EndIf

        Sleep($iDelay)

    WEnd

    Return SetError(@error, @extended, $sSTD)
EndFunc

    Rückgabe von STDOUT (und STDERR) nach Ausführung abgeschlossen ist, während das schreiben auf die Konsole während Ausführung. Ersetzen MsgBox() als erforderlich (logging-Funktion).

    InformationsquelleAutor user4157124
Schreibe einen Kommentar