flash-Ereignis-listener für movieclip-Ende?

Könnte jemand empfehlen, der beste Weg, um die trigger eine functiont, wenn ein movieclip-animation beendet ist?
Ich vermute ein eventlistener könnte damit umgehen, aber nicht sicher der beste Weg, um darüber zu gehen.
Dank
Paul

der Umgang etwas ähnliches im moment. Die einfachste option ist die Verwendung eines Ereignis-listener für das ENTER_FRAME-Ereignis aus und überprüfen Sie, ob die currentframe ist das Letzte (z.B. Funktion checkLastFrame(event:event):void{ trace(currentFrame == totalFrames); } ), aber je nachdem, wie einfach oder Komplex, sind finden Sie vielleicht die folgenden Ressourcen nützlich: adobe.com/devnet/flash/articles/timelinewatcher.html , bytearray.org/?p=603 , tink.ws/blog/framelabelmovieclip-uiframelabelmovieclip
Cheers für deine Hilfe, George
Warum kann man nicht einfach ein Ereignis ausgelöst auf dem letzten Bild?
Oder sogar ein Ereignis ausgelöst auf das Letzte Bild und hören Sie es an anderer Stelle.
Ich komme aus einem as2-Winkel - also das auslösen eines Ereignisses vom letzten Bild war das erste, woran ich dachte, aber ich kann nicht herausfinden, wie man trigger eine Funktion in der Wurzel von einer dynamisch geladenen Film
Ich habe mich oft gefragt, warum Flash nicht haben ein built-in-Ereignis für diese, wie für die videos, wenn Sie mit dem spielen fertig sind.

InformationsquelleAutor Dancer | 2011-05-12

Gibt es ein paar Wege zu gehen über diese:

Rufen Sie einfach die Funktion aus dem letzten frame der animation.
Ein Ereignis ausgelöst auf das Letzte Bild Ihrer Funktion und hören Sie es an anderer Stelle.
Die lange, aber wirksam /ordentlich /empfohlene Weg.

In Bezug auf Punkt 3, ich würde eine Basisklasse für Ihr Objekt. Auf diese Weise können Sie dieselbe Logik auf mehrere Elemente animiert.

Etwas wie dieses:

package
{
    import flash.display.MovieClip;
    import flash.events.Event;

    public class AnimatingObject extends MovieClip
    {
        //constants
        public const ANIMATION_COMPLETE:String = "animation_complete";

        /**
         * Constructor
         */
        public function AnimatingObject()
        {
            addEventListener(Event.ENTER_FRAME, _handle);
        }

        /**
         * Called on dispatch of Event.ENTER_FRAME
         */
        private function _handle(e:Event):void
        {
            if(currentFrame == totalFrames)
            {
                var evt:Event = new Event(ANIMATION_COMPLETE);
                dispatchEvent(evt);
            }
        }
    }
}

Nun können wir hören "animation_complete" und Sachen tun, entsprechend.

package
{
    import flash.events.Event;

    public class MyAnimatingObject extends AnimatingObject
    {
        /**
         * Constructor
         */
        public function MyAnimatingObject()
        {
            addEventListener(ANIMATION_COMPLETE, _lastFrame);
        }

        /**
         * Called on dispatch of AnimatingObject.ANIMATION_COMPLETE
         */
        private function _lastFrame(e:Event):void
        {
            trace("i'm done");
        }
    }
}

InformationsquelleAutor Marty

3

Es ist schon eine Weile her, ich spielte mit flash. Ich meistens tun, flex now, aber sollte diese Arbeit.

Mit dem enterFrame-Ereignis wäre eine riesige Verschwendung von Ressourcen, und erstellen Sie eine benutzerdefinierte event-Klasse ist nicht nötig.
Auf den letzten frame setzen diese
```
dispatchEvent(new Event("INSERTSTUPIDEVENTNAMEHERE"));
```
Und in Ihrem code auf Ihr "root"
```
movieInstanceName.addEventListener( "INSERTSTUPIDEVENTNAMEHERE", someCallBackFunction );

function someCallBackFunction ( e:Event ):void{
  trace( "Last frame hit");
}
```
- Diese Antwort funktioniert, wenn man code auf der Zeitleiste in Flash, aber Sie können keinen Zugriff auf das original .fla-oder sogar wollen, um code auf der Zeitachse, denn das kann verwirrend sein, manchmal. Plus ich würde nicht gerade nennen das enterFrame-Ereignis, eine "riesige" Nutzung von Ressourcen.
InformationsquelleAutor The_asMan

Durch die Nutzung eines ENTER_FRAME listener, können Sie sagen, wenn ein MovieClip hat gelesen das beenden der Wiedergabe; Sie können dann einen Schritt weiter, indem er es in eine Wrapper-Klasse, die ausgeführt wird, Sie die überwachung für Sie:

public class EndOfMovieClipEventDispatcher extends EventDispatcher
{
    private var target : MovieClip;
    private var endReachedEvent : String;

    public function EndOfMovieClipEventDispatcher(target : MovieClip, endReachedEvent : String = "complete") {
        this.target = target;
        this.endReachedEvent = endReachedEvent;
        target.addEventListener(Event.ENTER_FRAME, onEnterFrameEvent, false, 0, true);
    }

    public function destroy() : void {
        target.removeEventListener(Event.ENTER_FRAME, onEnterFrameEvent);
    }

    private function onEnterFrameEvent(event : Event) : void
    {
        if (target.currentFrame == target.totalFrames) {
            dispatchEvent(new Event(endReachedEvent));
        }
    }
}

