Excel. Erstellen von Diagrammen in verschiedenen Blättern

Brauche ich, um zu erstellen ein Diagramm pro Blatt in Excel. Hier ist mein code:

    Sheets(i).Activate

    For Each cht In ActiveSheet.ChartObjects
        cht.Delete
    Next

    'create chart
    Set chtChart = ActiveSheet.ChartObjects.Add(Left:=75, Width:=300, Top:=75, Height:=300).Chart
    With chtChart
        .ChartType = xlXYScatterSmooth

        Do While .SeriesCollection.Count <> 0
            Do Until .SeriesCollection.Count = 0
                .SeriesCollection(1).Delete
            Loop
        Loop

        Set srsNew = .SeriesCollection.NewSeries
        With srsNew
            .XValues = "='" & Sheets(i).Name & "'!" & _
            Sheets(i).Range(Range("K2"), Range("k2").End(xlDown)).Address
            .Values = "='" & Sheets(i).Name & "'!" & _
            Sheets(i).Range(Range("l2"), Range("l2").End(xlDown)).Address
        End With
    End With

Für das erste Blatt funktioniert es, aber für die zweite, Dritte ... tut es aber nicht. Es gibt die Fehlermeldung 1004 "Anwendungs-oder objektdefinierter Fehler" in XValues oder Werte. Mir ist auch aufgefallen, dass wenn ich vorstellen

range("K2")

außerhalb der with-block bekomme ich einen Fehler in der zweiten, Dritten .... Bettwäsche, aber nicht in der ersten.

Jede raten, ist willkommen

Hinsichtlich

João

InformationsquelleAutor jpcgandre | 2012-04-17
  1. 4
    1. Qualifizieren Sie Ihre Ranges mit den Blättern, dem Sie gehören.
    2. Nicht verwenden Select oder ActiveSheet.
    3. Nicht aufzubauen die Adresse des Strings. Verwenden Sie reicht direkt.
    Dim CurSheet As Worksheet, cht As ChartObject
Dim chtChart As Chart, srsNew As Series

...

Set CurSheet = Worksheets(i)

For Each cht In CurSheet.ChartObjects
  cht.Delete
Next


'create chart
Set chtChart = CurSheet.ChartObjects.Add(Left:=75, Width:=300, Top:=75, Height:=300).Chart
With chtChart
  .ChartType = xlXYScatterSmooth

  Do While .SeriesCollection.Count <> 0
    .SeriesCollection(1).Delete
  Loop

  Set srsNew = .SeriesCollection.NewSeries
  With srsNew
    .XValues = CurSheet.Range(CurSheet.Range("k2"), CurSheet.Range("k2").End(xlDown))
    .Values = CurSheet.Range(CurSheet.Range("l2"), CurSheet.Range("l2").End(xlDown))
  End With
End With
    • Danke! Sehr schöne Tipps!
    InformationsquelleAutor GSerg
  2. 1

    Vielleicht würde es helfen, wenn Sie vollständig qualifiziert diese Bereiche wie diese: 

    With srsNew
    .XValues = "='" & Sheets(i).Name & "'!" & _
    Sheets(i).Range(Sheets(i).Range("K2"), Sheets(i).Range("k2").End(xlDown)).Address
    .Values = "='" & Sheets(i).Name & "'!" & _
    Sheets(i).Range(Sheets(i).Range("l2"), Sheets(i).Range("l2").End(xlDown)).Address
End With
    • Danke!! Es funktioniert!
    InformationsquelleAutor deusxmach1na
Schreibe einen Kommentar