Netstat mit WMI und VBScript

Arbeite ich an einem Projekt, wo ich anpassen müssen, um ein Skript für Netzwerk-Dokumentation. Das aktuelle Skript, das wir verwenden, ist eine modifizierte version von SYDI, finden Sie hier. Was ich tun möchte, ist zu diesem Skript hinzufügen die Fähigkeit zum ausführen einer netstat- und habe es zurückgegeben mit der rest des Berichts. Ich war neugierig, ob jemand verwendet hat, WMI und VBScript zurück netstat-Informationen und wie Sie vielleicht in der Lage sein, um aufgenommen werden in diesem Skript.

HINWEIS: ich versuche nicht, um ein Produkt und ich bin nicht verbunden mit dem SYDI-Projekt.

InformationsquelleAutor John | 2012-05-22
  1. 3

    Könnten Sie ausführen, netstat und erfassen das Ergebnis wie das Skript hier unter, aber viel info auch von activeX-aber die die ich brauchen würde, zu wissen, welche Informationen Sie genau brauchen.

    set sh = CreateObject("Wscript.Shell") 
set Connections = CreateObject("Scripting.Dictionary") 

call Main() 

Function Main() 
    call GetConnections() 
    call ProcessConnections() 
End Function 

Function GetConnections() 
    i = 0 
    set shExec = sh.Exec("netstat -f") 

    Do While Not shExec.StdOut.AtEndOfStream 
        Line = shExec.StdOut.ReadLine() 
        If Instr(Line, "TCP") <> 0 Then 
            Set Connection = New NetworkConnection 
            Connection.ParseText(Line) 
            call Connections.Add(i, Connection) 
            i = i + 1 
        End If 
    Loop 
End Function 

Function ProcessConnections() 
    For Each ConnectionID in Connections.Keys 
        wscript.echo ConnectionID & Connections(ConnectionID).RemoteIP 
    Next 
End Function 

Class NetworkConnection 
    Public Protocol 
    Public LocalIP 
    Public LocalPort 
    Public RemoteIP 
    Public RemotePort 

    Public Sub ParseText(Line) 
        dim i 

        For i = 5 to 2 Step -1 
            Line = Replace(Line, String(i, " "), " ") 
        Next 

        Line = Replace(Line, ":", " ") 
        Line = Right(Line, Len(Line) - 1) 
        Line = Split(Line, " ") 

        Protocol = Line(0) 
        LocalIP = Line(1) 
        LocalPort = Line(2) 
        RemoteIP = Line(3) 
        RemotePort = Line(4) 

    End Sub 

    Private Sub Class_Initialize 
        'MsgBox "Initialized NetworkConnection object" 
    End Sub 

End Class

    EDIT: basierend auf dem Kommentar, den der OP hier eine vereinfachte version

    set sh = CreateObject("Wscript.Shell")  
call GetConnections()  

Function GetConnections()  
  i = 0  
  set shExec = sh.Exec("netstat -an")  
   Do While Not shExec.StdOut.AtEndOfStream  
      Wscript.Echo shExec.StdOut.ReadLine()  
  Loop  
End Function
    • Ich möchte die volle Leistung von der netstat-an - Befehl. Das heißt, ich möchte, um zu sehen, die gesamte Liste der Protokolle, Lokale Adressen, Adressen im Ausland und Staat. Im Idealfall wäre dies die Ausgabe in eine Tabelle ähnlich zu dem, was man sehen kann von der Befehl Linie, wenn Sie den Befehl ausführen. Vielen Dank für die Ideen und das Beispiel und deine Hilfe.
    • in diesem Fall, ist es einfach, bearbeitete ich meine Antwort
    InformationsquelleAutor peter
Schreibe einen Kommentar