Reflexion in PLSQL?

Ich Schreibe eine Prozedur zum Umgang mit benutzerdefinierten Objekt, das gespeichert ist in ANYDATA. Der Objekt-Typ und Attribut-Namen können erst zur Laufzeit, also kann ich nicht definieren, das viarable, für die es im declare-Abschnitt. In Java kann ich mit Reflexion zu beschäftigen, kann ich wissen, den Namen der Klasse und die Felder für name. Dann kann ich den Zugriff auf die Felder durch Reflexion. Gibt es eine Möglichkeit, es zu tun in PLSQL-wie das? Was in meinem Kopf gerade jetzt ist die Schaffung einer sql-string in der Prozedur dynamisch, und führen Sie es aus. Aber es ist nicht das, was ich will, genau.

Angenommen, Benutzer A definiert ein ADT geben Sie als create or replace type Person_type as object (fname varchar2(10), lname varchar2(10)); und erstellen Sie eine Objekt-Instanz und fügen Sie ihn in ANYDATA.

In meinem Verfahren, irgendwie ich weiß, ich benötigen, um mit dem ersten Attribut dieses Objekts, die fname. Also, wenn wissen, das adt-type auf den ersten Platz, mein code wird so sein:

declare
  adobject A.Person_type; -- HERE! I don't know the type yet, so I can't define adobject!
  tempAnydata anydata;
  rt number;
  vbuffer varchar2(10);
  ...
begin
   select somecolumn 
   into tempAnydata 
   from sometable 
   where something='something' for update;

   rt := tempAnydata.GetObject(adobject);

   vbuffer := adobject.fname; -- HERE! I don't know the attribute name is fname!
   -- deal with vbuffer here
end;

Also was soll ich tun, damit es dynamisch? Vielen Dank im Voraus.

Wenn Sie wissen, dass die tempAnydata ist wirklich ein A.person_type wie Sie sicherlich tun (sonst könnten Sie nicht tun, die GetObject(adobject) mit adobject von genau dieser Art), dann sollte man auch wissen, was in dieser Art das erste Attribut ist. Oder bin ich etwas fehlt?
A. person_type ist nur ein Beispiel, es könnte einer benutzerdefinierten Typ an. Es könnte sein, B. anymal_type oder etwas anderes.
Statische starke Typisierung saugt. (grumpy old Smalltalker wandert aus und murmelte zu sich selbst 🙂

InformationsquelleAutor icespace | 2012-04-19

Müssen Sie ANYTYPE zu beschreiben, die ANYDATA und sorgen dafür das der Typ korrekt ist. Dann können Sie den Zugriff auf die attribute über piecewise und getVarchar2.

Meisten der code ist für die überprüfung der Art, die Sie nicht benötigen, wenn Sie nicht besorgt über Art Sicherheit.

Funktion Rückgabewert:

create or replace function get_first_attribute(
    p_anydata in out anydata --note the "out" - this is required for the "piecewise"
) return varchar2 is
    v_typecode pls_integer;
    v_anytype anytype;
begin
    --Get the typecode, and the ANYTYPE
    v_typecode := p_anydata.getType(v_anytype);

    --Check that it's really an object
    if v_typecode = dbms_types.typecode_object then
        --If it is an object, find the first item
        declare
            v_first_attribute_typecode pls_integer;
            v_aname          varchar2(32767);
            v_result         pls_integer;
            v_varchar        varchar2(32767);
            --Variables we don't really care about, but need for function output
            v_prec           pls_integer; 
            v_scale          pls_integer;
            v_len            pls_integer;
            v_csid           pls_integer;
            v_csfrm          pls_integer;
            v_attr_elt_type  anytype;
        begin
            v_first_attribute_typecode := v_anytype.getAttrElemInfo(
                pos            => 1, --First attribute
                prec           => v_prec,
                scale          => v_scale,
                len            => v_len,
                csid           => v_csid,
                csfrm          => v_csfrm,
                attr_elt_type  => v_attr_elt_type,
                aname          => v_aname);

            --Check typecode of attribute
            if v_first_attribute_typecode = dbms_types.typecode_varchar2 then
                --Now that we've verified the type, get the actual value.
                p_anydata.piecewise;
                v_result := p_anydata.getVarchar2(c => v_varchar);

                --DEBUG: Print the attribute name, in case you're curious
                --dbms_output.put_line('v_aname: '||v_aname);

                return v_varchar;
            else
                raise_application_error(-20000, 'Unexpected 1st Attribute Typecode: '||
                    v_first_attribute_typecode);
            end if;
        end;
    else
        raise_application_error(-20000, 'Unexpected Typecode: '||v_typecode);
    end if;
end;
/

Typen:

create or replace type Person_type as object (fname varchar2(10), lname varchar2(10));

create or replace type other_type as object (first_name varchar2(10), poetry clob);

Testlauf:

declare
    --Create records
    v_type1 person_type := person_type('Ford', 'Prefect');
    v_type2 other_type := other_type('Paula', 'blah blah...');
    v_anydata anydata;
begin
    --Convert to ANYDATA.
    --Works as long as ANYDATA is an object with a varchar2 as the first attribute.
    v_anydata := anydata.convertObject(v_type1);
    dbms_output.put_line(get_first_attribute(v_anydata));

    v_anydata := anydata.convertObject(v_type2);
    dbms_output.put_line(get_first_attribute(v_anydata));
end;
/

Ausgänge:

Ford
Paula

+1 - ich werde löschen meiner Antwort. Ich denke immer noch, das OP ' s-Architektur ist eine eigenartige, aber wenn Sie sind wirklich schwerfällig ist dies die richtige Lösung
Ich denke, Sie sollten halten Sie Ihre Antwort, kann es hilfreich sein. Ich habe gesehen, object-relational-Lösungen oft mehr, als ANYDATA. (Obwohl im Allgemeinen ich versuche zu vermeiden, die beide von Ihnen; ich bin immer ein wenig skeptisch gegenüber allzu generische Lösungen.)
Erstaunlich! Ich danke Ihnen SEHR, jonearles. Das ist wirklich das, was ich will!!! ANYTYPE, schön, Sie zu treffen.
Das Kernstück dieser (das war die Sache, die ich kam hierher auf der Suche nach) entpuppt sich anydata.convertobject(self).gettypename() (oder ersetzen self mit dem Namen eine Art Instanz, wenn Sie von außen betrachtet, z.B. adobject in OP ' s Beispiel).

InformationsquelleAutor Jon Heller

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.