MS Access 2013 und zeigt nur Start-Formular, und sonst nichts

Beim einschalten meiner MS-Access-2013-Datenbank, nur muss ich es um zu zeigen das Start-Formular, und sonst nichts. Gewünschte Ergebnis wäre so etwas wie unten. Der hintergrund ist mein desktop.

Gewünschte:

MS Access 2013 und zeigt nur Start-Formular, und sonst nichts

Aber wenn ich das öffnen der DB öffnet sich ein Formular mit dem gesamten Bildschirm.

Den nachstehenden VBA-code ausgeführt wird, wenn das Start-Formular geladen und zunächst funktioniert es, aber wenn ich das Fenster minimieren kann ich den hintergrund wieder.

Option Compare Database
Option Explicit
Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3

Private Declare Function apiShowWindow Lib "user32" _
Alias "ShowWindow" (ByVal hWnd As Long, _
ByVal nCmdShow As Long) As Long

Function fSetAccessWindow(nCmdShow As Long)
Dim loX As Long
Dim loForm As Form
On Error Resume Next
Set loForm = Screen.ActiveForm

If Err <> 0 Then
    loX = apiShowWindow(hWndAccessApp, nCmdShow)
    Err.Clear
End If

If nCmdShow = SW_SHOWMINIMIZED And loForm.Modal = True Then
    MsgBox "Cannot minimize Access with " _
    & (loForm.Caption + " ") _
    & "form on screen"
ElseIf nCmdShow = SW_HIDE And loForm.PopUp <> True Then
    MsgBox "Cannot hide Access with " _
    & (loForm.Caption + " ") _
    & "form on screen"
Else
    loX = apiShowWindow(hWndAccessApp, nCmdShow)
End If
fSetAccessWindow = (loX <> 0)
End Function

Habe ich versteckte Bänder, Navigationsbereich und alle access-Benutzer-interfaces, aber ich muss entfernen Sie die Access-hintergrund auch.

Strom:

MS Access 2013 und zeigt nur Start-Formular, und sonst nichts

Jede Hilfe /Beratung wird sehr geschätzt. Vielen Dank im advace !!!

InformationsquelleAutor Subhojit Bhowmick | 2016-08-21
  1. 4

    Brauchen Sie nicht alle API-code.

    Folgende Einstellungen sollten funktionieren:

    Datei->Optionen->Aktuelle Datenbank

    Deaktivieren Sie "Display-Dokument mit Registerkarten"
    Wählen Sie Dokumente Im Registerkartenformat.

    Oben auch un-check die Anzeige Navigationsbereich.

    Ausblenden der Multifunktionsleiste, führen diese EINE Zeile VBA im Autostart:

    DoCmd.ShowToolbar "Ribbon", acToolbarNo

    Dem resultierenden Bildschirm wird dies:

    MS Access 2013 und zeigt nur Start-Formular, und sonst nichts

    Stellen Sie sicher, dass die form(en) sind nicht dialog, und stellen Sie sicher, Sie sind nicht popup-Formulare.

    Zurück in die "development" - Modus, verlassen Sie die Datenbank und dann neu starten mit gedrückter Umschalt-Taste–, der by-pass alle der oben genannten und lassen Sie Sie zu entwickeln.

    • Was, wenn Sie wollen, um verschiedene Formen in verschiedenen Größen? gibt es einen Weg, um das gesamte Fenster in der Größe mit den verschiedenen Formen?
    • Starten von Word -, Excel -, web browser NIE wieder die Größe des Anwendungsfensters. Auch ein accounting-system mit 200+ Formen NICHT re-size das Hauptfenster der Anwendung. Nie gesehen, JEDE software, die sich in den letzten 20 Jahren, die funktioniert wie Sie es beschreiben. Die Größe der Applikation wird auf die Größe der ersten form ins Leben gerufen. Für 99% der Anwendungen, die ich JE benutzt dann den main-UI-Fenster enthält Menüs, Registerkarten oder Navigations-bars in dem Sie oben oder unten auf der Seite. Könnte man vielleicht die Größe des Anwendungsfensters zu jedem Formular gestartet, aber das ist eher unruhig und eher faule Typ der UI habe ich noch NIE gesehen
    InformationsquelleAutor Albert D. Kallal
  2. 0

    Ich nutze die Synchronisation von Haupt-form und den Zugriff auf windows-Größen, so dass der Zugriff wird das Fenster immer hinter dem Hauptfenster. Hier ist der code hinter:

    Private Sub Form_Resize()
'main form
'Let us know when Form is Maximized...

If CBool(IsZoomed(Me.hwnd)) = True Then
    funSetAccessWindow (SW_SHOWMAXIMIZED)
    DoCmd.Maximize
    Me.TimerInterval = 0
ElseIf CBool(IsIconic(Me.hwnd)) = True Then
    funSetAccessWindow (SW_SHOWMINIMIZED)
    Me.TimerInterval = 0
Else
    'enable constant size sync
    Me.TimerInterval = 100
    SyncMainWindowSize Me, True
End If
End Sub

Private Sub Form_Timer()
SyncMainWindowSize Me
End Sub

Public Function SyncMainWindowSize(frm As Form, Optional blnForce As Boolean = False)
Dim rctForm As RECT
Dim iRtn As Integer
Dim blnMoved As Boolean

Static x As Integer
Static y As Integer
Static cx As Integer
Static cy As Integer

#If VBA7 And Win64 Then
    Dim hWndAccess As LongPtr
#Else
    Dim hWndAccess As Long
#End If

If GetWindowRect(frm.hwnd, rctForm) Then
    If x <> rctForm.Left Then
        x = rctForm.Left
        blnMoved = True
    End If

    If y <> rctForm.Top Then
        y = rctForm.Top
        blnMoved = True
    End If
    If cx <> rctForm.Right - rctForm.Left Then
        cx = rctForm.Right - rctForm.Left
        blnMoved = True
    End If
    If cy <> rctForm.Bottom - rctForm.Top Then
        cy = rctForm.Bottom - rctForm.Top
        blnMoved = True
    End If

    If blnMoved Or blnForce Then
        'move/resize main window
        hWndAccess = Application.hWndAccessApp
        iRtn = apiShowWindow(hWndAccess, WM_SW_RESTORE)
        Call SetWindowPos(hWndAccess, 0, x, y, cx, cy, WM_SWP_NOZORDER Or WM_SWP_SHOWWINDOW)
    End If
End If
End Function

Function funSetAccessWindow(nCmdShow As Long)
'Usage Examples
'Maximize window:
'       ?funSetAccessWindow(SW_SHOWMAXIMIZED)
'Minimize window:
'       ?funSetAccessWindow(SW_SHOWMINIMIZED)
'Hide window:
'       ?funSetAccessWindow(SW_HIDE)
'Normal window:
'       ?funfSetAccessWindow(SW_SHOWNORMAL)
    Dim loX  As Long
    On Error GoTo ErrorHandler

    loX = apiShowWindow(hWndAccessApp, nCmdShow)
    funSetAccessWindow = (loX <> 0)
End Function
    InformationsquelleAutor Sergey S.
Schreibe einen Kommentar