Funktion Ähnlich importxml in Excel?

Ich Liebe Google Docs-Funktion =importxml (), aber würde gerne wissen, ob es war alles wie es in Excel 2010? Ich kann nicht scheinen, einen Weg zu finden, damit das Programm automatisch ziehen Sie Daten aus einer verknüpften XML-Datei.

Zum Beispiel, ich würde gerne in der Lage, eine Spalte mit der überschrift "Item Name", dann haben Sie die nächste Spalte, fügen Sie den Benutzer eingegebenen Elementnamen in der vorhergehenden Spalte dieser url

http://util.eveuniversity.org/xml/itemLookup.php?name=

und dann analysieren Sie die resultierende XML-Datei zurückgeben die Typ-ID. Dies wird erreicht, in google docs mit

=importxml(concatenate("http://util.eveuniversity.org/xml/itemLookup.php?name=",A3);"//itemLookup/typeID")

A3 ist die Spalte, die den Namen des Elements, in diesem Fall wäre Tritanium, und importiert die Daten, die form der resultierenden XML-Datei

http://util.eveuniversity.org/xml/itemLookup.php?name=Tritanium

gibt den Wert 34.

Ich habe eine Liste mit etwa 20 item-Namen, die google docs aktualisiert automatisch die item-ID auf jedes mal, wenn ich die Datei öffnen. Gibt es eine Möglichkeit Excel 2010 zu replizieren diese Funktion?

Dank!

Wird

Was ist ein anderer Wert neben Tritanium, und was sollte Sie zurückkehren?
util.eveuniversity.org/xml/itemLookup.php?name=Pyerite ist ein weiteres Beispiel, und es sollte den Wert 35.--------wenn ein drittes Beispiel ist erforderlich, util.eveuniversity.org/xml/itemLookup.php?name=Isogen zurückkehren sollte 37.
Anscheinend Excel 2013 hat ein FilterXML - Funktion, die ähnlich ist. Mit 2010, ich denke, Sie würde tun müssen, eine Reihe von separaten Daten - >Importiert. Ich habe noch nie importiert XML, bevor, obwohl, so nehmen Sie nicht mein Wort für es. Interessante Frage.

InformationsquelleAutor wKavey | 2013-01-04

2

Müssen Sie schreiben Sie Ihre eigenen UDF.

Ein Weg wäre, um die MSXML2 Bibliothek, so etwas wie dieses:
```
Function GetData(sName As String, sItem As String, Optional sURL = "") As Variant
    Dim oHttp As New MSXML2.XMLHTTP60
    Dim xmlResp As MSXML2.DOMDocument60
    Dim result As Variant
    On Error GoTo EH

    If sURL = "" Then
        sURL = "http://util.eveuniversity.org/xml/itemLookup.php?name="
    End If

    'open the request and send it
    oHttp.Open "GET", sURL & sName, False
    oHttp.Send

    'get the response as xml
    Set xmlResp = oHttp.responseXML
    ' get Item
    GetData = xmlResp.getElementsByTagName(sItem).Item(0).Text

    ' Examine output of these in the Immediate window
    Debug.Print sName
    Debug.Print xmlResp.XML

CleanUp:
    On Error Resume Next
    Set xmlResp = Nothing
    Set oHttp = Nothing
Exit Function
EH:
    GetData = CVErr(xlErrValue)
    GoTo CleanUp
End Function
```
Rufen Sie es wie folgt aus (wobei A5 enthält die erforderlichen typeName)
```
=GetData(A5, "typeID")
```
Thx @doug, vergaß zu erwähnen, die Referenz. Fwiw Sie können natürlich, verwenden Sie späten Bindung anstatt
Ich habe es ausprobiert, aber als ich versuchte, verwenden Sie die Funktion, die es gab mir einen compile-Fehler "benutzerdefinierter Typ nicht definiert". Irgendwelche Ideen? Update: legen Sie die Referenz-und es war in der Lage zu verarbeiten, aber es ist wieder eine -1 bedeutet, dass die API nicht finden können, das Element, das eingetragen wurde, nach =dem Namen. (Ex: http://util.eveuniversity.org/xml/itemLookup.php?name=itemnoexist)
Ich vergaß zu erwähnen (als Doug darauf hingewiesen) Sie müssen einen Verweis: aus Tools Menü References scrollen Sie nach unten, um Microsoft XML, v6.0.
Tests ok, auf mein Ende, ich bekomme die Werte, die Sie erwähnt in den OP. Siehe update für einige debug-Hinweise
Nevermind - es ist in Ordnung jetzt. Ich weiß nicht, was passiert ist, aber Dank eine Tonne für die Antwort! Ich sollte in der Lage zu bauen, diese für andere XML-Dateien und andere APIs, die ich möglicherweise verwenden müssen, wie gut.

InformationsquelleAutor chris neilsen
4

Frage ist, ab 2013 ist einige Zeit vergangen...

Mit Excel 2013 gibt es eine Funktion WEBSERVICE laden von XML-Dokumenten, das würde genau das tun, was Sie wollen.

Gibt es auch FILTERXML die Suche geladenen XML-Dokuments mit XPath.

InformationsquelleAutor vav

Function ImportXML(url As String, query As String)

    Dim document    As MSXML2.DOMDocument60
    Dim http        As New MSXML2.XMLHTTP60

    http.Open "GET", url, False
    http.send

    Set document = http.responseXML

    ImportXML = document.SelectSingleNode(query).nodeTypedValue

End Function

Toll, ich könnte wirklich verwenden dies als die Excel-version des Google-Sheet-Variante...

InformationsquelleAutor Neil McGuigan

Der "From Web" - Funktion auf dem Menü "Daten" ziehen die online-Daten direkt in die Tabellenkalkulation. XML-Daten importieren ist auch unter dem Aus Anderen Quellen sub-Menü auch aufgeführt auf der Daten Menü.

Erstellt-verbindungen verwaltet werden, über die Verbindungen der Dialog-box auf dem Menü "Daten".

Beispielcode verwenden Makros aufzeichnen, während Sie ein 'From Web' Verbindung:

Sub Macro1()
' Macro1 Macro
With ActiveSheet.QueryTables.Add(Connection:= _
        "URL;http://en.wikipedia.org/wiki/Microsoft_Excel" _
        , Destination:=Range("$A$1"))
        .Name = _
        "?affID=110195&tt=270912_7a_3912_6&babsrc=HP_ss&mntrId=3e2fc48700000000000088532eb428ec"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .BackgroundQuery = True
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .WebSelectionType = xlEntirePage
        .WebFormatting = xlWebFormattingNone
        .WebPreFormattedTextToColumns = True
        .WebConsecutiveDelimitersAsOne = True
        .WebSingleBlockTextImport = False
        .WebDisableDateRecognition = False
        .WebDisableRedirections = False
        .Refresh BackgroundQuery:=False
    End With
End Sub

InformationsquelleAutor sendbits

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.