Festlegen einer Windows-Batchdateivariable auf den Wochentag

Ich habe eine windows-batch-Datei, die läuft täglich. Möchten, melden Sie Daten in eine Datei und wollen, um es zu drehen (d.h. maximal die letzten 7 Tage im Wert von Daten).

Sah in die Befehle DATE und DELIMS - Nicht herauszufinden, eine Lösung.

Gibt es da eine einfache Lösung zum erstellen einer Datei-Namen enthält, den Tag der Woche, d.h. 0 für Montag usw.

Oder muss ich etwas ähnliches besser shell-Skript.

InformationsquelleAutor der Frage Ed Heal | 2012-07-06

  1. 26

    %DATE% ist nicht dein Freund. Da die %DATE% Umgebungsvariable (und die DATE Befehl) gibt das aktuelle Datum mit dem Windows kurze Datum-format das ist voll und endlos anpassbar. Ein Benutzer kann das system so konfigurieren, zurück 07/06/2012, während andere wählen könnte, Fri060712. Mit %DATE% ist der absolute Albtraum für eine FLEDERMAUS-Programmierer.

    Gibt es zwei mögliche Ansätze um dieses problem zu lösen:

    1. Sie könnten versucht sein, ändern Sie vorübergehend das kurze Datum-format, indem Sie die locale-Einstellungen in der registry-Wert HKCU\Control Panel\International\sShortDate zu Ihrem erkennbaren format. Dann auf %DATE% um das Datum in das format, das Sie wollen; und schließlich wiederherstellen, das format zurück auf den ursprünglichen Benutzer format. So etwas

      reg copy "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp" /f >nul
reg add "HKCU\Control Panel\International" /v sShortDate /d "ddd" /f >nul
set DOW=%DATE%
reg copy "HKCU\Control Panel\International-Temp" "HKCU\Control Panel\International" /f >nul

      aber diese Methode hat zwei Probleme:

      • it-Stampfer mit einem globalen Registrierungswert für seine lokalen insbesondere purpouses, so kann es zu Störungen mit anderen Prozessen oder Aufgaben des Benutzers, die zur selben Zeit Abfrage das Datum im kurzen Datumsformat, einschließlich sich selbst, wenn die gleichzeitig ausgeführt werden.

      • und es gibt die drei-Buchstaben-Tag in der Woche, in der lokalen Sprache, die kann unterschiedlich sein in verschiedenen Systemen oder verschiedenen Benutzern.

    2. verwenden WMIC Win32_LocalTime, dass gibt das Datum zurück in eine bequeme Art und Weise direkt analysiert werden, mit einem FOR Befehl.

      FOR /F "skip=1" %%A IN ('WMIC Path Win32_LocalTime Get DayOfWeek' ) DO (
  set DOW=%%A
)

      dies ist die Methode, die ich empfehlen kann.

    InformationsquelleAutor der Antwort PA.

  2. 11

    paar mehr Möglichkeiten:

    1.Robocopy nicht in XP, aber heruntergeladen werden können mit win 2003 resource tool kit .Könnte auch davon abhängen, Lokalisierung:

    @echo off
setlocal 
for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
 set "dow=%%D"
 set "month=%%E"
 set "day=%%F"
 set "HH=%%G"
 set "MM=%%H"
 set "SS=%%I"
 set "year=%%J"
)

echo Day of the week: %dow%
endlocal

    2.MAKECAB - funktioniert auf jedem windows-Rechner (schafft aber eine kleine temp-Datei).Funktion von carlos:

    @Echo Off


Call :GetDate.Init
Rem :GetDate.Init should be called one time in the code before call to :Getdate
Call :GetDate
Echo weekday:%weekday%

Goto :EOF

