Holen Sie Benutzer benutzerdefinierten Felder ohne SOQL (wie $User in Formeln)?

Habe ich einige benutzerdefinierte Felder auf meiner Benutzer-Objekt, das ich für den Zugriff mit APEX VisualForce-code in meiner trigger. Wenn ich es auf einem Feld Formel ich verwenden, ein schickes $User Referenz, wie diese:

$User.my_prop__c

Von APEX ich habe eine Abfrage des User-Objekts durch Benutzerkennung wie diese:

[select my_prop__c from User where id = :UserInfo.getUserId()].my_prop__c;

Gibt es etwas, gebacken in APEX schon, das würde ich bei den user-Eigenschaften, ohne die SOQL-Abfrage? Wenn nicht, kennt jemand eine utility-Klasse für lazy loading und caching-Benutzer-Eigenschaften, so dass der overhead ist minimal.

InformationsquelleAutor twamley | 2012-07-10
  1. 2

    Ich würde etwas ähnliches wie den folgenden code Beispiel. Es verwendet ein singleton-Muster zu statisch speichern die Informationen, die im Arbeitsspeicher für die Dauer der Transaktion. Es ist ähnlich wie lazy loading, twamley vorgeschlagen, aber ich denke, das ist eine viel einfachere Ansatz.

    Verwendung 1: UserUtil.CurrentUser.E-Mail;

    Verwendung 2: Benutzer someUser = UserUtil.getUser(someUserId);

    Dieser ermöglicht Ihnen den Zugriff auf die gleichen Informationen über den aktuellen Benutzer oder für andere Benutzer in das system. Beachten Sie die queryUsers Methode nur gibt ein query-Ergebnis. Dies macht es einfach, hinzufügen und entfernen von Feldern aus der Abfrage, wie er ist isoliert in seiner eigenen Methode halten die Dinge einfach.

    Hinweis: beachten Sie, dass dieser code zieht alle Benutzer bei der Verwendung. Die meisten Organisationen nicht mit mehreren Hunderten von Benutzern, so dass die heap-Größe sollte nicht von Belang sein. Aber wenn es ist, können Sie ändern Sie einfach die queryUsers () - Methode, um nur die Rückkehr Benutzer aktiv sind, oder filter nach unten, basierend auf anderen Kriterien.

    public class UserUtil {
//Protected Members
private static final UserUtil instance = new UserUtil();
private Map<Id, User> mapUsers;

//Properties
public static User CurrentUser {
    get { return getUser(UserInfo.getUserId()); }
}

//Constructor
private UserUtil() {
    mapUsers = new Map<Id, User>(queryUsers());
}

//Public Methods
public static User getUser(Id userId) {
    if (instance.mapUsers.containsKey(userId)) {
        return instance.mapUsers.get(userId);
    }
    else {
        throw new InvalidUserIdException('Unable to locate user id: ' + userId);
    }
}

//Private Methods
private List<User> queryUsers() {
    return [SELECT 
                Id
                , Name
                , UserName
                , Email
                , Alias 
            FROM 
                User];
}

//Internal Classes
public class InvalidUserIdException extends Exception {}

    }

    • Schöne Arbeit. Ich mag das singleton-pattern-Ansatz und Rückkehr das Ergebnis der Abfrage ist eine nette Geste, auch.
    • Aber wird es für den neuen Benutzer ? Ich denke, Sie sind die Abfrage des Benutzer-Objekt nur einmal
    InformationsquelleAutor John De Santiago
  2. 0

    Schrieb ich meine eigene utility-Klasse. Ich bin immer noch daran interessiert, bessere Techniken, aber.
    Diese utility-Klasse lazy geladen wird, wenn die erste Eigenschaft zugegriffen wird. Update_Geschlossen_Gewonnen_Chancen__c und Set_Chancen_auf_Geschlossen_Gewonnen__c sind meine benutzerdefinierten Felder auf dem Benutzer-Objekt (sichtbar nur für Systemadministratoren, damit die Menschen können nicht aktualisieren Sie die Berechtigungen).

    public with sharing class MyUserInfo {
    private Id userId;
    private User myUser; //Hold onto the user object once we've loaded it

    //Default constructor uses the active user id
    public MyUserInfo() {
        userId = UserInfo.getUserId();
    }

    //Secondary constructor accepts a user id as a parameter
    public MyUserInfo(Id someOtherUserId) {
        userId = someOtherUserId;       
    }

    //Only called one time when we first need it so grab all of the custom fields now
    private void LazyLoadUser() {
        System.AssertNotEquals(null, userId);
        myUser = [
            SELECT Update_Closed_Won_Opportunities__c, Set_Opportunities_To_Closed_Won__c
            FROM User 
            WHERE id = :userId
        ];
        System.AssertNotEquals(null, myUser, 'Unable to load user with id ' + userId); //could return defaults instead
    }

    //Getters (be sure to include each field in the SOQL of LazyLoadUser)
    public boolean UpdateClosedWonOpportunities { get {
        if (myUser == null) LazyLoadUser();
        return myUser.Update_Closed_Won_Opportunities__c;
    } }
    public boolean SetOpportunitiesToClosedWon { get {
        if (myUser == null) LazyLoadUser();
        return myUser.Set_Opportunities_To_Closed_Won__c;
    } }
}

    Hier ist mein trigger die Verwendung dieser Klasse. Die erste Zeile myUserInfo = new MyUserInfo(); nicht ausführen, SOQL. Das wird nicht passieren, bis die erste custom-get-Eigenschaft verwendet wird. Nachfolgende Aufrufe nicht brauchen, SOQL. 

    trigger LockClosedOpportunity on Opportunity (before update) {
    MyUserInfo myUserInfo = new MyUserInfo();
    for (Opportunity o : trigger.old)
    {
        if (!myUserInfo.UpdateClosedWonOpportunities && o.StageName == 'Closed Won')
            trigger.newMap.get(o.Id).addError('You do not have permission to change an Opportunity after it has been set to Closed Won.');
    }
    for (Opportunity o : trigger.new)
    {
        if ( !myUserInfo.SetOpportunitiesToClosedWon && o.StageName == 'Closed Won' && trigger.oldMap.get(o.Id).StageName != 'Closed Won' )
            o.addError('You do not have permission to set an Opportunity to Closed Won.');
    }
}

    Liest es ähnlich $User in Formeln und ich habe keine sorgen zu machen über Heften auf mehreren SOQL Anrufe bei einem (oder null) reicht.

    InformationsquelleAutor twamley
Schreibe einen Kommentar