Gewusst wie: ausblenden (und wieder einblenden) soft-Tastatur, während TEdit ist in Schwerpunkt DELPHI XE7

Können Sie mir helfen , wie ausblenden (und wieder einblenden) soft-Tastatur, während TEdit ist in den Fokus?

Versucht InputMethodManager inputMethodManager = (InputMethodManager) activity.getSystemService(Activity.INPUT_METHOD_SERVICE); inputMethodManager.hideSoftInputFromWindow(activity.getCurrentFocus().getWindowToken(), 0);?
Siehe hier: [Nah - /ausblenden der Android Soft-Tastatur][1] [1]: stackoverflow.com/questions/1109022/...
Ich brauche Lösung für DELPHI

InformationsquelleAutor pudnivec74 | 2014-12-10

  1. 9

    Ich habe eine Lösung:

    1. In der .dpr set VKAutoShowMode zu Nie

      begin
  Application.Initialize;
  VKAutoShowMode := TVKAutoShowMode.Never;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

    2. Show soft-Tastatur auf die form (zum Beispiel TEdit.OnEnter-Ereignis):

      var
  FService: IFMXVirtualKeyboardService;
begin
  TPlatformServices.Current.SupportsPlatformService(IFMXVirtualKeyboardService, IInterface(FService));
  if (FService <> nil) then
  begin
    FService.ShowVirtualKeyboard(Edit1);
    Edit1.SetFocus;
  end;

    3. Ausblenden der soft-Tastatur auf die form (Edit1 wird noch konzentriert mit versteckten soft-Tastatur):

      var
  FService: IFMXVirtualKeyboardService;
begin
  TPlatformServices.Current.SupportsPlatformService(IFMXVirtualKeyboardService, IInterface(FService));
  if (FService <> nil) then
  begin
    FService.HideVirtualKeyboard;
    Edit1.SetFocus;
  end;
    Danke , diese information ist gut und funktioniert für mich auf Delphi XE7 mit android. Aber, ich habe eine Frage, ist dies der einfache Weg ?
    Derzeit ja. Embarcadero arbeiten auf die Korrektur von Fehlern in dieser Angelegenheit. Reparatur freigegeben werden sollen, in der nächsten version von Delphi.
    Funktioniert nicht mit Delphi 10.2 (Tokyo) und Android 6. Die Tastatur bleibt sichtbar

    InformationsquelleAutor pudnivec74

  2. 4

    Die Lösung ist sehr einfach und straight forward:

    Wickeln Sie das original IFMXVirtualKeyboardService mit Ihrem eigenen und überprüfen, ob die Steuerung soll über eine virtuelle Tastatur angezeigt wird oder nicht.

    Hier ist eine komplette wrapper für diese und nicht beschränkt auf Android

    unit Common.FMX.VirtualKeyboardService;

interface

uses
  System.Classes,
  System.Generics.Collections,
  FMX.Types,
  FMX.VirtualKeyboard;

type
  TVirtualKeyboardService = class( TComponent, IFMXVirtualKeyboardService )
  private
    FObjects: TList<TFmxObject>;
    FOriginalService: IFMXVirtualKeyboardService;
    constructor Create( AOwner: TComponent );
    class constructor Create;
  protected
    function GetVirtualKeyboardState: TVirtualKeyboardStates;
    function HideVirtualKeyboard: Boolean;
    procedure SetTransientState( Value: Boolean );
    function ShowVirtualKeyboard( const AControl: TFmxObject ): Boolean;
    procedure Notification( AComponent: TComponent; Operation: TOperation ); override;
  public
    class function Current: TVirtualKeyboardService;
    destructor Destroy; override;

    procedure AddOverrideObject( AObject: TFmxObject );
    procedure RemoveOverrideObject( AObject: TFmxObject );
    function IsOverriddenObject( AObject: TFmxObject ): Boolean;
  private
    class var _current: TVirtualKeyboardService;
  end;

implementation

uses
  FMX.Forms,
  FMX.Platform,
  System.SysUtils;

{ TVirtualKeyboardService }

constructor TVirtualKeyboardService.Create( AOwner: TComponent );
begin
  inherited Create( AOwner );

  FObjects := TList<TFmxObject>.Create;

  if TPlatformServices.Current.SupportsPlatformService( IFMXVirtualKeyboardService, FOriginalService ) then
  begin
    TPlatformServices.Current.RemovePlatformService( IFMXVirtualKeyboardService );
    TPlatformServices.Current.AddPlatformService( IFMXVirtualKeyboardService, Self );
  end;
end;