Verwendung ist ziemlich geradlinig; der Aufruf von destroy() ist optional, Dank der schwachen Ereignis-listener; aber empfohlen, wenn Sie fertig sind 🙂

new EndOfMovieClipEventDispatcher(myMovieClip).addEventListener(Event.COMPLETE, onMovieClipCompleteEvent);
myMovieClip.play();

InformationsquelleAutor JonnyReeves

0

Ich glaube nicht, es ist eine Veranstaltung, die Sendung am Ende ein movieclip ist, können Sie immer ein Skript ausführen, auf dem letzten frame der animation ausführen, was Sie wollen. Wenn Sie wirklich wollen, um Ereignisse, die im letzten frame des Movieclips könnte ein Skript auszuführen, nutzt dispatchEvent() zum senden eines benutzerdefinierten sogar die abgeholt werden können.

Ich bin mir nicht sicher, von deinem post, wenn Sie Event-Handler vor, also hier ist ein tutorial auf, dass (ich bin nicht gut im erklären, sorry!):
http://edutechwiki.unige.ch/en/ActionScript_3_event_handling_tutorial

und für dispatchEvent():
http://www.actionscript.org/resources/articles/204/1/Using-EventDispatcher/Page1.html

InformationsquelleAutor Curlystraw
0

Könnten Sie eine enterframe-listener, der prüft, um zu sehen, ob der movieclip den currentFrame == totalFrames, und wenn Sie gleich sind, versenden Sie ein benutzerdefiniertes Ereignis aus, dass Sie (wie TimelineComplete).

Andere option wäre eine kleine Komponente, löst Ihre benutzerdefinierten TimelineComplete Ereignis, und platzieren Sie diese Komponente auf dem letzten frame der animation, die Sie überwachen möchten. Dies würde ermöglichen es Ihnen, mehr Kreativität in die Zukunft und fügen Sie Dinge wie eine Verzögerung, bevor das Ereignis ausgelöst wird.

Haben Sie ein paar Optionen, von denen keines sind ideal meiner Meinung nach, aber Sie tun die Arbeit, und wenn gut gemacht, Sie werden nicht unhandlich. Das einzige, was ich nicht machen würde, ist fügen Sie ein wenig code, der auf dem letzten Bild. Das wird eher schwer zu verfolgen über die Zeit.

InformationsquelleAutor Alex Jillard

Können Sie erstellen eine benutzerdefinierte MovieClip Klasse löst ein Ereignis aus, wenn der MovieClip-Objekt ist auf dem letzten Bild. Sie können dann die benutzerdefinierten MovieClip Klasse der Basis-Klasse von der MovieClip-animation:

CustomMovieClip.als:

package display 
{
    import events.TimelineEvent;
    import flash.display.MovieClip;
    import flash.events.Event;

    public class CustomMovieClip extends MovieClip
    {
        private var _isLastFrame:Boolean;

        public function get isLastFrame():Boolean { return _isLastFrame }

        public function CustomMovieClip()
        {
            init();

        }//end function

        private function init():void
        {
            addEventListener(Event.ENTER_FRAME, onEnterFrame);

        }//end function

        private function onEnterFrame(e:Event):void
        {
            if (!_isLastFrame)
            {
                if (currentFrame == totalFrames) 
                {
                    dispatchEvent(new TimelineEvent(TimelineEvent.LAST_FRAME));
                    _isLastFrame = true;

                }//end if

            }
            else 
            {
                if (currentFrame != totalFrames) _isLastFrame = false;

            }//end else

        }//end function

    }//end class

}//end package

TimelineEvent.als:

package events
{   
    import flash.events.Event;

    public class TimelineEvent extends Event 
    {
        public static var LAST_FRAME:String = "lastFrame";

        public function TimelineEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false) 
        { 
            super(type, bubbles, cancelable);

        }//end function

        public override function clone():Event 
        { 
            return new TimelineEvent(type, bubbles, cancelable);

        }//end function

    }//end class

}//end package

Main.als(Dokument-Klasse):

package 
{
    import display.CustomMovieClip;
    import events.TimelineEvent;
    import flash.display.Sprite;
    import flash.events.Event;

    public class Main extends Sprite 
    {
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }///end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            var customMovieClip:CustomMovieClip = new CustomMovieClip();
            customMovieClip.addEventListener(TimelineEvent.LAST_FRAME, onCustomMovieClipLastFrame);
            customMovieClip.play();

        }//end function

        private function onCustomMovieClipLastFrame(e:TimelineEvent):void
        {
            var customMovieClip:CustomMovieClip = CustomMovieClip(e.target);
            customMovieClip.removeEventListener(TimelineEvent.LAST_FRAME, onCustomMovieClipLastFrame);

            trace(customMovieClip.isLastFrame); //output: true

        }//end function

    }//end class

}//end package

InformationsquelleAutor Taurayi

wenn man für die kürzeste Lösung, die ich denke, es wäre :

        mc.addFrameScript(mc.totalFrames - 1, function():void 
        {
            trace("end of mc");
        });

InformationsquelleAutor Delavega

0

Nur überprüfen currentFrame und totalFrames ist nicht genug für ein MovieClip mehrere Szenen. Sie müssen auch überprüfen, wenn es an die Letzte Szene.
```
function isAtLastFrame(mc:MovieClip):Boolean
{
  return currentScene.name == mc.scenes[mc.scenes.length - 1].name && currentFrame == currentScene.numFrames;
}
```
InformationsquelleAutor Yang Bo

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.