So ersetzen Sie alle Leerzeichen durch Unterstriche in allen Dateinamen in einem Ordner?

Ich versuche, umbenennen alle Dateien in einem Ordner (alle .exe-Dateien). Ich möchte, um zu ersetzen Sie alle Leerzeichen durch Unterstriche, z.B. qwe qwe qwe asd.exe zu qwe_qwe_qwe_asd.exe.

Muss ich dies über die Befehlszeile. Ich habe versucht, eine Menge von möglichen Lösungen, die ich gefunden im internet und auch auf dieser Seite, aber ich kann nicht damit es funktioniert.

Brauche ich auch, um dies zu tun, in "einer Zeile" /"ein-Befehl", aber ich nehme an, alle die arbeiten, Antworten.

InformationsquelleAutor Matias Elorriaga | 2013-12-26

47

Einen one-liner
```
cmd /e:on /v:on /c "for %f in ("* *.exe") do (set "n=%~nxf" & set "n=!n: =_!" & ren "%~ff" "!n!" )"
```
Spawn eine cmd-Instanz, mit Erweiterungen und verzögerte Erweiterung aktiviert, und für jede exe-Datei mit Leerzeichen im Namen, ersetzen Sie die Leerzeichen mit Unterstrichen und benennen Sie die Datei mit dem neuen Namen
- es funktioniert! danke!!!
- wow, danke, das war ein Lebensretter!
InformationsquelleAutor MC ND
17

Angepasst von hier:

https://stackoverflow.com/a/16129486/2000557
```
@echo off
Setlocal enabledelayedexpansion

Set "Pattern= "
Set "Replace=_"

For %%a in (*.exe) Do (
    Set "File=%%~a"
    Ren "%%a" "!File:%Pattern%=%Replace%!"
)

Pause&Exit
```
Erstellen Sie eine batch-Datei (*.bat) mit dem oben genannten Inhalt. Platzieren Sie diese batch-Datei in den Ordner mit allen .exe und es wird ersetzen Sie die Leerzeichen durch Unterstriche, wenn Sie es ausführen.
- vielen Dank für die Beantwortung, aber ich kann nicht verwenden Sie eine batch-Datei.., die ich brauche, um einen einzelnen Befehl..
- Sie können run for-Schleife direkt vom CMD - es ist nur 1 Zeichen'%', z.B.::::::::::::::::::::::::::::::: for %i in (*.css) do ( ren "%~i" "_%~i.scss" ) => umbenennen, alle Dateien, die mit .css-Erweiterung "_ORIGINALFILENAME.scss"
InformationsquelleAutor Gray
11

Einfach:
```
set filename=qwe qwe qwe asd.exe
set filename=%filename: =_%
```
- wie funktioniert das umbenennen von Dateien?
- set filename=qwe qwe qwe asd.exe, set filename2=%filename: =_%, ren "filename" "filename2"
- funktioniert nur so lange, wie der ursprüngliche Dateiname ist "qwe qwe qwe asc.exe"
InformationsquelleAutor n8b
6

Verwendung von forfiles:
```
forfiles /m *.exe /C "cmd /e:on /v:on /c set \"Phile=@file\" & if @ISDIR==FALSE ren @file !Phile: =_!"
```
Hinzufügen /s nach forfiles zu recurse durch Unterordner.
- In Fall, dass Sie wollen, ändern Sie Leerzeichen um Bindestriche oder Bindestriche, Unterstriche das bit, das steuert den "daraus, dass" die Logik ist Phile: =_!. Was kommt vor der = ist, was ersetzt wird. Das Ding, das geht nach der = ist das, was es ersetzt werden.
InformationsquelleAutor Jimadine
3

Basierend auf @Grau Antwort, ich habe es verlängern zu ersetzen Dateinamen rekursiv in alle Unterverzeichnisse.

Datei 1: ersetzen.bat
```
setlocal enabledelayedexpansion

set "pattern= "
set "replace=_"

for %%I in (*.ext) do (
    set "file=%%~I"
    ren "%%I" "!file:%pattern%=%replace%!"
)
```
Datei 2: rekursiv.bat
```
for /d /r . %%D in (*) do (
    copy replace.bat "%%D\replace.bat"
    cd "%%D"
    replace.bat
    del replace.bat
    cd..
)
```
Dateien
- replace.bat enthält Skript zum ersetzen von space mit underscore
- recursive.bat enthält Skript zu tun Rekursion in Unterverzeichnissen
Wie zu benutzen?
- Sparen replace.bat und recursive.bat im gleichen Verzeichnis.
- Ersetzen .ext mit der gewünschten Dateiendung zu entsprechen (wie .mp4) in replace.bat.
- Doppelklick (ausführen) NUR recursive.bat Datei.
- dies funktioniert nur, wenn ich manuell kopieren Sie die ersetzen.Fledermaus in alle Unterordner. Ist schon ein Schmerz. Was sollte ich hinzufügen, um manuell kopieren Sie die ersetzen.Fledermaus auf alle Unterordner?
- Folgen Sie bitte wie zu verwenden - Abschnitt
- Mhm, seh ich auch so übernehmen Sie theres nur ein Unterverzeichnis. In meinem Fall ist dies das Verzeichnis enthält auch viele Unterverzeichnisse mit jeweils einem Unterverzeichnis mit einer Datei die ich umbenennen möchten. Muss ich trotzdem kopieren Sie beide ersetzen und rekursive bat-Dateien zu jedem von Ihnen?
- Ort replace.bat und recursive.bat im übergeordneten Verzeichnis, dann funktioniert es auf alle untergeordneten Verzeichnisse.
InformationsquelleAutor Hamza Rashid
0

set data=%Datum:~6,4%%date:~3,2%%date:~0,2%_%time:~0,2%%time:~3,2%%time:~6,2%
set data=%data: =0%

InformationsquelleAutor ricarela
0

Speichern Sie die folgenden 2 Befehle in einer .bat - Datei. Es ersetzt " " mit "_" in allen Dateien und Ordnern, auch rekursiv, ausgehend vom Ordner, wo die Datei gespeichert ist.
```
forfiles /s /m *.* /C "cmd /e:on /v:on /c set \"Phile=@file\" & if @ISDIR==FALSE ren @file !Phile: =_!"
forfiles /s /C "cmd /e:on /v:on /c set \"Phile=@file\" & if @ISDIR==TRUE ren @file !Phile: =_!"
```
Hinweis: die Erste Zeile ist dabei für Dateien, und das zweite tut dies für Ordner. Jede Zeile kann separat verwendet werden.

InformationsquelleAutor Alex
0

Kleinere änderungen an Hamza Rashid die Antwort. Insbesondere seine rekursive.bat-Skript.

rekursiv.bat
```
set orig=%cd%

for /d /r . %%D in (*) do (
    copy replace.bat "%%D\replace.bat"
    cd "%%D"
    replace.bat
    del replace.bat
    cd %orig%
)
```
ersetzen.bat bleibt die gleiche, und die Anweisungen bleiben die gleichen.

InformationsquelleAutor DuckCowMooQuack

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.