MS Access zum ausführen von code in excel-vba

Habe ich diesen code in "DieseArbeitsmappe" - Objekt in Excel:

Public Sub TestScript()

    Debug.Print "Hello"

End Sub

Dann erfolgreich genannt-Zugriff über eine Schaltfläche in einem Formular aus:

Private Sub cmdRunExcel_Click()

    Dim xl As Excel.Application
    Set xl = CreateObject("Excel.Application")

    xl.Visible = True

    xl.Workbooks.Open "C:/Your/FolderPath/And/FileName.xlsx", True, False

    xl.Run "ThisWorkbook.TestScript"

    Set xl = Nothing

End Sub

Zugegeben, ich habe nicht gegeben es eine Menge code, um zu laufen, aber hier ist der code zumindest läuft auf Excel von Excel... die müssen besser sein, als zu versuchen, code ausführen, der auf Excel aus Access.

Update: Sehen Sie, wenn Sie erstellen können Sie das Modul aus Access nach Excel, indem Sie dieses zu testen (kann ich nicht testen, es richtig, weil ich bin mit einem computer arbeiten und es scheint nicht lassen mich laufen diese Art von code aufgrund von Sicherheitseinstellungen)

Private Sub cmdRunExcel_Click()

    Dim xl As Excel.Application
    Dim myWrkBk As Excel.Workbook
    Dim myModule As VBComponent
    Dim strVb As String

    Set xl = CreateObject("Excel.Application")

    xl.Visible = True

    xl.Workbooks.Open "C:/Your/FolderPath/And/FileName.xlsx", True, False

    Set myWrkBk = xl.Workbooks.Add
    Set myModule = myWrkBk.VBProject.VBComponents.Add(vbext_ct_StdModule)

    strVb = "Public Sub TestScript()" & vbCrLf _
          & "Debug.Print 'Hello'" _
          & "End Sub"

    myModule.CodeModule.AddFromString strVb

'    xl.Run "ThisWorkbook.TestScript"

    Set myModule = Nothing
    Set myWrkBk = Nothing
    Set xl = Nothing

End Sub

Wenn der code, den Sie ausführen möchten, in Excel immer die gleichen, dann öffnen Sie eine Excel-Vorlage mit makro-Arbeitsmappe befestigt, halten Sie Ihren code.
Dann, aus Access können Sie eine Reihe von Makros oder, natürlich, nur ein makro, wenn nur eine wird an den parameter-array:

Function RunExcelMacros( _
  ByVal strFileName As String, _
  ParamArray avarMacros()) As Boolean

Debug.Print "xl ini", Time

  On Error GoTo Err_RunExcelMacros

  Static xlApp      As Excel.Application
  Dim xlWkb         As Excel.Workbook

  Dim varMacro      As Variant
  Dim booSuccess    As Boolean
  Dim booTerminate  As Boolean

  If Len(strFileName) = 0 Then
    ' Excel shall be closed.
    booTerminate = True
  End If

  If xlApp Is Nothing Then
    If booTerminate = False Then
      Set xlApp = New Excel.Application
    End If
  ElseIf booTerminate = True Then
    xlApp.Quit
    Set xlApp = Nothing
  End If

  If booTerminate = False Then
    Set xlWkb = xlApp.Workbooks.Open(FileName:=strFileName, UpdateLinks:=0, ReadOnly:=True)

    ' Make Excel visible (for troubleshooting only) or not.
    xlApp.Visible = False 'True

    For Each varMacro In avarMacros()
      If Not Len(varMacro) = 0 Then
  Debug.Print "xl run", Time, varMacro
        booSuccess = xlApp.Run(varMacro)
      End If
    Next varMacro
  Else
    booSuccess = True
  End If

  RunExcelMacros = booSuccess

Exit_RunExcelMacros:

  On Error Resume Next

  If booTerminate = False Then
    xlWkb.Close SaveChanges:=False
    Set xlWkb = Nothing
  End If

Debug.Print "xl end", Time
  Exit Function

Err_RunExcelMacros:
  Select Case Err
    Case 0      'insert Errors you wish to ignore here
      Resume Next
    Case Else   'All other errors will trap
      Beep
      MsgBox "Error: " & Err & ". " & Err.Description, vbCritical +
vbOKOnly, "Error, macro " & varMacro
      Resume Exit_RunExcelMacros
  End Select

End Function

Beachten Sie bitte auch, dass Sie - wie oben gezeigt - äußerst strengen öffnen, verwenden und schließen Sie die Excel-Objekte und in der richtigen Reihenfolge. Keine ActiveWorkbook oder ähnliches.