Kann der Webbereitstellungs-Agent auf einem anderen Port als 80 auf IIS6 ausgeführt werden?

Gibt es ein paar Möglichkeiten, dies zu tun:

Option 1: Deinstallieren und neu installieren die Angabe eines anderen Ports:

msiexec /I WebDeploy_x86_en-US.msi /passive ADDLOCAL=ALL LISTENURL=http://+:8172/MsDeployAgentService

Die Befehlszeile installiert das MsDeployAgentService und konfiguriert auf port 8172 wie auf IIS7.

Option 2: Re-konfigurieren Sie den Bestehenden Service auf port 8172:

1. Stoppen Sie die msdepsvc (net stop msdepsvc)

2. Bearbeiten Sie die folgenden registry-Wert:

   HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters\ListenUrl
   

   Werde es so Aussehen:

   http://+:80/MsDeployAgentService
   

   Änderung:

   http://+:8172/MsDeployAgentService
   

3. Abfrage HTTP-Listener:

   httpcfg query urlacl
   

   Sollten Sie den folgenden Eintrag in den Ergebnissen aufgeführt:

   URL : http://+:80/MsDeployAgentService/
   ACL : D:(A;;GX;;;NS)
   

4. Ändern Hörer:

   httpcfg delete urlacl /u http://+:80/MsDeployAgentService/
   

   Diese darauf reagieren sollte mit: HttpDeleteServiceConfiguration completed with 0.

   httpcfg set urlacl /u http://+:8172/MsDeployAgentService//a D:(A;;GX;;;NS)
   

   Diese darauf reagieren sollte mit: HttpSetServiceConfiguration completed with 0.

   Der ACL angegeben, in der /a Schalter sollte mit dem ACL berichtet von der httpcfg query urlacl Befehl

5. Starten Sie den msdepsvc (net start msdepsvc).

6. Können Sie bestätigen, dass der Dienst lauscht auf port 8172 by doing:

   netstat -an
   

   Sollten Sie das folgende sehen:

   TCP    0.0.0.0:8172           0.0.0.0:0              LISTENING
   

Warnung:

Ich würde versuchen, diese auf einem nicht-produktiven Maschine zuerst dies zu gewährleisten, arbeitet wie Sie es erwarten.

InformationsquelleAutor der Antwort Kev

Für was es Wert ist, ich zusammengeklebt Kev ist eine solide Beratung in einem batch-script für one-stop-shopping auf ändern Sie die port-Nummern.

:: Name:     MsDepSvc.Port.cmd
:: Purpose:  Modifies the TCP/IP port that the Web Deployment Agent Service
::           (MsDepSvc) listens on.  Tested on Win7 Enterprise 32-bit.
:: Author:   [email protected]
:: Revision: January 2013

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION

:: variables
SET me=%~n0
SET url=
SET port=
IF NOT "%~1"=="" (
  SET /A port=%~1
)

ECHO %me%: Web Deployment Agent Service (MsDepSvc) port change script

:: default argument values
IF "%port%"=="" (
  SET /A port=8172
  ECHO %me%: INFO - using default port value of 8172
)

SC.EXE query msdepsvc >NUL 2>NUL
IF NOT "%ERRORLEVEL%"=="0" (
  ECHO %me%: ERROR - MsDepSvc not installed
  ECHO %me%: exiting
  EXIT /B 1
)

ECHO %me%: stopping MsDepSvc
NET STOP msdepsvc >NUL 2>NUL

:: check if the default port is set
REG.EXE QUERY HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters /v ListenUrl >NUL
IF NOT "%ERRORLEVEL%"=="0" (
  ECHO %me%: ERROR - MsDepSvc ListenUrl registry key not found
  REG.EXE QUERY HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters
  ECHO %me%: exiting
  EXIT /B 2
)

FOR /F "tokens=3" %%I IN ('REG.EXE QUERY HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters /v ListenUrl ^| FINDSTR ListenUrl') DO (
  SET url=%%I
)
ECHO %me%: INFO - MsDepSvc current reservation is "%url%"

NETSH.EXE http show urlacl "%url%" >NUL
IF NOT "%ERRORLEVEL%"=="0" (
  ECHO %me%: ERROR - reservation for "%url%" not found
  EXIT /B 4
)

:: save the existing urlacl properties for User, Listen, Delegate, and SDDL
FOR /F "tokens=1,* delims=: " %%A IN ('NETSH.exe http show urlacl %url%  ^| FINDSTR "User Listen Delegate SDDL"') DO (
  SET URLACL.%%A=%%B
)

IF NOT DEFINED URLACL.User     ECHO %me%: Failed to read the exising URLACL setting for User     &&GOTO :ERROR
IF NOT DEFINED URLACL.Listen   ECHO %me%: Failed to read the exising URLACL setting for Listen   &&GOTO :ERROR
IF NOT DEFINED URLACL.Delegate ECHO %me%: Failed to read the exising URLACL setting for Delegate &&GOTO :ERROR
IF NOT DEFINED URLACL.SDDL     ECHO %me%: Failed to read the exising URLACL setting for SDDL     &&GOTO :ERROR

ECHO %me%: updating MsDepSvc to listen on port %port%
REG.EXE ADD HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters /v ListenUrl /t REG_SZ /f /d "http://+:%port%/MSDEPLOYAGENTSERVICE/"

ECHO %me%: deleting the existing reservation for MsDepSvc
NETSH.EXE http delete urlacl "%url%" || GOTO :ERROR

ECHO %me%: adding the port %port% reservation for MsDepSvc
NETSH.EXE http add urlacl url=http://+:%port%/MsDeployAgentService/user="%URLACL.User%" listen="%URLACL.Listen%" delegate="%URLACL.Delegate%" SDDL="%URLACL.SDDL%"  || GOTO :ERROR

ECHO %me%: starting MsDepSvc
NET START msdepsvc >NUL 2>NUL

ECHO %me%: process info for MsDepSvc
QUERY.EXE PROCESS MSDEPSVC.EXE
ECHO.
ECHO %me%: port bindings for MsDepSvc
NETSTAT.EXE -a -n -o | FINDSTR /R "TCP.*:%port%.*LISTENING Proto"
ECHO.
ECHO %me%: finished

:END
ENDLOCAL
ECHO ON
@EXIT /B 0

:ERROR
ECHO %me%: ERROR - exiting with errorlevel %ERRORLEVEL%
ECHO ON
@EXIT/B %ERRORLEVEL%

Lesen Sie Mehr:

• https://gist.github.com/steve-jansen/5060329
• http://steve-jansen.github.com/blog/2013/02/28/how-to-modify-the-tcp-slash-ip-port-binding-for-the-microsoft-web-deployment-agent-service/

InformationsquelleAutor der Antwort Steve Jansen