Konvertieren Sie die Zeit in UTC vbScript

Hier ist die Lösung, die ich landete Durchführung auf Anregung von @AardVark71.

Lege ich diese in mein func.asp-Datei:

<script language="javascript" runat="server">
    function toUtcString(d) {
        var dDate = new Date(d);
        return Math.round(dDate.getTime() / 1000);
    };
</script>

Gibt es ein timestamp-Wert. Dann von überall in der klassischen asp-code, ich kann dies tun:

response.Write DateAdd("s", toUtcString(cDate("11/11/2012 06:25 PM")), "01/01/1970 00:00:00") 'expect 11/11/2012 10:25:00 PM gmt/utc time
response.Write DateAdd("s", toUtcString(cDate("06/11/2012 06:25 PM")), "01/01/1970 00:00:00") 'expect  6/11/2012  9:25:00 PM gmt/utc time

Diese (glaube ich) ist einfach, und es produziert den erwarteten Werten und vollständig Faktoren in der Sommerzeit.

InformationsquelleAutor GWR

Wenn ich nicht etwas vermissen, das Sie benötigen, um die lokale Zeit auf der remote-Maschine und time-zone-offset, richtig?

Hier Sehe ich selbst-Antwort auf WMI Win32_TimeZone Bias Eigenschaft. Aber laut diesem MSDN-Beispiel: "Konvertierung von Ortszeit in UTC-Zeit", Zitat:

Verwenden Win32_ComputerSystem CurrentTimeZone Eigenschaft, weil es
passt sich automatisch der Zeitzone bias Sommerzeit
Win32_TimeZone Bias-Eigenschaft nicht.

So, nächsten Beispiel wird die Funktion get current date time, und ich überlasse es Ihnen, es zu ändern, für konkretes Datum Zeit Messen.

' "." mean local computer
WScript.Echo FormatDateTime(UTCDate("."), 0)

Function UTCDate(strComputer)
    Dim objWMIService, ColDate, ColCS

    On Error Resume Next
    Set objWMIService = _
        GetObject("winmgmts:{impersonationLevel=impersonate}!\\" _
        & strComputer & "\root\cimv2")

    Set ColDate = objWMIService.ExecQuery("Select * From Win32_LocalTime")

    UTCDate = DateSerial(100, 1, 1)
    For Each objDate In ColDate
        UTCDate = DateAdd("yyyy", ObjDate.Year - 100, UTCDate)
        UTCDate = DateAdd("m", ObjDate.Month - 1, UTCDate)
        UTCDate = DateAdd("d", ObjDate.Day - 1, UTCDate)
        UTCDate = DateAdd("h", ObjDate.Hour, UTCDate)
        UTCDate = DateAdd("n", ObjDate.Minute, UTCDate)
        UTCDate = DateAdd("s", ObjDate.Second, UTCDate)
    Next

    ' http://msdn.microsoft.com/en-us/library/windows/desktop/ms696015(v=vs.85).aspx
    Set ColCS = objWMIService.ExecQuery("Select * From Win32_ComputerSystem")

    Dim TimeZoneOffset, LocalTimeZone
    For Each LocalTimeZone In ColCS
        TimeZoneOffset = LocalTimeZone.CurrentTimeZone
    Next

    If TimeZoneOffset < 0 Then
        TimeZoneOffset = Abs(TimeZoneOffset)
    Else
        TimeZoneOffset = -Abs(TimeZoneOffset)
    End If

    UTCDate = DateAdd("n", TimeZoneOffset, UTCDate)
    If Err Then UTCDate = vbNull
    Set objWMIService = Nothing
End Function

[EDIT] Naja, sieht aus wie nicht Vertrauen sollte auf der MSDN-Website (oder vielleicht arbeiten diese nur für die aktuelle Zeit). Allerdings sehe ich es nicht die Antwort, die Sie suchen. Wenn Sie nicht finden bessere Idee hat, können Sie den Vorgang automatisieren,online-Rechner.

P. S. Ok, Streik oben genannten code und können versuchen, einen anderen "iteration".

Nur der Hinweis, dass ich einen code kompatibel mit meinem Zeitzone (Bulgarien), wo PDT start am letzten Sonntag im März und endet am letzten Sonntag Oktober. Dies erlaubt mir, einfach mein PDT-Bereich. Kurz, die Idee ist, stellen Sie den Algorithmus für Ihre region. Der rest ist klar, hoffe ich.

With New DateDrill
    Debug.WriteLine .UTCDate("2008-6-28")
    Debug.WriteLine .UTCDate("2014-1-21")
End With

Class DateDrill

    Public Function UTCDate(ByVal dtDate)
        If Not IsDate(dtDate) Then Err.Raise 5
        dtDate = CDate(dtDate)
        Dim ZoneBias: ZoneBias = TimeZoneBias()
        If IsPDT(Now) <> IsPDT(dtDate) Then
            ZoneBias = ZoneBias - 60
        End If
        UTCDate = DateAdd("n", ZoneBias, dtDate)
    End Function

    Private Function IsPDT(ByVal dtDate)
        If Not IsDate(dtDate) Then Err.Raise 5
        dtDate = CDate(dtDate)
        Dim pdtLow, pdtUpr, nDaysBack

        pdtLow = DateSerial(Year(dtDate),  3, 31)
        pdtUpr = DateSerial(Year(dtDate), 10, 31)
        pdtLow = DateAdd("h", 2, pdtLow)
        pdtUpr = DateAdd("h", 2, pdtUpr)

        nDaysBack = Weekday(pdtLow) - 1
        If nDaysBack <> 0 Then
            pdtLow = DateAdd("d", -nDaysBack, pdtLow)
        End If

        nDaysBack = Weekday(pdtUpr) - 1
        If nDaysBack <> 0 Then
            pdtUpr = DateAdd("d", -nDaysBack, pdtUpr)
        End If

        IsPDT = (dtDate >= pdtLow And dtDate <= pdtUpr)
    End Function

    Private Function TimeZoneBias()
        Dim LTZone
        With GetObject("winmgmts:" & _
                "{impersonationLevel=impersonate}!\\.\root\cimv2")
            For Each LTZone In .ExecQuery(_
                    "Select * From Win32_ComputerSystem")
                TimeZoneBias = LTZone.CurrentTimeZone
            Next
        End With
        TimeZoneBias = TimeZoneBias * -1
    End Function

End Class

InformationsquelleAutor Panayot Karabakalov