Excel 2007 Filtern über mehrere Pivot-Tabellen

In Excel 2007, habe ich einen einzelnen Datensatz in form einer Excel-Tabelle, aus der ich das machen will mehrere pivot-Tabellen und pivot-charts. Ich möchte in der Lage sein, zu synchronisieren "report filter" - Feld über alle pivot-Tabellen und Diagramme gleichzeitig, so dass durch die Filterung, die (zum Beispiel) die US_Region Feld "Pacific Northwest" auf eines der pivot-Tabellen anwenden würde, dass die filter, um alle pivot-Tabellen und Diagramme in der Arbeitsmappe (die teilen sich ein einzelnes dataset). Gibt es eine Möglichkeit, dies ohne VBA und wenn nicht, was wäre die flexibelste/zuletzt klugy Weg, es zu tun in VBA?

Dank

InformationsquelleAutor John Sullivan | 2009-09-14

  1. 2

    Erstellen Sie eine Prozedur so ändern Sie alle Felder, Seite. Diese eine Schleife durch alle Arbeitsblätter in der Arbeitsmappe aus, und wenn das Arbeitsblatt eine pivot-Tabelle, ändert es die Seite Feld, mit dem page-Feld auf der pivot-Tabelle übergeben wird, um den sub.

    Sub ChangePage(pt As PivotTable)

    Dim strPageValue As String
    Dim wks As Worksheet
    Dim ptUpdate As PivotTable

    Application.ScreenUpdating = False
    Application.EnableEvents = False

    strPageValue = pt.PivotFields("Area").CurrentPage

    For Each wks In ThisWorkbook.Worksheets

        On Error Resume Next
        Set ptUpdate = wks.PivotTables(1)

        If Err.Number = 0 Then
            On Error GoTo 0
            wks.PivotTables(1).PivotFields("Area").ClearAllFilters
            wks.PivotTables(1).PivotFields("Area").CurrentPage = strPageValue
        End If
        Err.Clear

    Next wks

    Application.ScreenUpdating = True
    Application.EnableEvents = True

End Sub

    Dann einen Anruf zu diesem Verfahren im Arbeitsblatt code selbst, und übergeben Sie die pivot-Tabelle, die Sie geändert:

    Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)

    Call ChangePage(Target)

End Sub

    Ändern Sie den Namen der pivot-Feld vom "Bereich" der Seite ein Feld, das Sie benötigen, zum Beispiel "US_Region".

    Diese dürfen nicht geeignet sein, wenn die Menschen sich Häufig ändern die Struktur Ihrer pivot-Tabellen in anderer Weise, als es löst jedes mal die pivot-Tabelle wird verändert, auch wenn es aktualisiert wird. Es gibt auch einen Fehler, wenn Benutzer entfernen Sie das angegebene Feld Seite.

    Wenn die pivot-Tabellen statisch sind, obwohl, kann dies tun.

    InformationsquelleAutor dendarii

Schreibe einen Kommentar