Outlook makro zu sammeln/extrahieren von Daten aus "Betreff-Feld" der zahlreichen Meldungen in eine text-Datei

Bitte schreiben Sie diesen code, um Ihre Outlook-VBA-Modul. Ändern Sie die Namen einiger Ordner und Ziel-Datei, in der einige Zeilen weiter unten. Für weitere Informationen siehe Kommentare im sub.

Sub Retrieve_http()

'our Outlook folder- deifinitions
    Dim myItem As MailItem
    Dim myFolder As Folder
    Dim myNamespace As NameSpace
    Set myNamespace = Application.GetNamespace("MAPI")
    'put your folders name here
    '1st one is store folder which should refer to [email protected]
    'second is possibly 'inbox folder'
    Set myFolder = myNamespace.folders("[email protected]").folders("inbox")

'destination file
    Dim resFile As String
        resFile = "c:\Users\Kazik\Desktop\httpRequest.txt"
    Dim ff As Byte
        ff = FreeFile()
    'creating or opening it- each time you run this macro we will append data
    'until deletion of either file or its content
    Open resFile For Append As #ff

    For Each myItem In myFolder.items
        If InStr(1, myItem.Subject, "http://") > 0 And _
            InStr(1, myItem.Subject, "classified under:") > 0 Then
                'write to file
                Write #ff, myItem.Subject

        End If
    Next
    Close #ff
End Sub

BEARBEITEN zu enthalten entsprechende Löschung Prozess-und Referenz-code, um das Bild.

Dem folgenden Bild vorhanden Outlook-Fenster (polnische version) wo: Business E-Mail ist eine der Top-Ordner (der sich auf separate .pst-Datei). 'Skrzynka odbiorcza' nur 'Posteingang'.

Code, die Suche nach bestimmten E-Mails, ruft Betreff der E-Mails auf und löscht E-Mails danach wie folgt aus:

Sub Retrieve_http()

'our Outlook folder- deifinitions
    Dim myItem As MailItem
    Dim myFolder As Folder
    Dim myNamespace As NameSpace
    Set myNamespace = Application.GetNamespace("MAPI")
    'put your folders name here
    Set myFolder = myNamespace.folders("Business Mail").folders("skrzynka odbiorcza")

'destination file
    Dim resFile As String
        resFile = "c:\Users\Kazik\Desktop\httpRequest.txt"
    Dim ff As Byte
        ff = FreeFile()
    'creating or opening it- each time you run this macro we will append data
    'until deletion of either file or its content
    Open resFile For Append As #ff
    Dim i!
    For i = myFolder.items.Count To 1 Step -1
        If InStr(1, myFolder.items(i).Subject, "http://") > 0 And _
            InStr(1, myFolder.items(i).Subject, "classified under") > 0 Then
                'write to file
                Write #ff, myFolder.items(i).Subject
                'delete item
                myFolder.items(i).Delete
        End If
    Next
    Close #ff
End Sub

InformationsquelleAutor Kazimierz Jawor