:GetDate.Init
Set /A "jan=1,feb=2,mar=3,apr=4,may=5,jun=6,jul=7,aug=8,sep=9,oct=10,nov=11,dec=12"
Set /A "mon=1,tue=2,wed=3,thu=4,fri=5,sat=6,sun=7"
(
Echo .Set InfHeader=""
Echo .Set InfSectionOrder=""
Echo .Set InfFooter="%%2"
Echo .Set InfFooter1=""
Echo .Set InfFooter2=""
Echo .Set InfFooter3=""
Echo .Set InfFooter4=""
Echo .Set Cabinet="OFF"
Echo .Set Compress="OFF"
Echo .Set DoNotCopyFiles="ON"
Echo .Set RptFileName="NUL"
) >"%Temp%\~foo.ddf"
Goto :Eof

:GetDate
Set "tf=%Temp%\~%random%"
Makecab /D InfFileName="%tf%" /F "%Temp%\~foo.ddf" >NUL
For /F "usebackq tokens=1-7 delims=: " %%a In ("%tf%") Do (
Set /A "year=%%g,month=%%b,day=1%%c-100,weekday=%%a"
Set /A "hour=1%%d-100,minute=1%%e-100,second=1%%f-100")
Del "%tf%" >NUL 2>&1
Goto :Eof

    3.W32TM - verwendet-Befehl Schalter in Vista eingeführt wurde, also nicht auf windows 2003/XP:

    @echo off
setlocal
call :w32dow day_ow
echo %day_ow%
pause
exit /b 0
endlocal
:w32dow [RrnVar]
setlocal

rem :: prints the day of the week
rem :: works on Vista and above


rem :: getting ansi date ( days passed from 1st jan 1601 ) , timer server hour and current hour
FOR /F "tokens=4,5 delims=:( " %%D in ('w32tm /stripchart /computer:localhost  /samples:1  /period:1 /dataonly /packetinfo^|find "Transmit Timestamp:" ') do (
 set "ANSI_DATE=%%D"
 set  "TIMESERVER_HOURS=%%E"
)

set  "LOCAL_HOURS=%TIME:~0,2%"
if "%TIMESERVER_HOURS:~0,1%0" EQU "00" set TIMESERVER_HOURS=%TIMESERVER_HOURS:~1,1%
if "%LOCAL_HOURS:~0,1%0" EQU "00" set LOCAL_HOURS=%LOCAL_HOURS:~1,1%
set /a OFFSET=TIMESERVER_HOURS-LOCAL_HOURS

rem :: day of the week will be the modulus of 7 of local ansi date +1
rem :: we need need +1 because Monday will be calculated as 0
rem ::  1st jan 1601 was Monday

rem :: if abs(offset)>12 we are in different days with the time server

IF %OFFSET%0 GTR 120 set /a DOW=(ANSI_DATE+1)%%7+1
IF %OFFSET%0 LSS -120 set /a DOW=(ANSI_DATE-1)%%7+1
IF %OFFSET%0 LEQ 120 IF %OFFSET%0 GEQ -120 set /a DOW=ANSI_DATE%%7+1


rem echo Day of the week: %DOW% 
endlocal & if "%~1" neq "" (set "%~1=%DOW%") else echo %DOW%

    4..bat/jscript hybrid (muss gespeichert werden .bat):

     @if (@x)==(@y) @end /***** jscript comment ******
 @echo off
 for /f  %%d in ('cscript //E:JScript //nologo "%~f0"') do echo %%d
 exit /b 0
 *****  end comment *********/
 WScript.Echo((new Date).getDay());

    5..bat/vbscript hybrid (muss gespeichert werden .bat)

     :sub echo(str) :end sub
echo off
'>nul 2>&1|| copy /Y %windir%\System32\doskey.exe '.exe >nul

'& echo/
'& for /f %%w in ('cscript /nologo /E:vbscript %~dpfn0') do echo day of the week %%w
'& echo/
'& del /q "'.exe" >nul 2>&1
'& exit /b

WScript.Echo Weekday(Date)
WScript.Quit

    6.powershell heruntergeladen werden kann von microsoft.Standardmäßig verfügbar in alles zu bilden, win7 und höher:

    @echo off
setlocal
for /f %%d in ('"powershell (Get-Date).Day"') do set dow=%%d

