So ersetzen Sie alle Sonder Zeichen in einer Zeichenfolge mit Leerzeichen?

Ich bin mit XSLT 1.0.

Angenommen ich habe eine Zeichenfolge, die ähnlich wie "apple-mango%auch|es"

Ich versuche, ersetzen Sie alle nicht-alphanumerischen Zeichen mit Leerzeichen.
Ich habe versucht,

<xsl:value-of select="translate(., translate(., '0123456789abcdefghijklmnopqrstuvwxysABCDEFGHIJKLMNOPQRSTUVWXYZ', ''), ' ')"/>

aber es hat nicht funktioniert.
Das Problem ist mit der äußeren übersetzen.

So wie ich das verstehe, in einem translate() die Länge der Dritten Zeichenfolge sollte derselbe sein wie der zweite string oder sonst die fehlenden Zeichen werden getroffen werden, um durch einen leeren string ersetzt ('').

Das innere zu übersetzen, funktioniert einwandfrei, da ich möchte, entfernen Sie alle Zeichen mit einem leeren string sowieso.

Aber die äußeren übersetzen ersetzt nur das erste Zeichen des zweiten argument-string mit einem Leerzeichen und ersetzt den rest mit einem leeren string.

Da meine Liste von nicht-alphanumerischen Zeichen im zweiten argument des äußeren übersetzen ist dynamisch, ich kann nicht pre-code, das Dritte argument.

ex:

Meine innere übersetzen zurück -%|. Ist das so richtig.

Nun auf mein äußeres zu übersetzen, ist translate(., '-%|', ' ').

Gibt apple mangoalsothere.

Wie kann es geschehen kurzen schreiben etwas wie dieses:

