Pivot auf Oracle 10g

Ich bin mit oracle 10g.
Ich habe eine temporäre Tabelle TEMP.

TEMP hat folgende Struktur:-

USER COUNT TYPE
---- ----- ----
   1    10   T1
   2    21   T2
   3    45   T1
   1     7   T1
   2     1   T3

Brauche ich eine Abfrage, die alle Typen hat Sie die Spaltennamen und-Typen können einen beliebigen Wert haben wie T1, T2,..Tn und das Ergebnis wird ähnlich sein:-

USER T1 T2 T3
---- -- -- --
   1 17  0  1
   2  0 21  1
   3 45  0  0

und Spalte Benutzer zeigt alle Benutzer und - T1, T2 Spalte zeigt die Gesamtzahl der Arten.

keine Ahnung, wie dies zu tun
Sie müssen geben eine klare Beispiel dafür, was dein Ergebnis sein soll, mit der Beispiel-Tabelle.
bitte überprüfen Sie Beispiel-Ausgabe in Frage bearbeitet
es ist keine statische sql-Lösung, es sei denn, der T1.. Tn-Betrag ist begrenzt und bekannt. ansonsten, dynamische sql-und ref Cursor werden Ihre Optionen

InformationsquelleAutor F11 | 2012-11-16

  1. 7

    In Oracle 10g, gab es keine PIVOT Funktion, aber Sie können zu replizieren, mit der ein Aggregat mit einem CASE:

    select usr,
  sum(case when tp ='T1' then cnt else 0 end) T1,
  sum(case when tp ='T2' then cnt else 0 end) T2,
  sum(case when tp ='T3' then cnt else 0 end) T3
from temp
group by usr;

    Sehen SQL Fiddle mit Demo

    Wenn Sie Oracle 11g+ dann können Sie die PIVOT Funktion:

    select *
from temp
pivot
(
  sum(cnt)
  for tp in ('T1', 'T2', 'T3')
) piv

    Sehen SQL Fiddle mit Demo

    Wenn Sie eine unbekannte Anzahl von Werten zu transformieren, dann können Sie ein Verfahren zum generieren einer dynamischen version:

    CREATE OR REPLACE procedure dynamic_pivot(p_cursor in out sys_refcursor)
