Flex DataGrid-mit Zeilennummer-Spalte

Möchte ich verlängern Sie die DataGrid-Komponente so, dass es eine (nur-lese -) Spalte für die Nummer der Zeile wie in Tabellenkalkulationen. Ich stieß auf diesen Artikel http://www.cflex.net/showFileDetails.cfm?ObjectID=735 aber es hängt davon ab, die Daten, die einzigartig für jede Zeile, so dass es kann einen index in das array. Wenn die Daten nicht eindeutig (wie bei einem leeren grid) funktioniert es nicht. Wie kann ich das implementieren?

InformationsquelleAutor philcruz | 2009-06-03

  1. 2

    Dieser arbeitete für mich:

    <mx:Label xmlns:mx="http://www.adobe.com/2006/mxml">
<mx:Script>
    <![CDATA[
        import mx.controls.AdvancedDataGrid;

        private var handleDataChangedEnabled:Boolean = false;

        override public function set data(value:Object):void {
            super.data = value;

            if (!handleDataChangedEnabled) {
                addEventListener("dataChange", handleDataChanged);
            }
        }

        public function handleDataChanged(event:Event):void {
            this.text = String(listData.rowIndex + (listData.owner as AdvancedDataGrid).verticalScrollPosition + 1);
        }
    ]]>
</mx:Script>

    Natürlich, Sie würde sich ändern müssen AdvancedDataGrid an die DataGrid.

    Cheers.

    InformationsquelleAutor Matt

  2. 0

    sicherzustellen, dass der dataProvider-Komponente hat eine eindeutige Spalte oder Eigenschaft, dann nicht anzeigen, dass die Spalten - /Sachschäden, wenn Sie nicht gewohnt.
    Der Schlüssel ist die dataProvider -

    InformationsquelleAutor acromm

  3. 0

    Nur verwenden Sie diese Klasse als Ihre itemRenderer:
    RowNumColumnRenderer.als

    package
{
    import mx.collections.IList;
    import mx.controls.AdvancedDataGrid;
    import mx.controls.Label;
    import mx.controls.listClasses.ListBase;

    public class RowNumColumnRenderer extends Label
    {
        override public function set data(value:Object):void
        {
            super.data = value;
            if (listData != null)
                this.text = (AdvancedDataGrid(listData.owner).itemRendererToIndex(this) + 1).toString();
        }
    }
}

    InformationsquelleAutor Freddie Zero

  4. -1

    War ich in der Lage, dies zu tun durch die Implementierung einer benutzerdefinierten itemRenderer, RowNumberRenderer.als

    package com.domain
{
    import mx.collections.IList;
    import mx.controls.Label;
    import mx.controls.listClasses.ListBase;

    public class RowNumberRenderer extends Label
    {
        public function RowNumberRenderer()
        {
            super();
        }

        override public function set data(value:Object):void
        {
            super.data = value;
            this.text = String(IList(ListBase(listData.owner).dataProvider).getItemIndex(data) + 1);                     
        }

    }
}

    InformationsquelleAutor philcruz

  5. -1

    wie etwa die folgenden:

    RendererRowIndexPlusOne.as 
package
{
    import mx.controls.Label;
    import mx.utils.StringUtil;
    import mx.utils.ObjectUtil; 

    public class RendererRowIndexPlusOne extends Label
    {   
        public override function set data(item:Object):void {
            super.data = item; 

            trace('listData.label ' + listData.label);
            trace('listData.rowIndex ' + listData.rowIndex);
            trace('listData.columnIndex ' + listData.columnIndex);
            trace('listData.owner ' + listData.owner);

            text = String(listData.rowIndex + 1);
        }
    }
}

    InformationsquelleAutor Alex Lee

Schreibe einen Kommentar