translate(., '`~!@#$%^&*()-_=+[]{}\|;:'",<.>/?', '                                  ')

Können Sie erklären, was falsch ist mit dem ersten Ausdruck, so dass in der Tat ersetzen Sie alle nicht-Zeichen alphameric mit einem Leerzeichen. Sie wirklich brauchen, um spezifisch über, was Sie tun müssen, da gibt es nicht wirklich eine definition von "Sonderzeichen". Entweder müssen Sie definieren, genau die Zeichen, die Sie behalten möchten, oder Sie definieren genau das, was Zeichen, das Sie entfernen möchten. Danke!!!
Die Doppel-übersetzen trick verwendet in Ihrem Versuch, genau diese Aufgabe zu bewältigen: die innere übersetzen erzeugt eine Liste aller Zeichen in der Eingabe nach dem entfernen ascii-alphanumerische Zeichen, und die äußeren übersetzen ersetzt alle Zeichen in dieser Liste durch Leerzeichen.
Durch Sonderzeichen meinte ich nicht-alphanumerische Zeichen. Finden Sie die aktualisierte Frage
Finden Sie die aktualisierte Frage

InformationsquelleAutor Surender Thakran | 2015-04-16

xslt xslt-1.0

Einen Weg, dies zu tun wäre eine rekursive Vorlage zu erstellen, die eine Zeichenfolge von nichts, sondern Räume für eine gegebene Länge

<xsl:template name="AllSpaces">
    <xsl:param name="spaces" />
    <xsl:if test="$spaces > 0">
        <xsl:text> </xsl:text>
        <xsl:call-template name="AllSpaces">
            <xsl:with-param name="spaces" select="$spaces - 1" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

Dann erzeugen Sie in einem string die Anzahl der Leerzeichen gleich der Länge der Zeichenfolge, mit der Sie arbeiten.

    <xsl:variable name="specialchars" select="translate(., '0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ', '')" />
    <xsl:variable name="spaces">
        <xsl:call-template name="AllSpaces">
            <xsl:with-param name="spaces" select="string-length($specialchars)" />
        </xsl:call-template>
    </xsl:variable>

Anschließend können Sie diese spaces variable in Ihre zu übersetzen. Zum Beispiel, versuchen Sie, diese XSLT -

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text" />

    <xsl:template match="data">
        <xsl:variable name="specialchars" select="translate(., '0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ', '')" />
        <xsl:variable name="spaces">
            <xsl:call-template name="AllSpaces">
                <xsl:with-param name="spaces" select="string-length($specialchars)" />
            </xsl:call-template>
        </xsl:variable>
        <xsl:value-of select="translate(., $specialchars, $spaces)"/>
    </xsl:template>

    <xsl:template name="AllSpaces">
        <xsl:param name="spaces" />
        <xsl:if test="$spaces > 0">
            <xsl:text> </xsl:text>
            <xsl:call-template name="AllSpaces">
                <xsl:with-param name="spaces" select="$spaces - 1" />
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Nun, wenn Sie hatte mehrere Zeichenfolgen, die Sie ersetzen wollte, in Ihre XML -, Sie könnten etwas verbessern, Dinge, die durch eine Globale variable für spaces wurde gleich der Länge des längsten Strings. Dies würde Ihnen mehr Räume als Sie benötigt, aber, dass wäre kein problem.

Versuchen, diese XSLT zu

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text" />

    <xsl:variable name="spaces">
        <xsl:for-each select="//data">
            <xsl:sort select="string-length(.)" order="descending" />
            <xsl:if test="position() = 1">
                <xsl:call-template name="AllSpaces">
                    <xsl:with-param name="spaces" select="string-length(.)" />
                </xsl:call-template>
            </xsl:if>
        </xsl:for-each>
    </xsl:variable>

    <xsl:template match="data">
        <xsl:value-of select="translate(., translate(., '0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ', ''), $spaces)"/>
    </xsl:template>

    <xsl:template name="AllSpaces">
        <xsl:param name="spaces" />
        <xsl:if test="$spaces > 0">
            <xsl:text> </xsl:text>
            <xsl:call-template name="AllSpaces">
                <xsl:with-param name="spaces" select="$spaces - 1" />
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Angewandt auf das XML -

<test>
    <data>apple-mango%also|there</data>
    <data>apple-mango%also|there!test</data>
</test>

Folgende Ausgabe

apple mango also there
apple mango also there test

Hinweis:: Wenn Sie mit Xalan oder libxslt, die Sie verwenden können, die EXSLT str:padding() Funktion zum generieren der erforderlichen string aus Leerzeichen.
tolle Antwort. danke
Einschränkung: das Letzte Zeichen des Alphabets ist z - nicht ein anderer s.

InformationsquelleAutor Tim C

Andere Weise, die Sie Aussehen könnte auf diese ist das Ergebnis der "inneren übersetzen" - ich.e die Zeichenfolge, die alle unerwünschten Zeichen, die als parameter in eine benannte rekursive template ersetzen würde Ihnen ein-by-one, die durch ein Leerzeichen:

XML

<input>alpha-bravo/charlie#delta...echo?foxtrot%golf|hotel india-juliet</input>

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/">
    <output>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="string" select="input"/>
            <xsl:with-param name="delimiters" select="translate(input, '0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ', '')"/>
        </xsl:call-template>
    </output>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="string"/>
    <xsl:param name="delimiters"/>
    <xsl:choose>
        <xsl:when test="$delimiters">
            <xsl:variable name="delimiter" select="substring($delimiters, 1, 1)" /> 
            <xsl:value-of select="substring-before($string, $delimiter)" />
            <xsl:text> </xsl:text>
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="string" select="substring-after($string, $delimiter)"/>
                <xsl:with-param name="delimiters" select="substring($delimiters, 2)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$string"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Ergebnis

<?xml version="1.0" encoding="utf-8"?>
<output>alpha bravo charlie delta   echo foxtrot golf hotel india juliet</output>

ausgezeichnete Antwort. wirklich wünschte, ich könnte die Zeichen richtig anwers

InformationsquelleAutor michael.hor257k

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.