Hinzufügen einer Verknüpfung zu einer Schaltfläche in Flash/Actionscript

Vorausgesetzt dein button hat den Instanznamen "myButton", auf dem Rahmen, wo Sie Ihre Schaltfläche in der timeline, fügen Sie die folgenden (oder ähnliche) Actionscript.

AS2

myButton.onPress = function()
{
   getURL("http://stackoverflow.com", "_blank");
}

AS3

import flash.events.MouseEvent;
import flash.net.navigateToURL;
import flash.net.URLRequest;
import flash.net.URLRequestMethod;

myButton.addEventListener(MouseEvent.CLICK, onMouseClick);
function onMouseClick(event:MouseEvent):void
{
   var request:URLRequest = new URLRequest("http://stackoverflow.com");
   request.method = URLRequestMethod.GET;
   var target:String = "_blank";
   navigateToURL(request, target);
}

Abwärtskompatibel getURL für AS3

/**
 * Backwards compatibility for global getURL function.
 *
 * @param url     Url to go to.
 * @param method  'get' or 'post'.
 * @param target  Window target frame [ex. '_blank'].
 */
public static function getURL(url:String, target:String = '_blank', method:String = 'get'):void
{
    method = method.toUpperCase();
    target = target.toLowerCase();

    if (method != URLRequestMethod.POST && method != URLRequestMethod.GET) method = URLRequestMethod.GET;
    if (target != "_self" && target != "_blank" && target != "_parent" && target != "_top") target = "_blank";
    var request:URLRequest = new URLRequest(url);
    request.method = method;
    navigateToURL(request, target);
}

Beachten Sie, dass in beiden AS2-und AS3-Sie schreiben könnten, diesen code in eine Klasse und legen Sie die Klasse als export-Klasse, für Ihren button/movieclip. Das ist wohl ein bisschen komplexer aber.