procedure TVirtualKeyboardService.AddOverrideObject( AObject: TFmxObject );
begin
  if Supports( AObject, IVirtualKeyboardControl ) and not FObjects.Contains( AObject ) then
  begin
    FObjects.Add( AObject );
    Self.FreeNotification( AObject );
  end;
end;

class constructor TVirtualKeyboardService.Create;
begin
  TVirtualKeyboardService._current := TVirtualKeyboardService.Create( Application );
end;

class function TVirtualKeyboardService.Current: TVirtualKeyboardService;
begin
  Result := TVirtualKeyboardService._current;
end;

destructor TVirtualKeyboardService.Destroy;
begin
  if Assigned( FOriginalService ) then
  begin
    TPlatformServices.Current.RemovePlatformService( IFMXVirtualKeyboardService );
    TPlatformServices.Current.AddPlatformService( IFMXVirtualKeyboardService, FOriginalService );
  end;
  FObjects.Free;
  inherited;
end;

function TVirtualKeyboardService.GetVirtualKeyboardState: TVirtualKeyboardStates;
begin
  Result := FOriginalService.VirtualKeyboardState;
end;

function TVirtualKeyboardService.HideVirtualKeyboard: Boolean;
begin
  Result := FOriginalService.HideVirtualKeyboard;
end;

function TVirtualKeyboardService.IsOverriddenObject( AObject: TFmxObject ): Boolean;
begin
  Result := FObjects.Contains( AObject );
end;

procedure TVirtualKeyboardService.Notification( AComponent: TComponent; Operation: TOperation );
begin
  inherited;
  if ( Operation = opRemove ) and ( AComponent is TFmxObject ) then
  begin
    RemoveOverrideObject( AComponent as TFmxObject );
  end;
end;

procedure TVirtualKeyboardService.RemoveOverrideObject( AObject: TFmxObject );
begin
  if FObjects.Contains( AObject ) then
  begin
    FObjects.Remove( AObject );
    Self.RemoveFreeNotification( AObject );
  end;
end;

procedure TVirtualKeyboardService.SetTransientState( Value: Boolean );
begin
  FOriginalService.SetTransientState( Value );
end;

function TVirtualKeyboardService.ShowVirtualKeyboard( const AControl: TFmxObject ): Boolean;
begin
  if IsOverriddenObject( AControl ) then
    begin
      HideVirtualKeyboard;
      Result := False;
    end
  else
    Result := FOriginalService.ShowVirtualKeyboard( AControl );
end;

end.

    Wenn Sie möchten, deaktivieren Sie die virtuelle Tastatur für die Ihrer Kontrolle haben, rufen Sie einfach

    uses
  Common.FMX.VirtualKeyboardService;

procedure TForm1.AfterConstruction;
begin
  inherited;
  TVirtualKeyboardService.AddOverrideObject( Edit1 );
end;

    Thats it.

    InformationsquelleAutor Sir Rufo

  3. 3

    Versuchen, variable VKAutoShowMode im FMX.Typen

    InformationsquelleAutor

  4. 2

    Fügen Sie einfach die folgenden Zeilen von code im OnClick-Ereignis des Steuerelements. Es scheint gut zu funktionieren.

    edit1.resetfocus;
    edit1.setfocus;

    Ich habe versucht, diese für eine TSpinBox auf Android-und Windows-FMX, und es funktioniert eine Menge Zeit.

    InformationsquelleAutor Loc Nguyen

  5. 0

    Fand gerade eine wirklich einfache Lösung.

    In meinem OnKeyDown event und ich bin der überprüfung für vkEnter und ausführen von code. Ich möchte die Tastatur zu schließen, als ich fertig bin.

    Einfach meinen TEdit auf "nicht Aktiviert" und wieder zurück, dh:

    procedure TfrmMain.dtBarCodeKeyDown(Sender: TObject; var Key: Word;
  var KeyChar: Char; Shift: TShiftState);
begin
  if Key = vkReturn then
    begin
      dtBarCode.Enabled := false; //kill the keyboard
      try
        LoadBarCode;
      finally
        dtBarCode.Enabled := true;
      end;
    end;
end;

    Wenn der Benutzer klickt in das Textfeld erneut, die Tastatur kommt zurück.

    Getestet auf Android

    InformationsquelleAutor Maya

  6. -2

    Versuchen Sie es mit folgenden code:

    InputMethodManager inputMethodManager = (InputMethodManager) getSystemService(Activity.INPUT_METHOD_SERVICE);
inputMethodManager.hideSoftInputFromWindow(getCurrentFocus().getWindowToken(), 0);
    Ich brauche Lösung für DELPHI

    InformationsquelleAutor Pratik Dasa

Schreibe einen Kommentar