Senden Sie eine E-Mail über VB6

Frage ich mich, ob es eine Möglichkeit gibt eine E-Mail senden (SMTP) über VB6. Ich habe eine Anwendung, die nur senden muss, um eine einfache E-Mail, wenn der Benutzer geschieht, um zu lassen Sie eine Gruppe kennen, die von der Anwendung verarbeitet. Gibt es eine Möglichkeit, das zu tun?

Siehe auch stackoverflow.com/questions/3539242/... stackoverflow.com/questions/5155611/...

InformationsquelleAutor gary A.K.A. G4 | 2011-04-01

Ja - hängt davon ab, welche version von windows Sie verwenden. Vorausgesetzt, einer der späteren Versionen - CDO.Nachricht funktioniert Super.

Sub SendMessage(MailFrom,MailTo,Subject,Message)
    Dim ObjSendMail
    Set ObjSendMail = CreateObject("CDO.Message")

    'This section provides the configuration information for the remote SMTP server.

    With ObjSendMail.Configuration.Fields
    .Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 'Send the message using the network (SMTP over the network).
    .Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smpt server Address"
    .Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
    .Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False 'Use SSL for the connection (True or False)
    .Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

    ' If your server requires outgoing authentication uncomment the lines below and use a valid email address and password.
'    .Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 'basic (clear-text) authentication
'    .Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = MailFrom
'    .Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = yourpassword

    .Update
    End With

    'End remote SMTP server configuration section==

    ObjSendMail.To = MailTo
    ObjSendMail.Subject = Subject
    ObjSendMail.From = MailFrom

    ' we are sending a html email.. simply switch the comments around to send a text email instead
    ObjSendMail.HTMLBody = Message
    'ObjSendMail.TextBody = Message

    ObjSendMail.Send

    Set ObjSendMail = Nothing
End Sub

Durch die Einstellung einen Verweis auf die Bibliothek erhalten Sie auch benannte Konstanten für diese Feldnamen und magischen zahlen.

InformationsquelleAutor Dave

Fand ich diese hier:

Dim UserName$, UserMail$, MailRecipiant$, MailBody$, SockData$

Private Sub Command1_Click()
UserName = "YourUserName_or_Addr"
UserMail = "Your Name <[email protected]>"
MailRecipiant = UserMail
MailBody = "The message goes here"
Winsock1.LocalPort = 0
Winsock1.RemoteHost = "smtp-server"
Winsock1.RemotePort = 25
Winsock1.Connect
End Sub

Private Sub Winsock1_Connect()
Label1 = "Sending message..."
Winsock1.SendData "EHLO " & UserName & vbCrLf
If Not WaitFor("250") Then GoTo 100
Winsock1.SendData "MAIL FROM: " & UserMail & vbCrLf
If Not WaitFor("250") Then GoTo 100
Winsock1.SendData "RCPT TO: " & MailRecipiant & vbCrLf
If Not WaitFor("250") Then GoTo 100
Winsock1.SendData "DATA" & vbCrLf
If Not WaitFor("354") Then GoTo 100
Winsock1.SendData MailBody & vbCrLf & "." & vbCrLf
If Not WaitFor("250") Then GoTo 100
Winsock1.SendData "QUIT" & vbCrLf
If Not WaitFor("221") Then GoTo 100
Label1 = "Message sent"
GoTo 200
100
Label1 = SockData
200
Winsock1.Close
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
Winsock1.GetData SockData
End Sub

Private Sub Winsock1_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
Label1 = "Error: " & Description
SockData = "Error"
Winsock1.Close
End Sub

Private Function WaitFor(SockResponse As String) As Boolean
Do While Left(SockData, 3) <> SockResponse And Left(SockData, 3) <> "220" And Left(SockData, 3) <> "250"
  DoEvents
  If Left(SockData, 3) > "400" Then Exit Function
Loop
WaitFor = 1
SockData = ""
End Function

warum abgestürzten gestimmt?
Habe es getestet und es funktioniert in VB 6.0...
Vielleicht, weil dieser Ansatz schlägt fehl, wenn Sie brauchen, verschlüsselte Authentifizierung oder SSL/TLS-übertragung? Diese sind relativ Häufig Anforderungen nicht mehr. Attachments und HTML-Mails auch hinzufügen, mehr clunkiness dieser roll-your-own-Ansatz. Es ist toll, in wenigen Fällen aber.
"einfache E-Mail, wenn der Benutzer geschieht, um zu lassen Sie eine Gruppe kennen, die von der Anwendung verarbeitet"

InformationsquelleAutor SQLMason

3

Sollten Sie hoffentlich haben Sie die CDOSYS-Bibliotheken auf Ihrem Rechner installiert ist:

CDO-Messaging - MSDN

Erstellen und Senden einer Nachricht - MSDN

Senden von E-Mail mit CDOSYS ( THE REAL DEAL )

ASP Senden von e-mail mit CDOSYS

Wenn du das nicht hast, Bibliothek (und nicht in der Lage, es zu installieren), dann gibt es immer CDONTS zurückgreifen, aber es ist veraltet:

Mit Hilfe der CDONTS Komponente versenden E-Mail von ASP-Seiten.

InformationsquelleAutor Kev
0

Dave hat eine gute Lösung, wenn Sie wirklich brauchen, um E-Mail senden von dem client-PC. Jedoch, manchmal, bekommen Sie in Schwierigkeiten mit firewalls und so. In dem Fall, wo Sie eine Verbindung zu einem SQL-Server habe ich festgestellt, es ist einfacher und leichter zu verwalten, wenn Sie Ihre proxy-E-mail über SQL-Server (entweder durch queuing in einer ausgehenden E-mail-Tabelle, oder rufen Sie die xp_sendmail gespeicherte Prozedur selbst).

Hier ist ein tutorial, wie Sie SQL E-Mail-setup und auf dem server arbeiten, und am Ende es zeigt, wie eine gespeicherte Prozedur verwenden, um eine E-Mail senden.

Fand ich diese Lösung vorteilhaft, weil:
- Windows 7 Computer blockiert alle ausgehenden SMTP -
- Umsetzung der Wiederholungen und so zu tun, ausgehende E-Mails "richtig" war ziemlich kompliziert
- Mit Hilfe des queue-Methode mit SQL Server, aber nicht wirklich zum einrichten von SQL Mail auf meinem Entwicklungs-und test-Datenbanken, E-Mails blieben in der Warteschlange, es sei denn, ich war nicht gegen den produktiven server
InformationsquelleAutor Scott Whitlock
0

Wir haben die OstroSoft SMTP control bisher mit sehr guten Ergebnissen.

InformationsquelleAutor Mark Kram

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.