PL / SQL-Ausdruck-Ref-Cursor, der von einer gespeicherten Prozedur zurückgegeben wird

Wie kann ich das abrufen aus, um einen ref-cursor, der zurückgegeben wird, aus einer gespeicherten Prozedur (OUT-Variablen), und drucken Sie die resultierenden Zeilen in STDOUT in SQL*PLUS?

ORACLE-gespeicherten Prozedur:

PROCEDURE GetGrantListByPI(p_firstname IN VARCHAR2, p_lastname IN VARCHAR2,
p_orderby IN VARCHAR2, p_cursor OUT grantcur);

PL/SQL:

SET SERVEROUTPUT ON;

DECLARE
  TYPE r_cursor IS REF CURSOR;
  refCursor r_cursor;

  CURSOR grantCursor IS
    SELECT last_name, first_name
    FROM ten_year_pis
    WHERE year_added = 2010;

  last_name VARCHAR2(100);
  first_name VARCHAR2(100);

BEGIN
  OPEN grantCursor;
  FETCH grantCursor INTO last_name, first_name;

  WHILE grantCursor%FOUND LOOP
    PMAWEB_PKG.GetGrantListByPI(last_name, first_name, 'last_name', refCursor);

    --HOW DO I LOOP THROUGH THE RETURNED REF CURSOR (refCursor)
    --AND PRINT THE RESULTING ROWS TO STDOUT?

    FETCH grantCursor into last_name, first_name;
  END LOOP;
  CLOSE grantCursor;
END;
/

InformationsquelleAutor der Frage elpisu | 2011-04-28

  1. 36

    Hinweis: Dieser code ist ungetestet

    Definieren Sie einen Eintrag für Ihre refCursor zurück geben, nennen Sie es, rec. Zum Beispiel:

    TYPE MyRec IS RECORD (col1 VARCHAR2(10), col2 VARCHAR2(20), ...);  --define the record
rec MyRec;        -- instantiate the record

    Sobald Sie die refcursor der Rückkehr von Ihrem Verfahren können Sie fügen Sie den folgenden code, wo Ihre Kommentare sind jetzt:

    LOOP
  FETCH refCursor INTO rec;
  EXIT WHEN refCursor%NOTFOUND;
  dbms_output.put_line(rec.col1||','||rec.col2||','||...);
END LOOP;

    InformationsquelleAutor der Antwort DCookie

  2. 17

    Können Sie eine bind-variable auf SQLPlus-Ebene, dies zu tun. Natürlich, Sie haben wenig Kontrolle über die Formatierung der Ausgabe.

    VAR x REFCURSOR;
EXEC GetGrantListByPI(args, :x);
PRINT :x;

    InformationsquelleAutor der Antwort Dave Costa

  3. 2

    Wenn Sie möchten, drucken Sie alle Spalten in der select-Klausel können Sie gehen mit der autoprint-Befehl.

    CREATE OR REPLACE PROCEDURE sps_detail_dtest(v_refcur OUT sys_refcursor)
AS
BEGIN
  OPEN v_refcur FOR 'select * from dummy_table';
END;

SET autoprint on;

--calling the procedure
VAR vcur refcursor;
DECLARE 
BEGIN
  sps_detail_dtest(vrefcur=>:vcur);
END;

    Hoffe, das gibt Ihnen eine Alternative Lösung

    InformationsquelleAutor der Antwort akzhere

Schreibe einen Kommentar