Gnuplot: Wie laden und anzeigen einzelner numerischer Wert aus der Daten-Datei

Meine Daten-Datei hat diesen Inhalt

# data file for use with gnuplot
# Report 001
# Data as of Tuesday 03-Sep-2013 
total   1976
case1   522 278 146 65  26  7
case2   120 105 15  0   0   0
case3   660 288 202 106 63  1

Mache ich ein Histogramm von dem Fall... Zeilen, die mit dem Skript unten - und das funktioniert. Meine Frage ist: wie kann ich laden Sie die grand Gesamtwert 1976 (neben dem Wort 'Summe') aus der Daten-Datei und entweder (a) speichern Sie in eine variable oder (b) verwenden Sie es direkt im Titel des plot?

Dies ist mein gnuplot-script:

reset
set term png truecolor
set terminal pngcairo size 1024,768 enhanced font 'Segoe UI,10'
set output "output.png"
set style fill solid 1.00
set style histogram rowstacked
set style data histograms
set xlabel "Case"
set ylabel "Frequency"
set boxwidth 0.8
plot for [i=3:7] 'mydata.dat' every ::1 using i:xticlabels(1) with histogram \
notitle, '' every ::1 using 0:2:2 \
with labels \
title "My Title"

Zugunsten der anderen, die versuchen zu label-Histogramme, in meine Daten-Datei, die Spalte nach dem Fall label repräsentiert die Summe der rest der Werte auf die Zeile. Jene Summe zahlen angezeigt werden am oberen Rand jeder Histogramm bar. Zum Beispiel für case1, 522 ist die Summe (278 + 146 + 65 + 26 + 7).

Möchte ich die Anzeige der Gesamtsumme irgendwo auf meiner Karte, sagen, wie die zweite Zeile des Titels oder in einem label. Kann ich eine variable in sprintf in den Titel, aber ich habe nicht herausgefunden syntax zum laden einer "Zelle" Wert ("Zelle" bedeutet row-Spalte-Kreuzung) in eine variable.

Alternativ, wenn mir jemand sagen kann, wie die sum-Funktion, um insgesamt bis 522+120+660 (Lesen Sie aus den Daten der Datei, nicht als Konstanten!) und speichern, die Summe in eine variable, das würde vermeiden das müssen die Gesamtsumme der Daten-Datei, und das würde mich auch sehr glücklich.

Vielen Dank.

InformationsquelleAutor user424855 | 2013-09-03

  1. 12

    Fangen wir mit dem extrahieren eine einzelne Zelle an der Position (row,col). Wenn es einen einzigen Werte, die Sie verwenden können, die stats Befehl zum extrahieren der Werte. Die row und col angegeben mit every und using, wie in einem plot-Befehl. In Ihrem Fall, extrahieren Sie die gesamte Wert:

    # extract the 'total' cell
stats 'mydata.dat' every ::::0 using 2 nooutput
total = int(STATS_min)

    Zur Summe aller Werte in der zweiten Spalte verwenden:

    stats 'mydata.dat' every ::1 using 2 nooutput
total2 = int(STATS_sum)

    Sind und sich schließlich die Summe aller Werte in den Spalten 3:7 in allen Zeilen (D. H. der gleiche wie der Vorherige Befehl, aber ohne Verwendung der gespeicherten Summen) verwenden:

    # sum all values from columns 3:7 from all rows
stats 'mydata.dat' every ::1 using (sum[i=3:7] column(i)) nooutput
total3 = int(STATS_sum)

    Diese Befehle erfordern gnuplot 4.6 arbeiten.

    So, Ihr plotting-Skript könnte wie folgt Aussehen:

    reset
set terminal pngcairo size 1024,768 enhanced
set output "output.png"
set style fill solid 1.00
set style histogram rowstacked
set style data histograms
set xlabel "Case"
set ylabel "Frequency"
set boxwidth 0.8

# extract the 'total' cell
stats 'mydata.dat' every ::::0 using 2 nooutput
total = int(STATS_min)

plot for [i=3:7] 'mydata.dat' every ::1 using i:xtic(1) notitle, \
     '' every ::1 using 0:(s = sum [i=3:7] column(i), s):(sprintf('%d', s)) \
     with labels offset 0,1 title sprintf('total %d', total)

    welche gibt die folgende Ausgabe:

    Gnuplot: Wie laden und anzeigen einzelner numerischer Wert aus der Daten-Datei

    Ah ha!!!! Wunderbare Beispiele für die Verwendung der stats-Befehl zum laden der Zelle mit dem Wert(en).
    Immer ein Vergnügen zu Lesen Ihre Gnuplot related posts, sehr nützliche Sachen 🙂
    Was ist der Doppelpunkt : syntax? Ich verstehe nicht, was ::::0 oder ::1 machen soll - könnte jemand es mir erklären?
    Das ist in der Dokumentation beschrieben, von every im Abschnitt Plot -> data -> every finden Sie unter gnuplot.info/docs_5.0/...

    InformationsquelleAutor Christoph

  2. 1

    Die für linux und ähnliche.

    Wenn Sie nicht wissen, die Nummer der Zeile, wo sich Ihre Daten befinden, aber Sie wissen, es ist in der n-TEN Spalte einer Zeile, wo der Wert der m-TEN Spalte ist x können Sie eine Funktion definieren, die

    get_data(m,x,n,filename)=system('awk "\$'.m.'==\"'.x.'\"{print \$'.n.'}" '.filename)

    und dann verwenden Sie es, zum Beispiel, als

    y = get_data(1,"case2",4,"datafile.txt")

    Verwendung von Daten, die von user424855 

    print y

    zurückkehren sollte 15

    Schön. Sie haben einen kleinen Tippfehler, der Befehl sollte lauten: get_data(m,x,n,filename)=system('awk "\$'.m.'==\"'.x.'\"{print \$'.n.'}" '.filename).
    danke, es ist korrigiert jetzt 🙂

    InformationsquelleAutor boclodoa

Schreibe einen Kommentar