Exportieren von rich-text in outlook und halten Sie die Formatierung

Ich habe einen button in Access, öffnet sich Outlook, erstellen eines Termins.

Private Sub addAppointEstimate_Click()
    Dim objOutlook As Object
    Dim objOutLookApp As Object
    Dim strSubject As String
    Dim strBody As String

    strSubject = Forms!frmMain.LastName 'more stuff to add
    strBody = DLookup("EstimateText", "tblEstimateItems", "EstimateID = 78") '& Forms!frmMain!frmSubTransaction!frmSubEstimate.Form.EstimateID)

    Set objOutlook = CreateObject("Outlook.Application")
    Set objOutLookApp = objOutlook.CreateItem(1)
    With objOutLookApp
        .subject = strSubject
        .RTFBody = StrConv(strBody, vbFromUnicode)
        .Display
    End With

End Sub

Das problem ist, dass ich einfügen möchte, Rich-text in den Körper, aber es nicht formatieren, da es zeigt alle HTML-tags statt e.g:

<div><strong>example </strong><font color=red>text</font></div>

Gibt es eine Möglichkeit, die ich senden kann oder konvertieren Sie die rich-text in Outlook in einem format, das es zu erkennen? (Vielleicht über die Zwischenablage)

Es scheint, viele Menschen haben eine Lösung für Excel, aber ich bin kämpfen, um zu arbeiten in Access:

Ist strBody wirklich eine RTF-formatierten string oder HTML? Im letzteren Fall, setzen Sie einfach die HTMLBody-Eigenschaft.

InformationsquelleAutor Magnus | 2014-06-16

Übergeben RTF-formatierten string um outlook-E-Mail Körper ist einfach wie folgt

Function RTF2Outlook(strRTF as String) as boolean
    Dim myOlApp, myOlItem
    Dim arrFiles() As String, arrDesc() As String, i As Long

    Set myOlApp = CreateObject("Outlook.Application")
    Set myOlItem = myOlApp.CreateItem(olMailItem)

    With myOlItem
       .BodyFormat = olFormatRichText
       .Body = StrConv(strRTF, vbFromUnicode) 'Convert RTF string to byte array
    End With
    Set myOlApp = Nothing
    Set myOlItem = Nothing
End Function

Das Geheimnis ist, nicht zu verwenden ".RTFBody" aber nur ".Körper" und die übergeben werden byte-Arrays, wie in den obigen code. Es brauchte eine Weile, um es herauszufinden.
Dank Microsoft haben wir immer etwas haben, um herauszufinden.

Vielen Dank für die Beobachtung zu benutzen .Körper und nicht .RTFBody. Ich habe die Arbeit dieser für 2 Tage, endlich scheint es zu funktionieren.

InformationsquelleAutor eddypi

1

Können Sie ein wenig zusätzlichen Aufwand, um eine Nachricht erstellen, die mit der formatierten HTMLBody Inhalt, dann kopieren Sie den Inhalt in ein terminelement.

Beginnen Sie, indem Sie eine Nachricht und einen Termin und füllen diese wie gewünscht. Setzen Sie den text in der Nachricht, überspringen Sie die Körper auf den Termin für jetzt.
```
Dim objOutlook As Object
Dim objMyMsgItem As Object
Dim objMyApptItem As Object
Dim strSubject As String

strSubject = "Some text" 'Forms!frmMain.LastName 'more stuff to add

Set objOutlook = CreateObject("Outlook.Application")
Set objMyMsgItem = objOutlook.CreateItem(0) 'Message Item
With objMyMsgItem
    .HTMLBody = "<div><strong>example </strong><font color=red>text</font></div>"
            'DLookup("EstimateText", "tblEstimateItems", "EstimateID = 78")
    .Display
End With

Set objMyApptItem = objOutlook.CreateItem(1) 'Appointment Item
With objMyApptItem
    .Subject = strSubject
    .Display
End With
```
Dann verwenden Sie die GetInspector Eigenschaft für die Interaktion mit dem Körper der jedes Element über einen Word-editor, und kopieren Sie den formatierten text, der Weise.
```
Dim MyMsgInspector As Object
Dim wdDoc_Msg As Object
Set MyMsgInspector = objMyMsgItem.GetInspector
Set wdDoc_Msg = MyMsgInspector.WordEditor

Dim MyApptInspector As Object
Dim wdDoc_Appt As Object
Set MyApptInspector = objMyApptItem.GetInspector
Set wdDoc_Appt = MyApptInspector.WordEditor

wdDoc_Appt.Range.FormattedText = wdDoc_Msg.Range.FormattedText
```
Dieser code ist getestet und funktioniert in Access 2013.

Ich mag mich irren, aber ich schwöre, dass die Letzte GetInspector code-block, der nichts tut?
Versuchen Sie, ein Verweis auf die Microsoft Word 14.0 Object Library (im Visual Basic-Editor auf Verweise im Menü Extras, Blättern Sie nach unten und aktivieren Sie das entsprechende Kontrollkästchen).
Hacky, aber hat wunderbar funktioniert danke. Ich bin mit einem JavaScript-version: var apptIns = Termin.GetInspector(); var msgIns = msg.GetInspector(); var apptDoc = apptIns.WordEditor; var msgDoc = msgIns.WordEditor; apptDoc.Range().FormattedText = msgDoc.Range().FormattedText;

InformationsquelleAutor AjimOthy
0

Beim setzen auf plain-text-Body-Eigenschaft. Legen Sie die HTMLBody-Eigenschaft auf einen ordnungsgemäß formatierten HTML-string.