echo day of the week : %dow%
endlocal

    7.WMIC schon als eine Antwort, aber wollen einfach nur eine vollständige Referenz.Und mit deaktiviert <CR>:

    @echo off
setlocal
for /f "delims=" %%a in ('wmic path win32_localtime get dayofweek /format:list ') do for /f "delims=" %%d in ("%%a") do set %%d

echo day of the week : %dayofweek%
endlocal

    9.Selfcompiled jscript.net (muss gespeichert werden, als .bat):

    @if (@X)==(@Y) @end /****** silent line that start jscript comment ******

@echo off
::::::::::::::::::::::::::::::::::::
:::       compile the script    ::::
::::::::::::::::::::::::::::::::::::
setlocal
if exist "%~n0.exe" goto :skip_compilation

set "frm=%SystemRoot%\Microsoft.NET\Framework\"
:: searching the latest installed .net framework
for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
    if exist "%%v\jsc.exe" (
        rem :: the javascript.net compiler
        set "jsc=%%~dpsnfxv\jsc.exe"
        goto :break_loop
    )
)
echo jsc.exe not found && exit /b 0
:break_loop


call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
::::::::::::::::::::::::::::::::::::
:::       end of compilation    ::::
::::::::::::::::::::::::::::::::::::
:skip_compilation

"%~n0.exe"

exit /b 0


****** end of jscript comment ******/
import System;
import System.IO;

var dt=DateTime.Now;
 Console.WriteLine(dt.DayOfWeek);

    InformationsquelleAutor der Antwort npocmaka

  3. 6
    @ECHO OFF
REM GET DAY OF WEEK VIA DATE TO JULIAN DAY NUMBER CONVERSION
REM ANTONIO PEREZ AYALA
REM GET MONTH, DAY, YEAR VALUES AND ELIMINATE LEFT ZEROS
FOR /F "TOKENS=1-3 DELIMS=/" %%A IN ("%DATE%") DO SET /A MM=10%%A %% 100, DD=10%%B %% 100, YY=%%C
REM CALCULATE JULIAN DAY NUMBER, THEN DAY OF WEEK
IF %MM% LSS 3 SET /A MM+=12, YY-=1
SET /A A=YY/100, B=A/4, C=2-A+B, E=36525*(YY+4716)/100, F=306*(MM+1)/10, JDN=C+DD+E+F-1524
SET /A DOW=(JDN+1)%%7

    DOW steht 0 für Sonntag, 1 für Montag usw.

    InformationsquelleAutor der Antwort Aacini

  4. 3

    Ich dachte, dass meine erste Antwort-gibt den richtigen Tag der Woche als Zahl zwischen 0 und 6. Allerdings, denn Sie hatte nicht angegeben, warum diese Antwort nicht geben, das Ergebnis, die Sie wollen, kann ich nur raten, den Grund.

    Batch-Datei eine log-Datei erstellen, jeden Tag mit einer Ziffer im Namen, 0=Sonntag, 1=Montag, usw... Das Programm davon aus, dass echo %date% zeigen Sie das Datum im MM/TT/JJJJ-format; wenn dies nicht der Fall, ändern Sie einfach die position von mm und dd Variablen in der for Befehl.

    @echo off
for /F "tokens=1-3 delims=/" %%a in ("%date%") do set /A mm=10%%a %% 100, dd=10%%b %% 100, yy=%%c
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10, dow=(c+dd+e+f-1523)%%7
echo Today log data > Day-%dow%.txt

    Wenn dieses nicht ist, was Sie wollen, geben Sie bitte das problem, damit ich es beheben kann.

    BEARBEITEN: die version, Die Sie unten get-date-Teile unabhängig von der locale-Einstellungen:

    @echo off
for /F "skip=1 tokens=2-4 delims=(-/)" %%A in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
      set %%A=%%a
      set %%B=%%b
      set %%C=%%c
   )
)
set /A mm=10%mm% %% 100, dd=10%dd% %% 100
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10, 

