Oracle - wählen Sie eine bestimmte Spalte von ref cursor

Ich habe eine Tabelle mit dem Namen Table1. Es hat viele Spalten, eine davon ist " Column1. Ich weiß nicht, die anderen Spalten, die Sie möglicherweise ändern sich sogar manchmal. Es ist eine stark typisierte ref cursor-Typ, die Renditen der Table1-Tabelle%rowtype, benannt cur_Table1. Ich habe eine gespeicherte Prozedur mit dem Namen SP1, die hat einen parameter vom Typ cur_Table1. Ich rufe dieses SP1 gespeicherte Prozedur aus einer anderen Datenbank, die nur sieht, wie Sie diese gespeicherte Prozedur, aber nicht die Tabelle oder der Typ selbst. Wie wähle ich nur spalte1 aus der zurückgegebene cursor? Ich weiß, ich kann Holen, die in einem Datensatz oder in so viele Variablen wie die cursor-Spalten, aber ich kenne nur eine Spalte für die Existenz, also kann ich nicht erklären, das komplette Album oder die korrekte Anzahl von Variablen.

  • Bitte erläutern Sie, wie Sie vorschlagen, zum Aufruf einer Prozedur in einer anderen Datenbank (oder eine beliebige Datenbank, für diese Angelegenheit), ohne in der Lage zu sehen, die Typen der Argumente.
  • Ich habe ein "grant execute on SP zu einem anderen", aber nicht gewähren, nichts anderes, nicht auf die Tabelle oder die Typen, die Paket. Und es funktioniert.
  • Oh, und auf die aufrufende Seite, lege ich den out-parameter der SP in eine sys_refcursor, natürlich.
InformationsquelleAutor fejesjoco | 2012-04-25
  1. 7

    Können Sie dies mit DBMS_SQL, aber es ist nicht schön.

    Tisch-und sample-Daten (SPALTE 1 die Nummern 1 - 10):

    create table table1(column1 number, column2 date, column3 varchar2(1000), column4 clob);

insert into table1
select level, sysdate, level, level from dual connect by level <= 10;
commit;

    Paket mit einem Verfahren, das öffnet einen ref-cursor und wählt alles:

    create or replace package test_pkg is
    type cur_Table1 is ref cursor return table1%rowtype;
    procedure sp1(p_cursor in out cur_table1);
end;
/

create or replace package body test_pkg is
    procedure sp1(p_cursor in out cur_table1) is
    begin
        open p_cursor for select column1, column2, column3, column4 from table1;
    end;
end;
/

    PL/SQL-block, der liest COLUMN1 Daten aus dem ref cursor:

    --Basic steps are: call procedure, convert cursor, describe and find columns,
--then fetch rows and retrieve column values.
--
--Each possible data type for COLUMN1 needs to be added here.
--Currently only NUMBER is supported.
declare
    v_cursor sys_refcursor;
    v_cursor_number number;

    v_columns number;
    v_desc_tab dbms_sql.desc_tab;
    v_position number;
    v_typecode number;
    v_number_value number;
begin
    --Call procedure to open cursor
    test_pkg.sp1(v_cursor);
    --Convert cursor to DBMS_SQL cursor
    v_cursor_number := dbms_sql.to_cursor_number(rc => v_cursor);
    --Get information on the columns
    dbms_sql.describe_columns(v_cursor_number, v_columns, v_desc_tab);

    --Loop through all the columns, find COLUMN1 position and type
    for i in 1 .. v_desc_tab.count loop
        if v_desc_tab(i).col_name = 'COLUMN1' then
            v_position := i;
            v_typecode := v_desc_tab(i).col_type;

            --Pick COLUMN1 to be selected.
            if v_typecode = dbms_types.typecode_number then
                dbms_sql.define_column(v_cursor_number, i, v_number_value);
            --...repeat for every possible type.
            end if;
        end if;
    end loop;

    --Fetch all the rows, then get the relevant column value and print it
    while dbms_sql.fetch_rows(v_cursor_number) > 0 loop
        if v_typecode = dbms_types.typecode_number then
            dbms_sql.column_value(v_cursor_number, v_position, v_number_value);
            dbms_output.put_line('Value: '||v_number_value);
        --...repeat for every possible type
        end if;
    end loop;   
end;
/
    • Wow... und ich dachte, es wäre etwas triviales wie "select column1 from cursor".
    InformationsquelleAutor Jon Heller
  2. 3

    Angesichts der ursprünglichen Frage, jonearles Antwort noch richtig ist, also lasse ich es, als solche gekennzeichnet, aber ich landete etwas völlig anders und viel besser.

    Das problem war/ist, dass ich keine Kontrolle über SP1, Datenbank, ich muss nur rufen Sie es von irgendwo anders als 3rd-party-client. Jetzt habe ich es geschafft die Erlaubnis zu sehen, nicht nur SP, sondern auch die Art des Cursors. Ich verstehe immer noch nicht den Tisch, aber jetzt gibt es eine viel sauberere Lösung:

    In der anderen Datenbank die ich Zugriff haben, um zu sehen, diese Art jetzt:

    type cur_Table1 is ref cursor return Table1%rowtype;

    So, in meiner Datenbank kann ich dies jetzt zu tun:

    mycursor OtherDB.cur_Table1;
myrecord mycursor%rowtype;
...
OtherDB.SP1(mycursor);
fetch mycursor into myrecord;
dbms_output.put_line(myrecord.Column1);

    Sehen, ich habe immer noch keine Zugriff auf die Tabelle, sehe ich den cursor nur. Der Schlüssel ist, dass die Magie, %rowtype Werke für Cursor als auch, nicht nur Tabellen. Es funktioniert nicht auf einem sys_refcursor, aber es hat auf ein stark typisiertes ein. Angesichts dieser code, ich habe nicht zu kümmern, wenn sich etwas ändert auf der anderen Seite, ich nicht haben, definieren Sie die Spalten oder Datensätze an alle, ich geben Sie einfach die eine Spalte, die mich interessieren.

    Liebe ich diesen OOP-Haltung zu Oracle.

    InformationsquelleAutor fejesjoco
  3. 1

    Weiß nicht, ob es eine option ist oder nicht, aber wäre es nicht eine bessere Lösung zu erstellen, die eine Funktion zurückgibt, die einen bestimmten Wert nach der Sie suchen? Das vermeidet den Aufwand für die Zusendung der zusätzlichen Daten. Alternativ könnten Sie einen cursor mit einer Reihe von bekannten it-Bereiche, die beide Parteien kennen.

    • Ich habe keine Kontrolle mehr über die SP ' s Datenbank, ich muss nur rufen Sie es von irgendwo anders als 3rd-party-client.
    InformationsquelleAutor DCookie
Schreibe einen Kommentar