Klassische ASP-Authentifizierung Gegen Active Directory

Habe ich eine Klassische ASP-website (sorry!). Einige Teile davon müssen NT-Authentifizierung aktiviert ist.

Ich würde am Liebsten zu präsentieren, den Benutzer mit einer schönen login-Formular (eher als ein browser-Eingabeaufforderung) mit dem ich dann die Authentifizierung gegen AD-und dann nicht den üblichen "anmelden", wenn der Erfolg, den Fehler anzeigen, wenn der Fehler"

Ist das überhaupt möglich? Ich habe versucht, die folgenden auf einem lokalen computer, aber nicht sicher, wie Sie Sie richtig zu testen, bei Erfolg oder wenn es auch erweitert, um die Suche gegen AD

<html>
<head>
</head>
<body>
    <form action="test.asp" method="post">
        Username:
        <input type="text" name="strUserName"><br>
        Password:
        <input type="password" name="strPassword"><br>
        <input type="submit" name="btnSubmit">
    </form>
    <%
    If Request.Form("strUsername") <> "" Then
        Dim strADsPath
        strADsPath = "WinNT://ARIA"
        strUserName = Request.Form("strUserName")
        strPassword = Request.Form("strPassword")

        'Set adObject = GetObject("WinNT:")
        'Set userObject = adObject.OpenDSObject("WinNT://" & domainName, userName, password, ADS_SECURE_AUTHENTICATION)


        if (not strADsPath= "") then
            Dim oADsObject
            Set oADsObject = GetObject(strADsPath)

            response.write "Authenticating...<br><br>"

            Dim strADsNamespace
            Dim oADsNamespace

            strADsNamespace = left(strADsPath, instr(strADsPath, ":"))
            set oADsNamespace = GetObject(strADsNamespace)

            Set oADsObject = oADsNamespace.OpenDSObject(strADsPath, strUserName,strPassword, 0)

            if not (Err.number = 0) then
                Response.Write "<font color='red'><font size = 5><u><b>Authentication has failed...<b></u></font></font>"
                Session("Auth") = "NO"
            else
                Response.Write "<font color='blue'>USER AUTHENTICATED!</font><br>"
                Session("Auth") = "YES"
            end if
        end if
    End If
    %>
</body>
</html>

Also einmal authentifiziert wird, ist es möglich zu packen, andere Sachen wie E-Mail und Gruppen?

Habe ich versucht, folgenden Klassisches ASP (VBScript), 2008 R2, Fehler mit AD zu authentifizieren und versucht zu authentifizieren meiner lokalen Maschine, aber es IMMER authentifiziert, egal, was ich in. Ist es die Tatsache, ich bin mit einem lokalen Maschine bedeuten, es will einfach nicht funktionieren?

  • Sie müssen Anonymous Authentication für diese Arbeit, als Sie auf der Durchreise sind die Zugangsdaten in IIS muss nicht jede Authentifizierung. Beachten Sie, dass diese Methode ist anfällig für man-in-the-middle-Angriff, Neige ich dazu, verwenden Sie diese Methode nur in einer geschlossenen Umgebung wie ein intranet und auch dann ist es nicht 100% sicher.
  • Können Sie werfen etwas mehr Licht auf die "man in the middle" - situation bitte
  • Sie möchten Ihre eigene Benutzeroberfläche für die Authentifizierung auf Active Directory, das heißt, der client für Ihren Windows-Benutzernamen und Passwort in ein HTML-Formular, die gepostet werden in klar text, sichern Sie dies, indem Sie Ihre Website auf SSL-Verbindung ist ein muss.
  • Yup - SSL sortiert
InformationsquelleAutor pee2pee | 2014-03-10
  1. 4

    Ich weiß, das ist eine alte Frage, aber falls jemand noch interessiert:

    Dies ist, wie ich die Authentifizierung von Benutzern gegen eine ANZEIGE: Es ist ein Indirekter Ansatz mit einem authentifizierten LDAP-Abfrage. Wenn die Abfrage fehlschlägt, darf der Benutzer nicht authentifiziert der Domänencontroller.

    Es ist ein bisschen unelegant, soweit Bedarf es einer ausdrücklichen Benennung eines Domänencontrollers. domain-Namen (wenn Sie möchten, verwenden Sie die sam-account-Namen) und eine ORGANISATIONSEINHEIT für die Suche starten DN.

      dim domainController : domainController = "yourdc.company.com"
  dim ldapPort : ldapPort = 389
  dim startOu : startOu = "DC=company,DC=com"

  Function CheckLogin( szUserName, szPassword)
    CheckLogin = False

    szUserName = trim( "" &  szUserName)

    dim oCon : Set oCon = Server.CreateObject("ADODB.Connection")
    oCon.Provider = "ADsDSOObject"
    oCon.Properties("User ID") = szUserName
    oCon.Properties("Password") = szPassword
    oCon.Open "ADProvider"
    dim oCmd : Set oCmd = Server.CreateObject("ADODB.Command")
    Set oCmd.ActiveConnection = oCon

    ' let's look for the mail address of a non exitsting user
    dim szDummyQuery : szDummyQuery = "(&(objectCategory=person)(samaccountname=DeGaullesC))"
    dim szDummyProperties : szDummyProperties = "mail"
    dim cmd : cmd = "<" & "LDAP://" & domainController & ":" & ldapPort & _
                        "/" & startOu & ">;" & szDummyQuery & ";" & szDummyProperties & ";subtree"
    oCmd.CommandText = cmd
    oCmd.Properties("Page Size") = 100
    on error resume next
    dim rs : Set rs = oCmd.Execute
    if err.Number = 0 then
      CheckLogin = true
      call rs.Close()
      set rs = nothing
    end if
    on error goto 0
    set oCmd = nothing
  End Function

  ' perform test
  dim res : res = CheckLogin( "youradname\youruser", "yourpassword")
  if res then
    Response.Write( "Login ok")
  else
    Response.Write( "Login failed")
  end if
    InformationsquelleAutor schudel
Schreibe einen Kommentar