ermöglichen die end-Benutzer, um eine Kontrolle

Fand ich ein gutes Beispiel Hier, aber ich habe ein paar Probleme mit ihm.
1. Es ist nicht die Platzierung der Steuerung an der richtigen position, wo Sie die Maus nach Links off becase die Kontrolle ist ein großes.

  1. Könnte es sein, schob aus dem Bildschirm.. ich will es bleiben sollte innerhalb des Schirms Grenzen.

Dies ist mein code:

   Public Sub Form1_MouseMove(ByVal sender As Object, ByVal e As MouseEventArgs) Handles MyControl.MouseMove
    If Not _capturingMoves Then
        Return
    End If
    X = e.X
    Y = e.Y
End Sub

Public Sub Form1_MouseUp(ByVal sender As Object, ByVal e As MouseEventArgs) Handles MyControl.MouseUp
    If _capturingMoves Then
        ' Do any final placement
        MyControl.Location = New Point(X, Y)
        _capturingMoves = False
    End If
End Sub
InformationsquelleAutor Ezi | 2011-04-06
  1. 6

    Schrieb ich etwas wie dies für das ziehen von divs auf einer Webseite...

    Der Allgemeine Ansatz wurde zum speichern der Koordinaten auf mousedown, Holen Sie sich die Koordinaten auf, mouseup-und-shift die Position des Objekts durch den Unterschied.

    Hier einige Beispiel-code:

    Machte ich einen DragInfo Klasse hält, dass die erste Maus coords und ersten Standort. Ich habe dann speichern einer von diesen Jungs in der Steuerung Tag auf das mousedown-Ereignis:

    Public Class DragInfo
    Public Property InitialMouseCoords As Point
    Public Property InitialLocation As Point

    Public Sub New(ByVal MouseCoords As Point, ByVal Location As Point)
        InitialMouseCoords = MouseCoords
        InitialLocation = Location
    End Sub

    Public Function NewLocation(ByVal MouseCoords As Point) As Point
        Dim loc As New Point(InitialLocation.X + (MouseCoords.X - InitialMouseCoords.X), InitialLocation.Y + (MouseCoords.Y - InitialMouseCoords.Y))
        Return loc
    End Function
End Class

    Meinem test-Kontrolle wird nur ein panel, dass ich aus der toolbox. Es könnte alles sein, denke ich. Hier sind meine mousedown, mousemove und mouseup-event-Handler für das panel (Panel1):

    Private Sub Panel1_MouseDown(sender As System.Object, e As System.Windows.Forms.MouseEventArgs) Handles Panel1.MouseDown
    Panel1.Tag = New DragInfo(Form.MousePosition, Panel1.Location)
End Sub

Private Sub Panel1_MouseMove(sender As System.Object, e As System.Windows.Forms.MouseEventArgs) Handles Panel1.MouseMove
    If Panel1.Tag IsNot Nothing Then
        Dim info As DragInfo = CType(Panel1.Tag, DragInfo)
        Dim newLoc As Point = info.NewLocation(Form.MousePosition)
        If Me.ClientRectangle.Contains(New Rectangle(newLoc, Panel1.Size)) Then Panel1.Location = newLoc
    End If
End Sub

Private Sub Panel1_MouseUp(sender As System.Object, e As System.Windows.Forms.MouseEventArgs) Handles Panel1.MouseUp
    Panel1.Tag = Nothing
End Sub

    Dort gehen Sie! Das funktioniert. Beachten Sie, dass die mousemove-Methode überprüft, ob das Steuerelement im Formular ist, clientrectangle.

    Oder einen allgemeineren Weg zu gehen:

    Private Sub MakeDraggable(ByVal Control As Control)
    AddHandler Control.MouseDown, Sub(sender As Object, e As MouseEventArgs) StartDrag(Control)
    AddHandler Control.MouseMove, Sub(sender As Object, e As MouseEventArgs) Drag(Control)
    AddHandler Control.MouseUp, Sub(sender As Object, e As MouseEventArgs) StopDrag(Control)
End Sub
Private Sub StartDrag(ByVal Control As Control)
    Control.Tag = New DragInfo(Form.MousePosition, Control.Location)
End Sub
Private Sub Drag(ByVal Control As Control)
    If Control.Tag IsNot Nothing AndAlso TypeOf Control.Tag Is DragInfo Then
        Dim info As DragInfo = CType(Control.Tag, DragInfo)
        Dim newLoc As Point = info.NewLocation(Form.MousePosition)
        If Me.ClientRectangle.Contains(New Rectangle(newLoc, Control.Size)) Then Control.Location = newLoc
    End If
End Sub
Private Sub StopDrag(ByVal Control As Control)
    Control.Tag = Nothing
End Sub

    Jetzt können Sie nur verwenden MakeDraggable(Panel1) oder irgendeiner anderen-Kontrolle zu machen, ziehbar!

    Edit: Beide Beispiele jetzt halten Sie das Steuerelement gezogen wird out-of-bounds.

    • Vielen Dank ich würde mich freuen, wenn du in der Lage bist, mich mit dieser Probe.
    • Ich erkannte, dass die Kontrolle in-bounds war Ihr Prinzip in Frage. Ich befestigte den Beispielen zu tun. Ich überprüfen, dass die Steuerung innerhalb des Formulars clientrectangle.
    • Es funktioniert tatsächlich Super!!! vielen Dank
    • Kein problem. Ich bin froh, dass ich helfen konnte!
    InformationsquelleAutor Brian Mulcahy
Schreibe einen Kommentar