Läuft ein Programm/Skript von QMake

Wir haben eine ziemlich große code-Basis. Die überwiegende Mehrheit der der code kompiliert wird mit qmake zum erzeugen der makefiles. Allerdings gibt es einige sub-Projekte, die hergestellt werden durch ausführen von batch-Dateien oder die Ausführung anderer Programme.

Ich würde gerne in der Lage sein, alles zu haben kompiliert mit qmake, aber ich kann nicht herausfinden, wie man qmake einfach ein Skript ausführen.

Eine Sache, die ich probiert habe ist mit QMAKE_EXTRA_TARGETS in meinem pro-Datei, etwa so:

TEMPLATE = lib
SOURCES = placeholder.cpp
CONFIG += no_link staticlib
batch_runner.target   = placeholder.cpp
batch_runner.commands = my_batch_file.bat
QMAKE_EXTRA_TARGETS   = batch_runner

Dann habe ich die batch-Datei erzeugen placeholder.cpp etwa so:

# do the real work here
# ...
# create placeholder.cpp so qmake and nmake are happy
echo //dummy >> placeholder.cpp

Dieser scheint gut zu funktionieren. Das Problem ist, dass es etwas abgedroschen. Wenn ich nicht angeben batch_runner.Ziel (d.h. ich leer lassen) oder nicht zu setzen placeholder.cpp in den QUELLEN dann die batch-Datei nie ausgeführt wird. Dies ist, weil qmake nicht batch_runner.Befehle die Aktion für alle anderen Abhängigkeiten im Makefile.

Gibt es einen besseren Weg, um QMake zu konstruieren, ein Makefile derart, dass ein Skript ausgeführt wird, wenn das Makefile ausgeführt?

InformationsquelleAutor der Frage Tom Hennen | 2010-08-31

14

Sieht es aus wie QMAKE_POST_LINK funktioniert gut für diese Art der Sache.

Dieser scheint den job zu erledigen. my_batch_file.bat wird ausgeführt, wenn nmake läuft (eher als wenn qmake läuft) und ich muss nicht alles lustig mit Platzhalter targets oder Dateien.

Es ist ziemlich wahrscheinlich, dass ich nicht alle der aufgelisteten Elemente in der 'CONFIG'.
```
TEMPLATE = lib
TARGET   = 
CONFIG  += no_link target_predeps staticlib

QMAKE_POST_LINK  = my_batch_file.bat
QMAKE_CLEAN     += batch_output.obj
```
InformationsquelleAutor der Antwort Tom Hennen
6

Versuchen die system () - Befehl. Zum Beispiel:
```
system(pwd)
```
InformationsquelleAutor der Antwort Arnold Spence
5

Hier ist eine andere Lösung:
```
TEMPLATE = aux
OBJECTS_DIR = ./
DESTDIR = ./

first.commands = my_batch_file.bat
QMAKE_EXTRA_TARGETS += first
QMAKE_CLEAN += batch_output.obj
```
Die Vorlage aux im Grunde erzeugt ein makefile, das tut nichts, wenn ausgeführt wird, ohne Angabe eines Ziels. Die OBJECTS_DIR und DESTDIR Variablen auf das aktuelle Verzeichnis festgelegt, um zu verhindern, dass qmake erstellt die debug und release Verzeichnisse (es ist wichtig, um Sie zu ./ - und nicht nur .; zumindest unter Windows). Dann, mit QMAKE_EXTRA_TARGETS wir definieren den Ziel - first zum ausführen des benutzerdefinierten Befehls, wenn das makefile aufgerufen wird, ohne Ziel.

Es ist ein bisschen hacky, aber es bekommt den job getan.

Zusatz:
Wenn Sie verhindern möchten, dass die Erzeugung von drei makefiles (Makefile, Makefile.Debug, Makefile.Release), Sie können hinzufügen
```
CONFIG -= debug_and_release
```
Jedoch, wenn Sie dieses und, je nachdem, wie das makefile aufgerufen wird (immer manuell aufgerufen werden, wird von übergeordneten Verzeichnisses "Unterverzeichnisse" *.pro-Datei, ...), kann es notwendig sein, erstellen gefälschte debug und release Ziele zu vermeiden "no rule to make target..." - Fehler. Zum Beispiel:
```
release.target = release
release-clean.target = release-clean
release-install.target = release-install
[...]
debug.target = debug
debug-clean.target = debug-clean
debug-install.target = debug-install
[...]
QMAKE_EXTRA_TARGETS += release release-clean release-install [...]
QMAKE_EXTRA_TARGETS += debug debug-clean debug-install [...]
```
InformationsquelleAutor der Antwort Ignitor
1

Könnten Sie die UNTERVERZEICHNISSE, die Konfiguration auf mehrere unterschiedliche Ziele, auch aus dem gleichen makefile. Das funktioniert besonders gut mit Ihren zusätzlichen Zielen, als ein subdir-Konfiguration können Sie bestimmte einem bestimmten Ziel in der makefile ausgeführt (siehe undokumentierte qmake für details). In diesem Fall würde ich alle "normalen" build-Befehle in einem .pro-Datei, die externen build-Befehle in einer anderen, und Unterverzeichnisse .pro-Datei zu erstellen, alle von Ihnen. Habe ich noch nicht getestet, alles ganz so, aber es sollte funktionieren.

regelmäßig.pro:
```
SOURCES += main.cpp
TARGET = regular.exe
```
externe.pro:
```
batch_runner.commands = my_batch_file.bat
QMAKE_EXTRA_TARGETS   += batch_runner

other_runner.commands = other_batch_file.bat
QMAKE_EXTRA_TARGETS   += other_runner
```
do_it_all.pro:
```
TEMPLATE = subdirs
CONFIG += ordered

regular.file = regular.pro
SUBDIRS += regular

batch.file = external.pro
batch.target = batch_runner
SUBDIRS += batch

other.file = external.pro
other.target = other_runner
SUBDIRS += other
```
InformationsquelleAutor der Antwort Caleb Huitt - cjhuitt

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.