Kopieren und Einfügen einer Schleife in VBA basiert auf die Zelle Werte

Ich versuche zu erstellen, einige code, der schaut durch einen Zellbereich und kopieren Sie und fügen Sie die Zellen, die mit einer spezifischen parameter an eine andere Position in der Arbeitsmappe.

Ich würde gerne alles kopieren, das mit dem Buchstaben " L " von "tabelle5" und kopiere einen bestimmten Bereich zu "Tabelle1"

Ich muss etwas falsch mit der loop-Teil des Codes, weil nur die Oberseite der Zellbereich kopiert wird. Ich möchte das einfügen beginnen in Zeile 5 und weiter nach unten. Bedeutet das, dass ich richtig IRow = IRow + 1 unterhalb der "einfügen" Funktion?

Sub Paste_Value_Test()

Dim c As Range
Dim IRow As Long
Dim rDestination As Excel.Range

Application.ScreenUpdating = False
Sheets("sheet5").Activate
For Each c In Sheets("sheet5").Range("b2", Range("N65536").End(xlUp))
    If c.Value = "L" Then
        Sheets("sheet5").Cells(c.Row, 2).Copy

        Set rDestination = Worksheets("sheet5").Cells(5 + IRow, 12)

        rDestination.Select
        Selection.PasteSpecial Paste:=xlPasteValues, _
        Operation:=xlNone, _
        SkipBlanks:=False, _
        Transpose:=False

        IRow = IRow + 1

    End If
Next c

End Sub

Ich wirklich zu schätzen jede Hilfe bei diesem. Ich bin relativ neu in VBA und bin im Begriff, zu beginnen ernsthaft zu Graben in.

  • Also das "L" kann überall sein, in den Spalten B:N? Und wenn Sie ihn gefunden haben, den Sie kopieren möchten den Wert aus Spalte 2 der Zeile?
  • Sie sind das kopieren von Tabelle5 Sie zu Tabelle5 in deinem code?
InformationsquelleAutor dutchballa | 2014-01-29
  1. 3

    Ist das, was Sie versuchen, durch Zufall? Ich habe, kommentierte der code sollte also keine Probleme haben, es zu verstehen.

    Sub Paste_Value_Test()
    Dim c As Range
    Dim IRow As Long, lastrow As Long
    Dim rSource As Range
    Dim wsI As Worksheet, wsO As Worksheet

    On Error GoTo Whoa

    '~~> Sheet Where "L" needs to be checked
    Set wsI = ThisWorkbook.Sheets("Sheet5")
    '~~> Output sheet
    Set wsO = ThisWorkbook.Sheets("Sheet1")

    Application.ScreenUpdating = False

    With wsI
        '~~> Find Last Row which has data in Col B to N
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            lastrow = .Columns("B:N").Find(What:="*", _
                          After:=.Range("B1"), _
                          Lookat:=xlPart, _
                          LookIn:=xlFormulas, _
                          SearchOrder:=xlByRows, _
                          SearchDirection:=xlPrevious, _
                          MatchCase:=False).Row
        Else
            lastrow = 1
        End If

        '~~> Set you input range
        Set rSource = .Range("B2:N" & lastrow)

        '~~> Search for the cell which has "L" and then copy it across to sheet1
        For Each c In rSource
            If c.Value = "L" Then
                .Cells(c.Row, 2).Copy
                wsO.Cells(5 + IRow, 12).PasteSpecial Paste:=xlPasteValues

                IRow = IRow + 1
            End If
        Next
    End With

LetsContinue:
    Application.ScreenUpdating = True
    Application.CutCopyMode = False
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub
    • Ich bin wirklich dankbar für die Hilfe hier. Das funktionierte perfekt für das, was ich tun wollte. Meine Erklärung war verwirrend, da schnappte ich code aus einem anderen Beitrag, dass ich nicht Bearbeiten, genug für mein Szenario. Ich bin der Planung auf dem gehen durch eine vollständige VBA-tutorial, aber wenn Sie irgendwelche Quellen, die nützlich für das lernen, data manipulation in VBA, das wäre sehr hilfreich.
    • Froh, dass es geholfen): Welche Art der Daten-manipulation? Stackoverflow hat viele Beispiele auf Daten-manipulation. Dann gibt es google, die können eine große Hilfe sein, wenn Sie wissen, wie zu suchen 🙂
    • Es bekam. Ich denke, dass ist die beste Wette. Plan ist, gehen durch ein tutorial zu machen, sicher, ich kann Debuggen und haben ein Allgemeines Verständnis von VBA. Dann gehen Dinge zu lernen, die auf Projekt-basis. Dies ist ein großes forum. Dank einer Tonne für die Hilfe.
    InformationsquelleAutor Siddharth Rout
Schreibe einen Kommentar