dow=(c+dd+e+f-1523)%%7
echo Today log data > Day-%dow%.txt

    BEARBEITEN: die version, Die unter insert-Tag der Woche als 3-Buchstaben-Abkürzung:

    @echo off
for /F "skip=1 tokens=2-4 delims=(-/)" %%A in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
      set %%A=%%a
      set %%B=%%b
      set %%C=%%c
   )
)
set /A mm=10%mm% %% 100, dd=10%dd% %% 100
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10, 

dow=(c+dd+e+f-1523)%%7 + 1
for /F "tokens=%dow%" %%a in ("Sun Mon Tue Wed Thu Fri Sat") do set dow=%%a
echo Today log data > Day-%dow%.txt

    Grüße,

    Antonio

    InformationsquelleAutor der Antwort Aacini

  5. 2

    Dieser stellte sich heraus, viel mehr Komplex, dann habe ich zunächst vermutet, und ich denke, das ist es, was mich faszinierte, suchte ich an jedem Ort und zu den Methoden gegeben, würde nicht funktionieren auf Windows 7.

    So, ich habe eine Alternative Lösung, die über ein Visual Basic Script.

    Batch erstellt und führt das script aus(DayOfWeek.vbs), weist die Skripte ausgegeben (Montag, Dienstag usw) zu einer Variablen ("dow"), die variable wird dann geprüft und eine andere variable (dpwnum) zugewiesen mit der Anzahl Tage, danach wird die VBS gelöscht, hoffe es hilft:

    @echo off

REM Create VBS that will get day of week in same directory as batch
echo wscript.echo WeekdayName(Weekday(Date))>>DayOfWeek.vbs

REM Cycle through output to get day of week i.e monday,tuesday etc
for /f "delims=" %%a in ('cscript /nologo DayOfWeek.vbs') do @set dow=%%a

REM delete vbs
del DayOfWeek.vbs

REM Used for testing outputs days name
echo %dow%

REM Case of the days name is important must have a capital letter at start
REM Check days name and assign value depending
IF %dow%==Monday set downum=0
IF %dow%==Tuesday set downum=1
IF %dow%==Wednesday set downum=2
IF %dow%==Thursday set downum=3
IF %dow%==Friday set downum=4
IF %dow%==Saturday set downum=5
IF %dow%==Sunday set downum=6

REM print the days number 0-mon,1-tue ... 6-sun
echo %downum%

REM set a file name using day of week number
set myfile=%downum%.bak

echo %myfile%

pause
exit

    EDIT:

    Obwohl ich wandte mich an VBS, Es kann getan werden, in reiner Stapel, nahm mich eine Weile, um es arbeiten und viel suchen, lol, aber das scheint zu funktionieren:

     @echo off
SETLOCAL enabledelayedexpansion
SET /a count=0
FOR /F "skip=1" %%D IN ('wmic path win32_localtime get dayofweek') DO (
    if "!count!" GTR "0" GOTO next
    set dow=%%D
    SET /a count+=1
)
:next
echo %dow%
pause

    Die einzige Einschränkung für Sie auf den obigen batch ist, dass der Tag der Wochen sind von 1-7 und nicht 0-6

    InformationsquelleAutor der Antwort David Kroukamp

  6. 2

    Dies funktioniert für mich 

    FOR /F "tokens=3" %%a in ('robocopy ^|find "Started"') DO SET TODAY=%%a

    InformationsquelleAutor der Antwort Dan

  7. 2

    Dies ist nicht meine Arbeit (gut, ich veränderte es etwas aus dem Beispiel), und es ist zu spät, um das Spiel, aber so funktioniert es auf dem Server 2003 für mich;

    @echo off  
set daysofweek=Monday,Tuesday,Wednesday,Thursday,Friday,Saturday,Sunday  
for /F "skip=2 tokens=2-4 delims=," %%A in ('WMIC Path Win32_LocalTime Get DayOfWeek /Format:csv') do set daynumber=%%A  
for /F "tokens=%daynumber% delims=," %%B in ("%daysofweek%") do set day=%%B

    Zitat: TechSupportForum

    InformationsquelleAutor der Antwort delliottg

  8. 2

    First - Copy CON SETUPDAY.001
    SET ARBEITSTAG=^Z (sehr wichtig - keine cr/lf)

    DATE /T >SETUPDAY.002
