Kopieren Sie den VBA-code von einem Blatt in einer Arbeitsmappe in eine andere?

Habe ich mit den folgenden Zeilen zu kompakt VBA-Module aus einer Arbeitsmappe in eine andere, und ich weiß nicht, ob es eine einfachere Möglichkeit gibt, aber Sie haben sich fein arbeiten:

Set srcVba = srcWbk.VBProject
Set srcModule = srcVba.VBComponents(moduleName)

srcModule.Export (path) 'Export from source
trgtVba.VBComponents.Remove VBComponent:=trgtVba.VBComponents.Item(moduleName) 'Remove from target
trgtVba.VBComponents.Import (path) 'Import to target

Aber jetzt muss ich kopieren, VBA-code, der in einem Blatt, nicht in ein Modul. Die obige Methode funktioniert nicht für dieses Szenario.

Welchen code kann ich verwenden, zu kopieren, VBA-code in ein Blatt aus einer Arbeitsmappe in eine andere?

InformationsquelleAutor der Frage user1283776 | 2013-08-28

  1. 28

    Können Sie nicht entfernen und re-importieren Sie die VBComponentdenn das würde logischerweise löschen Sie das gesamte Arbeitsblatt. Sie müssen stattdessen verwenden CodeModule zum Bearbeiten des Texts in der Komponente:

    Dim src As CodeModule, dest As CodeModule

Set src = ThisWorkbook.VBProject.VBComponents("Sheet1").CodeModule
Set dest = Workbooks("Book3").VBProject.VBComponents("ThisWorkbook") _
    .CodeModule

dest.DeleteLines 1, dest.CountOfLines
dest.AddFromString src.Lines(1, src.CountOfLines)

    InformationsquelleAutor der Antwort Chel

  2. 1

    Wenn jemand landet auf der Suche für VSTO-äquivalent von Chel ' s Antwort, hier ist es:

    void CopyMacros(Workbook src, Workbook dest)
{
  var srcModule = src.VBProject.VBComponents.Item(1).CodeModule;
  var destModule = dest.VBProject.VBComponents.Add(Microsoft.Vbe.Interop.vbext_ComponentType.vbext_ct_StdModule);

  destModule.CodeModule.AddFromString(srcModule.Lines[1, srcModule.CountOfLines]);
}

    Dinge zu beachten:

    1. Müssen Sie Verweis hinzufügen, um Microsoft.Vbe.Interop zu tun, dieses Zeug.
    2. Ich bin hinzufügen eines neuen Allgemeinen Modul, um die Ziel-Arbeitsmappe, so brauchte ich nicht zu rufen DeleteLines. YMMV.

    InformationsquelleAutor der Antwort dotNET

  3. 0

    Dies ist eine kompilierte code aus verschiedenen Quellen sowie von einem Beitrag.
    Mein Beitrag ist ein code, der kopiert ALLE Ihre codes von VBE (Blätter/DieseArbeitsmappe/Userforms/Module/Klassen) in eine neue Arbeitsmappe.

    habe ich diese , weil ich habe eine beschädigte Arbeitsmappe aus, und machen Sie einen code, um wieder alle, die nicht korrupt, einschließlich code. (dieser Teil nur erholt code + Referenzen) :

    'needs a reference to : Visual basic for Application Extensibility 5.3 ,
'or run this code : thisworkbook.VBProject.References.AddFromFile "C:\Program Files (x86)\Common Files\Microsoft Shared\VBA\VBA6\VBE6EXT.OLB"
'from immediate window (ctrl+G) or create a small sub

Option Explicit

Sub CopyComponentsModules() 'copies sheets/Thisworkbook/Userforms/Modules/Classes  to a new workbook
Dim src As CodeModule, dest As CodeModule
Dim i&
Dim WB_Dest As Workbook
'Dim sh As Worksheet
Dim Comp As VBComponent

'Set sh = ThisWorkbook.Sheets(1)
'sh.Cells.Clear

Set WB_Dest = Application.Workbooks.Add
On Error Resume Next 'needed for testing if component already exists in destination WorkBook and for cross-references.
For Each Comp In ThisWorkbook.VBProject.VBComponents

            'i = i + 1
            'sh.Cells(i, 1).Value = Comp.Name

            'Set Source code module
            Set src = Comp.CodeModule  'ThisWorkbook.VBProject.VBComponents("Sheet1").CodeModule

            'test if destination component exists first
            i = 0: i = Len(WB_Dest.VBProject.VBComponents(Comp.Name).Name)
            If i <> 0 Then 'or: if err=0 then
                Set dest =     WB_Dest.VBProject.VBComponents(Comp.Name).CodeModule
            Else 'create component
                With WB_Dest.VBProject.VBComponents.Add(Comp.Type)
                    .Name = Comp.Name
                    Set dest = .CodeModule
                End With
            End If

            'copy module/Form/Sheet/Class 's code:
            dest.DeleteLines 1, dest.CountOfLines
            dest.AddFromString src.Lines(1, src.CountOfLines)

Next Comp

'Add references as well :
Dim Ref As Reference
For Each Ref In ThisWorkbook.VBProject.References
    'Debug.Print Ref.Name 'Nom
    WB_Dest.VBProject.References.AddFromFile Ref.FullPath
    'Debug.Print Ref.FullPath 'Chemin complet
    'Debug.Print Ref.Description 'Description de la référence
    'Debug.Print Ref.IsBroken 'Indique si la référence est manquante
    'Debug.Print Ref.Major & "." & Ref.Minor 'Version
    'Debug.Print "---"
Next Ref

Err.Clear: On Error GoTo 0

'WB_Dest.Activate

Set Ref = Nothing
Set src = Nothing
Set dest = Nothing
Set Comp = Nothing
Set WB_Dest = Nothing
End Sub

    InformationsquelleAutor der Antwort Patrick Lepelletier

Schreibe einen Kommentar