as
    sql_query varchar2(1000) := 'select usr ';

    begin
        for x in (select distinct tp from temp order by 1)
        loop
            sql_query := sql_query ||
              ' , sum(case when tp = '''||x.tp||''' then cnt else 0 end) as '||x.tp;

                dbms_output.put_line(sql_query);
        end loop;

        sql_query := sql_query || ' from temp group by usr';

        open p_cursor for sql_query;
    end;
/

    dann, um den code auszuführen:

    variable x refcursor
exec dynamic_pivot(:x)
print x

    Das Ergebnis für alle Versionen ist die gleiche:

    | USR | T1 | T2 | T3 |
----------------------
|   1 | 17 |  0 |  0 |
|   2 |  0 | 21 |  1 |
|   3 | 45 |  0 |  0 |

    Edit: Basierend auf Ihren Kommentar, wenn Sie möchten, eine Total Bereich, der einfachste Weg ist, die Abfrage in einem anderen SELECT ähnlich wie diese:

    select usr,
  T1 + T2 + T3 as Total,
  T1,
  T2,
  T3
from
(
  select usr,
    sum(case when tp ='T1' then cnt else 0 end) T1,
    sum(case when tp ='T2' then cnt else 0 end) T2,
    sum(case when tp ='T3' then cnt else 0 end) T3
  from temp
  group by usr
) src;

    Sehen SQL Fiddle mit Demo

    Brauche ich eine Spalte zwischen BENUTZER und T1 zeigen die Gesamtzahl der Arten,wie kann es getan werden, durch Abfrage.Ausgabe sollte so sein:- | USR |Gesamt | T1 | T2 | T3| ---------------------- Spalte Total zeigt die Summe von T1,T2,T3
    Ihre beste Wette ist, stellen Sie Ihre Abfrage in einem anderen wählen Sie, ähnlich wie in dieser demo - sqlfiddle.com/#!4/a42bb/5
    Ich brauche noch eine Hilfe.Ich habe zu zeigen, Summe aller Zeilen mit header.Insgesamt wird Hinzugefügt, mit Kopfzeile, in der Summe ist die Summe der Spalte.Wie Benutzer|Total_Total|T1_Total|T2_Total|
    Dann verwenden Sie spaltenaliasnamen auf der select-Anweisung. So wählen usr User, etc. aber wenn Sie noch weitere Fragen haben, sollten Sie veröffentlichen eine neue Frage.
    ich habe es gepostet als eine neue Frage,stackoverflow.com/questions/14037006/...

    InformationsquelleAutor Taryn

  2. 2

    Hier ist ein code zur Erstellung der Tabelle:

    CREATE TABLE TBL_TEMP
(
    USR   NUMBER
   ,CNT   NUMBER
   ,TP    VARCHAR2 (10)
);

INSERT INTO TBL_TEMP VALUES (1,10,'T1');
INSERT INTO TBL_TEMP  VALUES (2,21,'T2');
INSERT INTO TBL_TEMP  VALUES (3,45,'T1');
INSERT INTO TBL_TEMP  VALUES (1,7,'T1');
INSERT INTO TBL_TEMP  VALUES (2,1,'T3');

    Und hier ist ein code für Ihre Anfrage:

      SELECT T1.USR
        ,SUM (T1) T1
        ,SUM (T2) T2
        ,SUM (T3) T3
    FROM (SELECT DISTINCT USR FROM TBL_TEMP) T1
        ,(SELECT T2.USR
                ,DECODE (T2.TP, 'T1', T2.CNT, 0) T1
                ,DECODE (T2.TP, 'T2', T2.CNT, 0) T2
                ,DECODE (T2.TP, 'T3', T2.CNT, 0) T3
            FROM TBL_TEMP T2) T2
   WHERE T1.USR = T2.USR
GROUP BY T1.USR;

    Und das Ergebnis ist das, was Sie wollte.

    Überprüfen Sie es auf SQL Fiddle-Link hier

    +1. Für die künftigen Nutzer, Oracle 11g führt die pivot-Funktionalität

    InformationsquelleAutor kangbu

  3. 0

    Bitte überprüfen Sie die Abfrage:

    SET SERVEROUTPUT ON;
DECLARE
CURSOR V_CUR IS
 SELECT DISTINCT "TYPE" FROM temp_tbl;

V_QUERY CLOB;
V_COLUMNHEADING CLOB;
V_ROW V_CUR%ROWTYPE;
BEGIN
  OPEN V_CUR;
  LOOP
  FETCH V_CUR INTO V_ROW;
  EXIT WHEN V_CUR%NOTFOUND;
    V_COLUMNHEADING:=CONCAT(V_COLUMNHEADING,''''||V_ROW."TYPE"||''' AS "'||V_ROW."TYPE"||'",');
  END LOOP;

  IF NVL(V_COLUMNHEADING,' ') <> ' ' THEN
        V_COLUMNHEADING := SUBSTR(V_COLUMNHEADING,0,LENGTH(V_COLUMNHEADING)-1);
  END IF;

  V_QUERY := CONCAT(V_QUERY,'select * from (select * from temp_tbl)a pivot (sum("COUNT")for "TYPE" in ('||V_COLUMNHEADING||'))b;');
  DBMS_OUTPUT.PUT_LINE(V_QUERY);
END ;

    Daten auszuwählen, verwenden Sie Anweisung OPEN CUR_TURN_TIME FOR V_QUERY; im Ort DBMS_OUTPUT.PUT_LINE(V_QUERY);, wo CUR_TURN_TIME ist der cursor deklariert wurde das Paket.

    InformationsquelleAutor TechDo

Schreibe einen Kommentar