Groovy laden .csv-Dateien

Wie zu Lesen und zu importieren .csv-Datei in groovy on grails. Ich habe .csv-Datei mit Daten und

für den import in die db mit user-interface .

InformationsquelleAutor Srinath | 2010-04-12
  1. 54

    Gibt es wie immer verschiedene Möglichkeiten zum arbeiten mit CSV-Dateien in Groovy.

    Als Groovy ist vollständig kompatibel mit Java, Sie können verwenden Sie eine vorhandene CSV-libararies, z.B. OpenCSV.

    Abhängig von der Komplexität der CSV-Datei, die Sie verwenden, Sie können auch die standard-Datei - /string-handling-Möglichkeiten von Groovy:

    def sql = Sql.newInstance("jdbc:mysql://localhost:3306/mydb",
  "user", "pswd", "com.mysql.jdbc.Driver")
def people = sql.dataSet("PERSON")
new File("users.csv").splitEachLine(",") {fields ->
  people.add(
    first_name: fields[0],
    last_name: fields[1],
    email: fields[2]
  )
}

    EDIT:
    Kelly Robinson schrieb gerade einen schönen blog-post über die verschiedenen Möglichkeiten, die verfügbar sind für die Arbeit mit CSV-Dateien in Groovy.

    EDIT #2:
    Als Leonard Axelsson kürzlich veröffentlichte version 1.0 seiner GroovyCVS Bibliothek, ich dachte, ich sollte auf jeden Fall fügen Sie diese zu der Liste der Optionen.

    • Ich habe eine schriftliche groovified wrapper OpenCSV, die aufgerufen wird, GroovyCSV und macht das arbeiten mit csv in Groovy viel einfacher und Redewendungen. Es ist erhältlich auf xlson.com/groovycsv
    InformationsquelleAutor Christoph Metzendorf
  2. 9

    Mit xlson ist GroovyCSV:

    @Grab('com.xlson.groovycsv:groovycsv:1.1')
import static com.xlson.groovycsv.CsvParser.parseCsv

for(line in parseCsv(new FileReader('countries.csv'), separator: ';')) {
    println "Country=$line.COUNTRY, Capital=$line.CAPITAL"
}

    Die Feldnamen werden aus der Kopfzeile der CSV-Datei.

    Wenn die CSV-Datei keinen header besitzt, können Sie den Feldnamen programmgesteuert.

    InformationsquelleAutor Nicolas Raoul
  3. 1

    Mit Apache Commons CSV:

    @Grab('org.apache.commons:commons-csv:1.2')
import org.apache.commons.csv.CSVParser
import static org.apache.commons.csv.CSVFormat.*

import java.nio.file.Paths

Paths.get('countryInfo.txt').withReader { reader ->
    CSVParser csv = new CSVParser(reader, DEFAULT.withHeader())

    for (record in csv.iterator()) {
        println record.dump()
    }
}

    Commons-CSV hat gute API-und ich empfehlen, dass.

    Mit GroovyCSV:

    @Grab('com.xlson.groovycsv:groovycsv:0.2')
import com.xlson.groovycsv.CsvParser

def csv = '''Name,Lastname
Mark,Andersson
Pete,Hansen'''

def data = new CsvParser().parse(csv)
for(line in data) {
    println "$line.Name $line.Lastname"
}

    (Entnommen aus es Proben)

    Last resort: Regulärer Ausdruck.

    Hier, wie ich Analysierte eine Datei, die enthält möglicherweise zitiert escaped string im vierten Spalte:

        File detailedStatsFile = new File("stats.csv");
    detailedStatsFile.eachLine { line, number ->
        //Number Of Executions, Total Milliseconds, Milliseconds per execution, "Type"
        def match = line =~ /([^,]*?),\s*([^,]*?),\s*([^,]*?),\s*(?:([^",]+)|(?:"((?:[^\\"]++(?:\\")?)++)"))$/; //"

        if (!match.matches())
            continue;

        def numberOfExecs = Integer.valueOf(match.group(1));
        def totalMillis = Integer.valueOf(match.group(2));
        def detailedStatName = match.group(4);
        if (detailedStatName == null)
            detailedStatName = match.group(5).replaceAll('\\"','"');
    • Erste Methode fehlschlägt, mit groovy.lang.MissingMethodException: No signature of method: sun.nio.fs.UnixPath.withReader() is applicable for argument types: (myscript$_run_closure1) values: [myscript$_run_closure1@536f2a7e]
    InformationsquelleAutor Ondra Žižka
  4. 1

    Beispiel mit opencsv

    @Grab('com.opencsv:opencsv:4.0')
import com.opencsv.CSVReader
import com.opencsv.CSVWriter

class TestCsvReader {


    static main(args) {
        def csv = '''"a","b","c"
"d","e","f"
'''
        def Reader csvFileReader = new StringReader(csv)
        def Writer csvFileWriter = new PrintWriter(System.out)
        def CSVReader reader = new CSVReader(csvFileReader)
        def CSVWriter writer = new CSVWriter(csvFileWriter)

        reader.iterator().each { fields ->
            writer.writeNext(fields)
        }
        reader.close()
        writer.close()
    }
}
    InformationsquelleAutor Haim Raman
  5. 0

    Bevorzuge ich ein leichtes zwicken auf der akzeptierten Antwort: zip-Spalten und-Werte zusammen, im Gegensatz zu der Indizierung jeder Anzahl. Das Ergebnis ist etwas kürzer-code.

    def sql = Sql.newInstance("jdbc:mysql://localhost:3306/mydb", "user", "pswd", "com.mysql.jdbc.Driver")
def people = sql.dataSet("PERSON")
def columns = ['first_name', 'last_name', 'email']
new File("users.csv").splitEachLine(",") {values ->
    people.add([columns, values].transpose().collectEntries())
}
    InformationsquelleAutor jaco0646
Schreibe einen Kommentar