Einfügen von text in der Hintergrundfarbe einer Zelle

Ich bin auf der Suche nach einer Möglichkeit zum einfügen von text in den hintergrund einer Zelle, so dass ich die noch zahlen eingeben auf der Oberseite des Textes - ähnlich wie ein Wasserzeichen, außer für eine einzelne Zelle. Alle Möglichkeiten, dies zu tun, vorzugsweise ohne Verwendung eines Makros (aber offen für diese Lösungen auch)?

InformationsquelleAutor Scott Jones | 2013-08-12

7
- Wählen Sie die Zelle aus, wo Sie wollen, um den Hintergrund.
- Klicken Sie auf "Einfügen" und legen Sie eine rechteckige Form haben, in diesem Ort.
- Der rechten Maustaste auf die Form - wählen Sie "Format Shape"
- Gehe zu "Füllen" und wählen Sie "Bild oder textur füllen"
- Goto "Einfügen aus Datei" - option
- Wählen Sie das Bild, das Sie wollen, um Wasser-mark
- Bild erscheint an der Stelle der rechteckigen Form
- Klicken Sie nun auf das Bild "Rechte Maustaste" und wählen Sie Format Picture
- Gehe zu "Füllen" und die Transparenz erhöhen, wie erforderlich, um es so Aussehen wie ein "Water-Mark" oder Licht beckground
- Diese erhalten ebenfalls abgedruckt.
hier
- +1 ich habe mich immer gefragt, warum jemand wollen, um ein Bild in den hintergrund einer Zelle. Clever. ...eigentlich ist es nur eine etwas transparenter Form auf der Oberseite der Zelle rechts? Machen nicht, dass die Auswahl der Zelle irgendwie einen Schmerz, obwohl?
- Dies ist ideal für Bilder - gibt es eine Möglichkeit die Eingabe von text als hintergrund?
InformationsquelleAutor Andrew

Ähnlich Andrews post, das ist die VBA version, welche Formate der Form korrekt und erlaubt auch die direkte Auswahl von Zellen.

Einfügen von text in der Hintergrundfarbe einer Zelle

Code-MODUL:

Sub watermarkShape()
Const watermark As String = "watermark"
Dim cll As Range
Dim rng As Range
Dim ws As Worksheet
Dim shp As Shape

    Set ws = Sheet1
    Set rng = ws.Range("A1:F10") 'Set range to fill with watermark

    Application.ScreenUpdating = False

    For Each shp In ws.Shapes
        shp.Delete
    Next shp

    For Each cll In rng

        Set shp = ws.Shapes.AddShape(msoShapeRectangle, 5, 5, 5, 5)

        With shp
            .Left = cll.Left
            .Top = cll.Top
            .Height = cll.Height
            .Width = cll.Width

            .Name = cll.address
            .TextFrame2.TextRange.Characters.Text = watermark
            .TextFrame2.TextRange.Font.Name = "Tahoma"
            .TextFrame2.TextRange.Font.Size = 8
            .TextFrame2.VerticalAnchor = msoAnchorMiddle
            .TextFrame2.TextRange.ParagraphFormat.Alignment = msoAlignCenter
            .TextFrame2.WordWrap = msoFalse
            .TextFrame.Characters.Font.ColorIndex = 15
            .TextFrame2.TextRange.Font.Fill.Transparency = 0.35

            .Line.Visible = msoFalse
'            Debug.Print "'SelectCell (""" & ws.Name & """,""" & cll.address & """)'"
            .OnAction = "'SelectCell """ & ws.Name & """,""" & cll.address & """'"

            With .Fill
                .Visible = msoTrue
                .ForeColor.ObjectThemeColor = msoThemeColorBackground1
                .Transparency = 1
                .Solid
            End With

        End With


    Next cll

    Application.ScreenUpdating = True
End Sub

Sub SelectCell(ws, address)
    Worksheets(ws).Range(address).Select
End Sub

UPDATE:

Beispiel unten weist ein Wasserzeichen von die Adresse der Zelle ungerade Zeilen und verlässt den geraden Zeilen als die ständige watermark. Dies ist ein stehen im Beispiel, basierend auf meinen Kommentar, dass jede Zelle zugeordnet werden können alle Wasserzeichen-text, basierend auf was auch immer Rechte, die Sie wollen.

Einfügen von text in der Hintergrundfarbe einer Zelle

Option Explicit

Sub watermarkShape()
Const watermark As String = "watermark"
Dim cll As Range
Dim rng As Range
Dim ws As Worksheet
Dim shp As Shape

    Set ws = Sheet1
    Set rng = ws.Range("A1:F10") 'Set range to fill with watermark

    Application.ScreenUpdating = False

    For Each shp In ws.Shapes
        shp.Delete
    Next shp

    For Each cll In rng

        Set shp = ws.Shapes.AddShape(msoShapeRectangle, 5, 5, 5, 5)

        With shp
            .Left = cll.Left
            .Top = cll.Top
            .Height = cll.Height
            .Width = cll.Width

            .Name = cll.address
            If cll.Row Mod 2 = 1 Then
                .TextFrame2.TextRange.Characters.Text = cll.address
            Else
                .TextFrame2.TextRange.Characters.Text = watermark
            End If
            .TextFrame2.TextRange.Font.Name = "Tahoma"
            .TextFrame2.TextRange.Font.Size = 8
            .TextFrame2.VerticalAnchor = msoAnchorMiddle
            .TextFrame2.TextRange.ParagraphFormat.Alignment = msoAlignCenter
            .TextFrame2.WordWrap = msoFalse
            .TextFrame.Characters.Font.ColorIndex = 15
            .TextFrame2.TextRange.Font.Fill.Transparency = 0.35

            .Line.Visible = msoFalse
'            Debug.Print "'SelectCell (""" & ws.Name & """,""" & cll.address & """)'"
            .OnAction = "'SelectCell """ & ws.Name & """,""" & cll.address & """'"

            With .Fill
                .Visible = msoTrue
                .ForeColor.ObjectThemeColor = msoThemeColorBackground1
                .Transparency = 1
                .Solid
            End With

        End With


    Next cll

    Application.ScreenUpdating = True
End Sub

Sub SelectCell(ws, address)
    Worksheets(ws).Range(address).Select
End Sub

Gibt es eine VBA zum anpassen der eingegebene text in den hintergrund der einzelnen Zellen? Das Endprodukt dieser sieht toll aus, ich hätte nur die Möglichkeit haben möchten, zu passen, was sagt der text für jede Zelle.
Die Linie .TextFrame2.TextRange.Characters.Text = watermark weist Konstante watermark alle Zellen. Ändern Sie einfach die Zeile .TextFrame2.TextRange.Characters.Text = "Some Text" zu, was text Sie wollen, basierend auf den Zellbereich/Adresse
+1 für die Einstellung klicken Sie auf Aktion wählen Sie die Zelle darunter.

InformationsquelleAutor user3357963

5

Können Sie ein benutzerdefiniertes Zahlenformat angeben, einen hellgrauen text, der angezeigt wird, wenn der Wert der Zelle ist 0 - Color15 macht ein schönes Wasserzeichen Farbe:
```
[Black]000000;;[Color15]"(order number)";@
```
Keine unordentlichen Formen, ist kein VBA, und das Wasserzeichen verschwindet, wenn der Wert tatsächlich gefüllt.

Und wenn Sie unbedingt brauchen, um es in VBA, dann können Sie leicht eine Funktion schreiben, baut der format-string, basierend auf einige Parameter:
```
Public Function BuildWatermarkFormat(ByVal watermarkText As String, Optional ByVal positiveFormat As String = "General", Optional ByVal negativeFormat As String = "General", Optional ByVal textFormat As String = "General") As String
    BuildWatermarkFormat = positiveFormat & ";" & negativeFormat & ";[Color15]" & Chr(34) & watermarkText & Chr(34) & ";" & textFormat
End Function
```
Und dann können Sie tun:
```
myCell.NumberFormat = BuildWatermarkFormat("Please enter a value")
myCell.Value = 0
```
Und können Sie noch benutzerdefinierte Formate für positive/negative Werte nach Ihren Bedürfnissen; die einzige Sache ist, dass 0 ist reserviert für "kein Wert" und löst das Wasserzeichen.
```
myCell.NumberFormat = BuildWatermarkFormat("Please enter a value", "[Blue]#,##0.00_)", "[Red](#,##0.00)")
myCell.Value = -25
```
- Konnte nicht das gleiche erreicht man mit einer bedingten Formatierung die Regel? Sie könnte dann noch in der Lage sein zu verwenden, benutzerdefinierte Zahlenformate, erzielen die gleiche Wirkung, und verwenden Sie eine Regel, die sucht nach leere Zellen gegenüber Zellen, die nur mit einem Wert von 0.
- Obwohl in der Praxis, ich bin mir nicht sicher, ob es eine gute Art, einschließlich text mit einer Bedingten Formatierung die Regel :).
- gut Sie konnte, indem Sie einen.... Anzahl format 😉
- Ich dachte, dass nach der Tat. Man könnte die beiden verbinden, um eine noch bessere Wirkung. Eine Regel, die für das Wasserzeichen, wenn leer, mit numberformat, und eine weitere Regel, die gilt eine andere Regel, wenn es nicht leer (zum Beispiel, ein "000000" - format).
- Ich würde gerne hören, über diese downvote.
InformationsquelleAutor Mathieu Guindon
-1

Geben Sie Ihren text in einer Zelle, irgendwo.
Kopieren Sie es und es wird gespeichert in der Zwischenablage.
Legen Sie eine rechteckige Form überall.
Mit der rechten Maustaste und wählen Sie "Send to back".
Dies wird sicherstellen, dass Sie im hintergrund.
Rechts klicken und "Form Formatieren".
Tun, um die Registerkarte "Füllen" und klicken Sie auf "Bild oder textur füllen".
Auf die "einfügen" wählen Sie "Zwischenablage".
Nun, was auch immer text, den Sie haben, in die Zwischenablage kopieren, werden in der rechteckigen Form.
Die Größe der Form zu passen, die Zelle(N), die Sie gewünscht.
Passen Sie jedoch wie zum Beispiel entfernen Sie die rechteckige Linien, Schatten hinzufügen, ändern schriftart, hintergrund entfernen etc.

InformationsquelleAutor Lee

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.