Flex-Timer-Beispiel

Ich versuche, mit timer im flex. Ich bezog mich auf dieses Beispiel : Timer : blog.flexexamples.com.

Hier ist, was ich erreichen will:

Ich möchte, um den timer zu starten, zeigt Minuten verstrichen da timer
gestartet. Es sollte unabhängig von der region sind Sie in.(
gleich welcher zone Sie sich befinden, timer sollte einwandfrei funktionieren
jede zone).

Timer fortsetzen sollte, sofern nicht eine bestimmte Schaltfläche geklickt wird, wo ich will
zeigen Sie die verstrichene Zeit in Minuten, die in einer Alert-Box und dann timer starten soll wieder von 0 an.

Ich habe versucht mein Beispiel, aber es funktioniert nicht richtig.

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
                layout="vertical"
                verticalAlign="middle"
                backgroundColor="white"
                creationComplete="init()">

    <mx:Script>
        <![CDATA[
            import flash.events.TimerEvent;
            import flash.utils.Timer;

            import mx.controls.Alert;
            private const TIMER_INTERVAL:Number = 10;

            private var baseTimer:int;

            private var t:Timer;

            private function init():void {
                t = new Timer(TIMER_INTERVAL);
                t.addEventListener(TimerEvent.TIMER, updateTimer);
            }

            private function updateTimer(evt:TimerEvent):void {
                var d:Date = new Date(getTimer()-baseTimer);
                var min:String = (d.minutes).toString();
                var sec:String = (d.seconds).toString();

                counter.text = String(min+"."+sec);
            }

            private function startTimer():void {

                baseTimer = getTimer();
                t.start();
            }

            private function stopTimer():void {
                t.stop();
            }
        ]]>
    </mx:Script>

    <mx:ApplicationControlBar dock="true">
        <mx:Button label="Start timer" click="startTimer()" />
        <mx:Button label="Stop timer" click="stopTimer()" />
    </mx:ApplicationControlBar>

    <mx:Label id="counter" fontSize="96" />
</mx:Application>

Kann jemand sagen, was ist das problem ? Wie es zu lösen ?

EDIT :
Wenn ich dieses Beispiel auf meinen pc, der timer beginnt von 30,0 bis es 59.59 erreicht und dann dreht er sich zurück auf 0.0 und startet dann wieder......Nun, Was ich will, ist zu Beginn von 0,0 und weiter " das zählen von Minuten bis einige button geklickt wird ... und diese Arbeit sollte in jedem Zeitzonen

  • Sie sollten derjenige sein zu sagen, was das problem ist! Was mache ich falsch? Wie können wir helfen? "Es funktioniert nicht" nicht wirklich geben keine Hinweise.
  • Wenn ich dieses Beispiel auf meinen pc, der timer beginnt von 30,0 bis es 59.59 erreicht und dann dreht er sich zurück auf 0.0 und startet dann wieder......Was ich will ist zu Beginn von 0,0 und weiter " das zählen von Minuten bis einige button geklickt wird ... und diese Arbeit sollte in jedem Zeitzonen
InformationsquelleAutor tomjerry | 2011-12-09
  1. 6

    Ihren Anwendungsfall erfordert nicht die Verwendung von Date() und/oder Zeitzonen. Alles, was Sie tun müssen, ist, zählt man die Sekunden verstrichen, und Timer bietet Ihnen eine einfache Möglichkeit, dies zu tun: stellen Sie das Intervall auf 1000 (Eine Zahl pro Sekunde) und der Verwendung Timer.currentCount. Dann alles, was Sie tun müssen, ist zu berechnen, Minuten und Sekunden anzuzeigen. Unten ist eine Implementierung können Sie integrieren in Ihre bestehende mxml:

    private function init():void {
    t = new Timer(1000);
    t.addEventListener(TimerEvent.TIMER, updateTimer);
}

//it's good practice to separate event handler from functional method
private function updateTimer(evt:TimerEvent):void {
    display (t.currentCount);
}

private function display ( count : int ) : void {
    var minutes : int = count / 60; //divide by 60 to get the minutes
    var seconds : int = count % 60; //use modulo operator to get the "rest"
    var min : String = minutes < 10 ? "0" + minutes : "" + minutes; //add leading zero if necessary
    var sec : String = seconds < 10 ? "0" + seconds : "" + seconds;

    counter.text = min+":"+sec; //no need to cast to String if you use "" + something
}

private function startTimer():void {
    t.start();
}

private function stopTimer():void {
    t.stop();
    t.reset();
    display (0); //reset the display
}
    • Wird diese Arbeit unabhängig von Zeitzonen ? Ich meine keine Probleme mit UTC hier ?
    • und wenn es geht über die 60 min Marke, ich will es weiterhin zeigt die Zeit in Minuten, die nur.. so .. 61:15 .. 61 min, 15 Sek vergangen ..
    • Beides ist in diesem Beispiel der Fall: Es gibt keine UTC, wenn Sie einfach nur zählen, wie oft der timer aufgerufen wird. Und da gibt es keine "Stunden", die Minuten werden weiter zunehmen.
    • danke für deine Antwort 🙂 ... ich bin mit den code .. akzeptiere Ihre Antwort darauf geben, wenn keine Frage kommt .. Naja, schon +1 von mir für diese Antwort ..
    InformationsquelleAutor weltraumpirat
  2. 0

    Das Beispiel, das Sie sich beziehen, ist die Dinge ein bisschen zu kompliziert für Ihr spezielles problem. Hier ist ein kleines Beispiel, wie können Sie zeigen, dass die Minuten mit einem einfachen Timer:

    private const TIMER_INTERVAL:Number = 1000*60;
private var t:Timer;

private function init():void {
    t = new Timer(TIMER_INTERVAL);
    t.addEventListener(TimerEvent.TIMER, updateTimer);
    counter.text = "0";
}

private function updateTimer(evt:TimerEvent):void {

    counter.text = String(t.currentCount);
}

private function startTimer():void {

    t.start();
}

private function stopTimer():void {

    t.stop();

    //if you want the timer to reset make sure to reset your text also
    /*
    t.reset();
    counter.text = "0";
    */
}
    • Ich lief Ihr code .. aber, immer noch nach 5 Minuten .. es zeigt 0 nur .. die Zeit ändert sich nicht ..
    • und wenn es geht über die 60 min Marke, ich will es weiterhin zeigt die Zeit in Minuten, die nur.. so .. 61:15 .. 61 min, 15 sec vergangen
    • Antwort, die für alle Werke dieser
    • Ihre TIMER_INTERVAL 60 * 1000 Millisekunden == 1 minute.
    • In der OP bittet er um showing minutes elapsed also, warum habe ich mich für den einfachsten Weg. Ihre Lösung ist vollständiger (daher mein +1) (@tomjerry, wenn ich den code testen kann ich der Vergangenheit in der 5-Minuten-Marke btw)
    InformationsquelleAutor Rick van Mook
Schreibe einen Kommentar