Erhaltung entity-Referenzen beim transformieren von XML mit XSLT?

Wenn Sie wissen, welche Einheiten werden verwendet und wie sind Sie definiert haben, können Sie die folgenden (ziemlich primitiv und fehleranfällig, aber immer noch besser als nichts):

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:character-map name="mapEntities">
  <xsl:output-character character="&amp;" string="&amp;"/>
 </xsl:character-map>

 <xsl:variable name="vEntities" select=
 "'stackoverflow',
 'How can I preserve the entity reference when transforming with XSLT\?\?'
 "/>

 <xsl:variable name="vReplacements" select=
 "'&amp;so;', '&amp;question;'"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:text disable-output-escaping="yes"><![CDATA[<!DOCTYPE doc [ <!ENTITY so "stackoverflow">
<!ENTITY question
"How can I preserve the entity reference when transforming with XSLT??"> ]>
]]>
  </xsl:text>

  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="text()">
  <xsl:value-of select=
  "my:multiReplace(.,
                   $vEntities,
                   $vReplacements,
                   count($vEntities)
                   )
  " disable-output-escaping="yes"/>
 </xsl:template>

 <xsl:function name="my:multiReplace">
  <xsl:param name="pText" as="xs:string"/>
  <xsl:param name="pEnts" as="xs:string*"/>
  <xsl:param name="pReps" as="xs:string*"/>
  <xsl:param name="pCount" as="xs:integer"/>

  <xsl:sequence select=
  "if($pCount > 0)
     then
      my:multiReplace(replace($pText,
                              $pEnts[1],
                              $pReps[1]
                              ),
                      subsequence($pEnts,2),
                      subsequence($pReps,2),
                      $pCount -1
                      )
      else
       $pText
  "/>
 </xsl:function>
</xsl:stylesheet>

, wenn angewandt auf das XML-Dokument:

<!DOCTYPE doc [ <!ENTITY so "stackoverflow">
<!ENTITY question
"How can I preserve the entity reference when transforming with XSLT??"> ]>
<doc>
    <text>Hello &so;!</text>
    <text>&question;</text>
</doc>

das erwartete Ergebnis produziert wird:

<!DOCTYPE doc [ <!ENTITY so "stackoverflow">
<!ENTITY question
"How can I preserve the entity reference when transforming with XSLT??"> ]>

  <doc>
      <text>Hello &so;!</text>
      <text>&question;</text>
</doc>

Tun, beachten Sie:

1. Den besonderen (RegEx) - Zeichen in den Ersetzungen, die geschützt werden müssen.

2. Mussten wir auflösen, um DOE, die nicht empfohlen wird, weil es gegen die Grundsätze der XSLT-Architektur und-Verarbeitung Modell-in anderen Worten diese Lösung ist ein ekliger hack.

Wenn Sie eine Java-Implementierung des XSLT 2.0-Prozessor (wie Saxon 9 Java), möchten Sie vielleicht zu prüfen, ob http://andrewjwelch.com/lexev/ hilft, können Sie Vorverarbeiten Ihre XML-Daten mit entity-und character-Referenzen, die Art und Weise, um Sie zu bekommen markiert als XML-Elemente können Sie dann verwandeln, wie es notwendig ist.

Sie halten können EntityReference-Knoten in die Dokument mit einem DOM-LS-parser mit "Entitäten" - parameter auf true festgelegt.
http://docs.oracle.com/javase/6/docs/api/org/w3c/dom/DOMConfiguration.html

Die Spezifikation sagt, dass der default-Wert ist true, aber je nach parser, könnte es falsch sein, bewusst sein, dass.

Laden Xerces :

DOMImplementationLS domImpl = new org.apache.xerces.dom.CoreDOMImplementationImpl();

Können Sie die Registrierung verwenden, wie unten auch, aber personnaly, würde ich eher fest die Umsetzung ich möchte wie oben:

DOMImplementationRegistry registry = DOMImplementationRegistry.newInstance();
DOMImplementationLS domImpl = (DOMImplementationLS) registry.getDOMImplementation("XML 3.0 LS 3.0"); 

Dann laden Sie Ihre Dokument :

//XML parser with XSD schema 
LSParser parser = domImpl.createLSParser(DOMImplementationLS.MODE_SYNCHRONOUS, "http://www.w3.org/2001/XMLSchema");
DOMConfiguration config = parser.getDomConfig();
config.setParameter("entities", true);
LSInput input = impl.createLSInput();
Document lDoc = parser.parse(your XML stream);

Dann Ihre XML-Entitäten, die nicht erweitert werden, in der DOM.

Dann, weil SÄCHSISCHEN behandelt nicht die Personen nicht erweitert werden ('nicht unterstützter Knotentyp in der DOM! 5' - Fehler), die Sie nicht verwenden können net.sf.saxon.xpath.XPathFactoryImpl Sie haben, um den Standard-XPathFactory von Xerces mit XPathFactory.newInstance()