Die object doesnt support .HTMLBody-Eigenschaft offenbar. Und ich glaube nicht, dass ich das ändern kann .BodyFormat einen Termin.
Outlook Termine, Aufgaben und Kontakte in der Tat nicht unterstützen, die HTMLBody-Eigenschaft, es ist nur ausgesetzt, indem das MailItem-Objekte. Sie können entweder die RtfBody Eigenschaft(byte-array), um eine korrekt formatierte RTF-Daten. Wenn Sie mit der Erlösung ist eine option, macht es die HTMLBody-Eigenschaft auf die RDOAppointmentItem, RDOContactItem und RDOTaskItem Objekte, die zur Laufzeit Erlösung dynamisch wandelt den angegebenen HTML-to-RTF.
Ok, ich habe versucht Einstellung der RTFBody Eigenschaft zu meinem text. Ich denke, ich wandelte es in ein Byte-array korrekt ein (Siehe code oben aktualisiert). Aber ich bekomme die Fehlermeldung "RTFBody" Objekt "_Appointment" ist fehlgeschlagen. Irgendwelche Ideen?
Noch, StrConv wandelt einen string top anderen. Sie benötigen ein byte-assay (wie im Dim SomeVar(100) usw,). Plus es braucht, um die echte RTF-text - öffnen Sie eine bestehende RTF-Datei im Editor.
Ich arbeite an einer Lösung, die beinhaltet die Bewältigung der formatierte text in die Zwischenablage kopieren, dann einfügen in Terminvereinbarung Körper. Ich weiß, ich sollte wahrscheinlich post dies als eine neue Frage, aber ist es möglich, zum einfügen in den Körper mithilfe von VBA in access?

InformationsquelleAutor Dmitry Streblechenko

Ich kam mit einer Lösung. Ich habe gerade kopiert und eingefügt, die gesamte sub, aber die Antwort ist in es ich verspreche es. Ich habe auch hervorgehoben, die wichtige bits.

Ich funktioniert auf meinem Rechner zu Hause, aber nicht auf den clients. So ich nicht verwenden, aber wenn Sie verbessern können, auf lass es mich wissen.

Private Sub addAppointmentEst_Click()


    Dim objOutlook As Object
    Dim objOutLookApp As Object
    Dim strSubject As String
    Dim strBody As String

    On Error GoTo appointmentEstError

    If Not IsNull(DLookup("EstimateID", "tblEstimate", "TransactionID = " & Me.TransactionID.Value)) Then
        DoCmd.OpenForm "frmEditEstimate", , , , , acHidden '<------ OPEN FORMATTED TEXT IN A FORM
        Forms!frmEditEstimate.SetFocus
        Forms!frmEditEstimate!frmSubEstimateItems.Form.EstimateText.SetFocus
        DoCmd.RunCommand acCmdCopy '<------ COPY FORMATTED TEXT
        DoCmd.Close acForm, "frmEditEstimate", acSaveNo
    End If

'        If Not IsNull(Forms!frmMain.Title.Value) Then
'            strSubject = strSubject & Forms!frmMain.Title.Value
'        End If
     If Not IsNull(Forms!frmMain.FirstName.Value) Then
         strSubject = strSubject & Forms!frmMain.FirstName.Value
    End If
    If Not IsNull(Forms!frmMain.LastName.Value) Then
        strSubject = strSubject & " " & Forms!frmMain.LastName.Value
    End If
    If Not IsNull(Forms!frmMain.Organisation.Value) Then
        strSubject = strSubject & " (" & Forms!frmMain.Organisation.Value & ")"
    End If
    If Not IsNull(Forms!frmMain!frmSubTransaction.Form.Property.Value) Then
        strSubject = strSubject & " - " & Forms!frmMain!frmSubTransaction.Form.Property.Value
    End If

    Set objOutlook = CreateObject("Outlook.Application")
    Set objOutLookApp = objOutlook.CreateItem(1)

     With objOutLookApp
         .subject = strSubject
         .Display
     End With

    If Not IsNull(DLookup("EstimateID", "tblEstimate", "TransactionID = " & Me.TransactionID.Value)) Then
        Set objectOutlookBody = objOutlook.ActiveInspector.WordEditor
        objOutLookApp.Body = vbCrLf & "Estimate ID: " & Forms!frmMain!frmSubTransaction!frmSubEstimate.Form.EstimateID.Value & _
                            vbCrLf & "Estimate Date: " & Forms!frmMain!frmSubTransaction!frmSubEstimate.Form.EstimateDate.Value
        objectOutlookBody.Application.Selection.Paste '<----- PASTE TEXT INTO APPOINTMENT

        Forms!frmMain.EmptyValue.Value = " " '<----- EMPTY CLIPBOARD
        Forms!frmMain.EmptyValue.SetFocus
        DoCmd.RunCommand acCmdCopy
    End If

Exit Sub

appointmentEstError:
        MsgBox _
        Prompt:="Failed create an appointment in Outlook, with the estimate attached", _
        Buttons:=vbOKOnly + vbExclamation, _
        Title:="Error"
End Sub

InformationsquelleAutor Magnus

0

Als in der vorherigen Antwort, diese Zeile ist der Schlüssel, es kopiert text, hyperlinks, Bilder etc. ohne änderung der Inhalt der Zwischenablage:
```
wdDoc_Appt.Range.FormattedText = wdDoc_Msg.Range.FormattedText
```
InformationsquelleAutor T800

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.