COPY SETUPDAY.001+SETUPDAY.002 NEWDAY.BAT >nul
CALL NEWDAY.BAT

SET WEEKDAY=%WORKDAY:~0,3%
SET MDY=%WORKDAY:~4,10%

    %WOCHENTAG%, DIE IN IHREM SKRIPT

    InformationsquelleAutor der Antwort Ted Waterbury

  9. 1

    Locale-abhängige version: In einigen Umgebungen, die folgenden extrahieren wird der Tag-name aus dem Datum:

    set dayname=%date:~0,3%

    Es wird davon ausgegangen, dass die Tag-Namen ist der erste Teil %date%. Abhängig von den Einstellungen der Maschine, wenn der Teilstring Teil (~0,3) ändern muss.

    Einer Aussage wie dieser würde dump in eine Datei mit einem drei-Zeichen-Tag-name:

    set logfile=%date:~0,3%.log
echo some stuff > %logfile%

    Locale-unabhängig version:, Wenn Sie es brauchen weniger abhängig von der aktuellen Maschine Tag-format, einen anderen Weg, es zu tun, wäre die Erstellung einer kleinen Anwendung, die druckt den Tag der Woche. Verwenden Sie dann die Ausgabe von diesem Programm aus der batch-Datei. Zum Beispiel ist das folgende C-Anwendung druckt dayN wobei N=0..6.

    #include <stdio.h>
#include <time.h>

int main( int argc, char* argv[] )
{
   time_t curtime;
   struct tm * tmval;

   time( &curtime );
   tmval = localtime( &curtime );
   //print dayN.  Or use a switch statement and print
   //the actual day name if you want
   printf( "day%d", tmval->tm_wday );
}

    Wenn die oben genannten wurden zusammengestellt und miteinander verknüpft myday.exe haben, dann könnten Sie es aus einer batch-Datei wie folgt:

    for /f %%d in ('myday.exe') do set logfile=%%d.log
echo some stuff > %logfile%

    InformationsquelleAutor der Antwort Mark Wilkins

  10. 1

    Ich bin in den USA. Ich kann diesen code ausführen in Windows 7, Windows 2008 R2, Windows Server 2003, Windows XP (Alle Betriebssysteme werden aktuell mit Windows Updates und patches). Alle mit der Einstellung kurzes Datum ohne ddd - (oder dddd) (Tag der Woche).

    @echo off
for /f %%a in ('date /t') do set DAY=%%a
echo.
echo The Day Is: %DAY%
echo.

    Wenn heute Donnerstag ist, würde es die Ausgabe "Der Tag Ist: do".

    Dieser gibt den Tag über alle 4 Windows-Versionen, die ich getestet habe. Und nur der Tag. Wenn ich änderte meine kurze Datum-setup "ddd, M/d/yyyy", meine Ausgabe würde zeigen Sie den Tag mit einem Komma (z.B. do /FR), was sagt mir dieser code ist für das kurze Datumsformat. Aber was auch passiert werden kann ist, dass, wenn das kurze Datum nicht enthalten ist der Tag der Woche, kann es Aussehen, um das lange Datum-format, das auf allen 4 Rechnern die ich getestet habe, haben dddd im format.

    InformationsquelleAutor der Antwort user2316634

  11. 1

    Habe ich diese Lösung für mich:

    Erstellen Sie eine Datei namens dayOfWeek.vbs in der gleichen dir wo die cmd-Datei wird gehen.

    dayOfWeek.vbs enthält eine einzige Zeile:

    wscript.stdout.write weekdayname(weekday(date))

    oder, wenn Sie wollen, Tag Nummer statt name:

    wscript.stdout.write weekday(date)

    Die cmd-Datei wird diese Zeile:

    For /F %%A In ('CScript dayOfWeek.vbs //NoLogo') Do Set dayName=%%A

    Nun können Sie variable dayName wie:

    robocopy c:\inetpub \\DCStorage1\Share1\WebServer\InetPub_%dayName% /S /XD history logs

    InformationsquelleAutor der Antwort Manuel Alves

  12. 0

    Wenn Sie ändern, können format kurzes Datum in den PC zu "ddd-yyyy-MM-dd" (nur der erste parameter " TTT " ist obligatorisch), dann folgenden Befehl wird-

    c:\>vol | date
The current date is: Mon 2014-12-01

    Dann Sie können schreiben Sie die batch-Datei -

    @echo off

vol | date | find /i "sun" > nul 
if not errorlevel 1 goto SUN

vol | date | find /i "mon" > nul 
if not errorlevel 1 goto MON

      # write block for other week days    

goto END

:SUN
set fname="sun"
goto BACKUP

:MON
set fname="mon"
goto BACKUP

      # write block for other week days

:BACKUP
echo %fname%

:END

    InformationsquelleAutor der Antwort willstay

  13. 0
    Rem Remove the end comma and add /A to set for this line worked for me.
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10

    InformationsquelleAutor der Antwort Eamonn Deering

  14. 0

    War auf der Suche, diese selbst zu tun und sah, Beschwerden über leere Zeilen:

    rem Make the win32_localtime output all one line, though some versions may contain blank lines as well.
rem So ignore blank lines and just pick up the number after the equal sign.
for /f "delims== tokens=2" %%a in ('wmic path win32_localtime get dayofweek /format:list') do (
    rem Increment the DOW as it is documented to be a zero-based index starting with Sunday.
    set /a DayOfWeekIndex=%%a+1
)
rem Also get name day of week. The DOW coming in is now a one-based index.
rem This is used to reference the "array" of week day names.
set DayOfWeekNames=Sun Mon Tue Wed Thu Fri Sat
for /f "tokens=%DayOfWeekIndex%" %%b in ("%DayOfWeekNames%") do (
    set DayOfWeekName=%%b
)

    InformationsquelleAutor der Antwort georges

  15. 0

    Verbesserte Ich Aacini Antwort
    um es Echo Vollen Tag der Woche Name

    So, hier ist mein Code

    @echo off
for /F "skip=1 tokens=2-4 delims=(-/)" %%A in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
      set %%A=%%a
      set %%B=%%b
      set %%C=%%c
   )
)
set /A mm=10%mm% %% 100, dd=10%dd% %% 100
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=4-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10,dow=(c+dd+e+f-1523)%%7 + 1
for /F "tokens=%dow%" %%a in ("Sunday Monday Tuesday Wednesday Thursday Friday Saturday ") do set dow=%%a
echo Today is %dow%>"Today is %dow%.txt"
echo Today is %dow%
Pause>Nul

REM Sun Mon Tue Wed Thu Fri Sat
REM Sunday Monday Tuesday Wednesday Thursday Friday Saturday

    InformationsquelleAutor der Antwort Omar Deif

  16. -1

    Einer version mit MSHTA und javascript. Veränderung in %jsfunc% auf whateve jscript-Funktion, die Sie anrufen möchten

    @echo off
::Invoke a javascript function using mhta

set jsfunc=new Date().getDay()
set dialog="about:<script>resizeTo(0,0);new ActiveXObject('Scripting.FileSystemObject').
set dialog=%dialog%GetStandardStream(1).WriteLine(%jsfunc%);close();</script>"

for /f "tokens=* delims=" %%p in ('mshta.exe %dialog%') do set ndow=%%p

::get dow string from array of strings  
for /f "tokens=%ndow%"  %%d in ("Mon Tue Wed Thu Fri Sat Sun") do set dow=%%d 

echo dow is : %ndow%  %dow%
pause

    InformationsquelleAutor der Antwort Antoni Gual Via

Schreibe einen Kommentar