Parsen von JSON-feed automatisch in MS Access

Mithilfe der VBA JSON Bibliothek, Sie kann sicherlich importieren JSON-formatierte Dateien in MS Access. Die Idee ist, zu betrachten, JSON-Daten als eine Sammlung von Wörterbüchern und Visual Basic stellt die Sammlung und Wörterbuch als Datenstrukturen.

Unten sind die Schritte:

1. Erstellen Sie eine Tabelle entsprechend der Struktur der erwarteten JSON-Daten
2. Auf die VBA-IDE Seite von MS Access, importieren Sie die JsonConverter.bas (vom link oben) in ein neues Modul
3. Noch in der IDE, unter " Extras /Verweise, aktivieren Sie das VBA-Referenz: Microsoft Scripting Runtime
4. Den folgenden code enthalten, der liest den JSON-text-Datei, analysiert es als eine Sammlung von Wörterbüchern (mit Schlüssel und valeus), und fügt die Werte iterativ in die Access-Tabelle. Platzieren Sie code hinter einem Access-Formular oder-Modul (Beispiel verwendet eine geschachtelte Ebene JSON-Datei)

JSON

[
  {
    "col1": somenumber,
    "col2": "somestring",
    "col3": "somestring",
    "col4": "somestring",
    "col5": "somestring"
  }
]

VBA-Code

Private Function JSONImport()
    Dim db As Database, qdef As Querydef
    Dim FileNum As Integer
    Dim DataLine As String, jsonStr As String, strSQL As String
    Dim p As Object, element As Variant        

    Set db = CurrentDb

    ' READ FROM EXTERNAL FILE
    FileNum = FreeFile()
    Open "C:\Path\To\JsonFile.json" For Input As #FileNum

    ' PARSE FILE STRING
    jsonStr = ""
    While Not EOF(FileNum)
        Line Input #FileNum, DataLine

        jsonStr = jsonStr & DataLine & vbNewLine
    Wend
    Close #FileNum
    Set p = ParseJson(jsonStr)

    ' ITERATE THROUGH DATA ROWS, APPENDING TO TABLE
    For Each element In p
        strSQL = "PARAMETERS [col1] Long, [col2] Text(255), [col3] Text(255), " _
                          & "[col4] Text(255), [col5] Text(255); " _
                  & "INSERT INTO TableName (col1, col2, col3, col4, col5) " _
                          & "VALUES([col1], [col2], [col3], [col4], [col5]);"

        Set qdef = db.CreateQueryDef("", strSQL)

        qdef!col1 = element("col1")
        qdef!col2 = element("col2")
        qdef!col3 = element("col3")
        qdef!col4 = element("col4")
        qdef!col5 = element("col5")

        qdef.Execute
    Next element

    Set element = Nothing
    Set p = Nothing
End Function

InformationsquelleAutor Parfait