KDB; stripping Zeichen aus der Spalte der Symbole

q)t:([]a:1 2 3;b:`abc11`abc22`abc33;c:10 20 30)
q)t
a b     c
----------
1 abc11 10
2 abc22 20
3 abc33 30

Streifen die ersten drei Zeichen:

q)update `$3_'string b from t
a b    c
---------
1 11 10
2 22 20
3 33 30

Oder suchen und ersetzen:

q)update `$ssr[;"abc";""] each string b from t
a b    c
---------
1 11 10
2 22 20
3 33 30

Wenn die Tabelle groß ist und viele sich wiederholende Elemente, in Betracht ziehen .Q.fu:

q)t:1000000#([]a:1 2 3;b:`abc11`abc22`abc33;c:10 20 30)
q)\t r1:update `$3_'string b from t
111
q)\t r2:update .Q.fu[{`$3_'string x};b] from t
5
q)r1~r2
1b

Wenn Ihre situation ist mehr allgemein und Sie möchten, entfernen Sie alles, bevor Sie Ihre erste numerische dann könnte man etwas tun, wie unten. Man könnte weiter verallgemeinern, um alle Spalten mit symbol Typ

q)show r1:update b:`${(first each where each x in .Q.n)_'x}string b from X
a b  c
-------
1 11 10
2 22 20
3 33 30
q)show r2:@[X; exec c from meta X where t="s"; `${(first each where each x in .Q.n)_'x}string@]
a b  c
-------
1 11 10
2 22 20
3 33 30
q)r1~r2
1b

Zugegeben, ich weiß nicht, was Ihr einrichten, aber auf meinem Rechner, das ist ziemlich schnell. Nicht annähernd so schnell wie Ihr Wörterbuch Ansatz, aber könnte sich lohnen, ein Opfer für die Allgemeinheit

q)\ts update b:`${(first each where each x in .Q.n)_'x}string b from X
69 12746848j