Prolog: Filtern einer Liste?

Derzeit arbeite ich an einem sehr kurzen Projekt auf den Prolog, und nur steckengeblieben versucht, einen "filter" die ich erstellt habe, auf eine Liste. Ich habe das, was man nennen könnte den filter bereit, aber ich kann Sie nicht anwenden. Es wäre besser, wenn ich verdeutlichen:

filter(A, B)

...gibt 'wahr', wenn bestimmte Bedingungen erfüllt sind.

filterList(A, [X, Y, Z])

...gibt eine Liste, die enthält alle Elemente aus der zweiten argument, dass der filter Ausgang false. (Also, wenn der filter(A, X) wahr ist, wird der Ausgang [Y, Z] ).

Habe ich den "filter" - Funktion bereit, aber jetzt muss ich es anwenden, um eine Liste wie auf dem zweiten Beispiel, ohne alle Elemente, für die der filter true zurück, wenn angewendet mit dem ersten argument.

So, wenn der filter ist eine einfache A == B, die Funktion soll erhalten [A,B,A,C,D,A] und output [B,C,D], nachdem entfernt alle Elemente, für die der filter anwendbar ist, offensichtlich.

Ich habe Probleme mit der grundlegenden Struktur von der Funktion, so, wenn jemand liefern könnte, einen grundlegenden überblick für eine Funktion wie diese, es wäre eine große Hilfe. Habe ich vereinfachte meine situation so viel wie möglich, damit ich Sie ergreifen können, was Sie möglicherweise in der Lage zu liefern, und ändern Sie es für meine Bedürfnisse.

Vielen Dank im Voraus!

InformationsquelleAutor der Frage Sergio Morales | 2008-11-18

12

Wenn Sie sind auf der Suche für höherwertige Funktionen in Prolog, sollten Sie auf jeden Fall konsultieren Naish (1995)eine sehr gute Ressource, auf dieser.

Seine definition von filter/3 ist die folgende (er verwendet-Differenz-Liste-notation, also entweicht zu definieren filter/4):
```
filter(_,[],[]).
filter(P, A0-As0, As) :-
    (
        call(P, A0) -> As = A0-As1
    ;
        As = As1
    )
    , filter(P, As0, As1).
```
Ich Sie haben Fragen zu diesem Prädikat, Fragen Sie mich bitte in den Kommentar. Zeitung Lesen ist auch sehr zu empfehlen, auch beeinflusst mapfoldr und compose! Beachten Sie, dass viele der Einschränkungen, die er erwähnt (wie zum Beispiel eine fehlende call/3 oder einer höheren apply nicht mehr anwenden. SWI-Prolog hat die =.. Betreiber, die Adressen all seine sorgen und macht beliebige n-order logic möglich.

InformationsquelleAutor der Antwort Aleksandar Dimitrov
9

SWI-Prolog bietet exclude/3 und andere meta-Prädikate. Deinem ursprünglichen problem kann codiert werden, wie diese:
```
are_identical(X, Y) :-
    X == Y.

filterList(A, In, Out) :-
    exclude(are_identical(A), In, Out).
```
Beispiel:
```
?- filterList(A, [A, B, A, C, D, A], Out).
Out = [B, C, D].
```
InformationsquelleAutor der Antwort Kaarel
3

Gibt es eine inhärente problem mit filter-Funktionen, die den Erfolg oder das scheitern eines Prädikats als Kriterium für die Filterung: Das entstehende Programm ist nicht mehr eine Reine monotone Programm. Es verliert dadurch alle seine deklarative Eigenschaften — die einzige Bedeutung ist, die bleibt, ist eine Verfahrens-Schritt-für-Schritt-interpretation. Hier ist eine Reine, vergegenständlicht version filtern mit if_/3:
```
tfilter(_CT_2,    [], []).
tfilter(CT_2, [E|Es], Fs0) :-
   if_(call(CT_2,E), Fs0 = [E|Fs], Fs0 = Fs ),
   tfilter(CT_2, Es, Fs).
```
Das erste argument ist also eine Schließung/Fortführung, erhalten zwei weitere Argumente: Das element und die resultierende Wahrheitswert.
```
=(X,X,true).
=(X,Y,false) :- dif(X,Y).
```
Nun, die Ergebnisse präzise bleiben:
```
| ?- tfilter(=(X),[A,B],Xs).
B = A,
X = A,
Xs = [A,A] ? ;
X = A,
Xs = [A],
dif(A,B) ? ;
X = B,
Xs = [B],
dif(B,A) ? ;
Xs = [],
dif(X,A),
dif(X,B) ? ;
no
```
Gibt es vier Möglichkeiten, wie eine Liste mit zwei Elementen können gefiltert werden, indem das Kriterium der gleich X. Jedes element kann gleich oder unterschiedlich sein kann.

Der Nachteil dieses Ansatzes ist, dass man zu bieten hat vergegenständlicht Versionen aller Kriterien.

InformationsquelleAutor der Antwort false

Gut, was würden Sie wissen, habe ich gerade herausgefunden. So, hier ist mir der Einreichung eine Antwort auf meine Frage, wie erwartet, eine sehr kurze Funktion hat die Aufgabe:

filterList(_,[],R,R).           % Returns answer when the list is exhausted.
filterList(L,[A|List],Temp,Res) :-
   filterList(L,List,New,Res),  % Recursive call, New is either the same list
   (  filter(L,A),              % in case the filter outputs true, or the list
      New = Temp
   ;  New = [A|Temp]            % plus the current element otherwise.
   ).

InformationsquelleAutor der Antwort Sergio Morales

0

Bekomme ich die Erwachsenen, die in einem Land //Obtengo los adultos de un pais, Land = Pais, Personen = Personas, Person = una sola Persona
```
habitants(USA, [juan, pedro, david])

adults(Adults, Country) :-
     findall(Person, (habitants(Country,People), member(People, Person), adult(Person)), Adults)
```
Dies ist ein filter in prolog //Asi es-un-filter en prolog

InformationsquelleAutor der Antwort Jesus Ledesma

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.