Excel-VBA-Ereignis-Handler

Ich immer empfehlen, diese bei der Verwendung Worksheet_Change

1. Müssen Sie nicht den Namen des Blattes. Es wird davon ausgegangen, dass der code ausgeführt werden, auf der aktuellen Platte, es sei denn, Sie versuchen, verwenden Sie ein weiteres Blatt Zeile als eine Referenz, wie richtig erwähnt brettdj in den Kommentaren unten.

2. Wann immer Sie arbeiten mit Worksheet_Change Veranstaltung. Schalten Sie immer Ereignisse, wenn Sie das schreiben von Daten zu der Zelle. Dies ist erforderlich, damit der code nicht gehen in eine mögliche Endlosschleife

3. Wann immer Sie abschalten Veranstaltungen, mit Fehlerbehandlung else if erhalten Sie eine Fehlermeldung, der code wird nicht ausgeführt, das nächste mal.

Hier ist ein Beispiel

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    On Error GoTo Whoa

    Application.EnableEvents = False

    '
    '~~> Rest of the code
    '

LetsContinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub

Also mit dem obigen code wird (UNGETESTET)

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rowCount As Long

    On Error GoTo Whoa

    Application.EnableEvents = False

    With ActiveSheet
        rowCount = .Cells(.Rows.Count, "A").End(xlUp).Row
    End With


    If Not Intersect(Target, Range("M3:M" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("T3:T" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("X3:X" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("AB3:AB" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("AI3:AI" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    End If

LetsContinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub

BEARBEITEN:

Bezüglich deiner 2. Frage. Wie ich bereits im Kommentar oben, können Sie verwenden eine Öffentliche variable zu prüfen, ob das worksheet-change-Ereignis verursacht wird, indem Sie die Arbeitsmappe öffnen.

Dieser code in ein Modul.

Public WasWbOpened As Boolean

Platzieren Sie diesen code in die Arbeitsmappe code-Bereich

Option Explicit

Private Sub Workbook_Open()
    WasWbOpened = True
    '
    '~~> Rest of the code
    '
    WasWbOpened = False
End Sub

Und ändern Sie Ihre worksheet-change-Ereignis zu

Private Sub Worksheet_Change(ByVal Target As Range)
    If WasWbOpened = True Then Exit Sub

    Dim rowCount As Long

    On Error GoTo Whoa

    Application.EnableEvents = False

    With ActiveSheet
        rowCount = .Cells(.Rows.Count, "A").End(xlUp).Row
    End With


    If Not Intersect(Target, Range("M3:M" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("T3:T" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("X3:X" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("AB3:AB" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    ElseIf Not Intersect(Target, Range("AI3:AI" & rowCount)) Is Nothing Then
       MsgBox ("Hi")
    End If

LetsContinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub