Excel 2013 makro, um nur bestimmte Zeilen basiert auf eine Zelle-Wert

Aufrufe für die Excel-Objekt-Modell verlangsamt die Dinge wesentlich, so ist es wahrscheinlich am besten, zu laden, die Werte, die Sie überprüfen möchten in ein dictionary oder array, und verweisen, statt. Sie könnten auch laden Sie die Nummer der Zeile und den Wert der Zeilen, die Sie prüfen, in einem anderen Wörterbuch und cross-Referenz-die zwei Daten-Strukturen während der Herstellung beachten der Zeilen, die Sie brauchen, um sich zu verstecken. Auf diese Weise arbeiten nehmen einiges an Speicher, aber wird auf jeden Fall schneller als die cross-Referenzierung Blätter direkt...

hth

InformationsquelleAutor Pat Mustard

Der folgende code nimmt einen etwas anderen Ansatz zu deinem problem. Bitte beachten Sie, daß es wird davon ausgegangen, dass Tabelle1 Werte in Spalte A plus eine unbestimmte Anzahl von Datenspalten und, Tabelle2 ist nur ein Satz von Werten in Spalte A, gegen die der Tabelle1 in Spalte A Werte sind aufeinander abgestimmt.

Der code macht Folgendes:

• Schafft die match-Werte in der Spalte rechts von der letzten Spalte in Arbeitsblatt 1 (1 = keine übereinstimmung, 0 = übereinstimmung)
• Setzt einen autofilter auf dem Blatt 1 Daten-Bereich, mit einem Kriterium den Wert 1 in der Spalte "match" (D. H., filter und zeigt nur die nicht-übereinstimmungen)
• Weist die gefilterten Zeilen in eine range-variable
• Entfernt den filter und löscht die Spalte "match"
• Versteckt in der Masse der Zeilen identifiziert, die in den Bereich variable

Getestet habe ich die Prozedur mit einem Tabelle1 Datenbestand von 300.000 Zeilen code die Werte in Spalte A und zufälligen numerischen Daten in den Spalten B und C, mit knapp über 1.000 match-Werte in Tabelle2. Die zufällig generierten 10-stelligen code und die match-Werte wurden so konstruiert, dass 20 Prozent der Tabelle1 in Spalte A Werte wurden nicht-übereinstimmungen.

Laufzeiten gegen diese Daten gemittelt unter zwei Minuten.

Sub MatchFilterAndHide2()

    Dim calc As Variant
    Dim ws1 As Worksheet, ws2 As Worksheet
    Dim ws1Name As String, ws2Name As String
    Dim rng1 As Range, rng2 As Range
    Dim hideRng As Range
    Dim lastRow1 As Long, lastRow2 As Long
    Dim lastCol1 As Long

    Application.ScreenUpdating = False
    calc = Application.Calculation
    Application.Calculation = xlCalculationManual

    ws1Name = "Sheet1"
    Set ws1 = Worksheets(ws1Name)
    With ws1
        lastRow1 = .Range("A" & .Rows.Count).End(xlUp).Row
        lastCol1 = .Cells(1, ws1.Columns.Count).End(xlToLeft).Column + 1
        Set rng1 = .Range(.Cells(1, 1), .Cells(lastRow1, lastCol1))
    End With

    ws2Name = "Sheet2"
    Set ws2 = Worksheets(ws2Name)
    With ws2
        lastRow2 = .Range("A" & .Rows.Count).End(xlUp).Row
        Set rng2 = .Range("A2:A" & lastRow2)
    End With

    'add column of match values one column to the right of last data column
    '1 = no-match, 0 = match
    With ws1.Range(ws1.Cells(2, lastCol1), ws1.Cells(lastRow1, lastCol1))
        .FormulaArray = "=N(ISNA(MATCH(" & ws1Name & "!" & rng1.Address & _
            "," & ws2Name & "!" & rng2.Address & ",0)))"
        .Value = .Value
    End With

    'set autofilter on rng1 and filter to show the no-matches
    With ws1.Range(ws1.Cells(1, 1), ws1.Cells(1, lastCol1))
        .AutoFilter
        .AutoFilter field:=lastCol1, Criteria1:=1
    End With

    With ws1
        'assign no-matches to range object
        Set hideRng = .Range("A2:A" & lastRow1).SpecialCells(xlCellTypeVisible)

        'turn off autofilter, clear match column, and hide no-matches
        .AutoFilterMode = False
        .Cells(1, lastCol1).EntireColumn.Clear
        hideRng.EntireRow.Hidden = True
        .Cells(1, 1).Select
    End With

    Application.Calculation = calc
    Application.ScreenUpdating = True
End Sub

InformationsquelleAutor chuff