So Erzeugen Sie eine formatierte XML-Datei mit VB 6.0?

Arbeite ich auf Visual Basic 6.0-Projekt, und ich brauche, um zu generieren, eine gut formatierte XML-Datei, deren sieht wie folgt aus:

<Myinfo>
      <FirstName>My First Name</FirstName>
      <LastName>My Last Name</LastName>
      <StreetAdd>My Address</StreetAdd>
<MyInfo>

Hinweis: ich bekam den job zu erledigen die Generierung der XML-Datei, aber ich bin immer noch in der Notwendigkeit für die richtige Formatierung, wie oben gezeigt.

Die XML-Datei generiert ich formatiert ist, wie Sie in einer einzigen Zeile wie diese:

<Myinfo><FirstName>My First Name</FirstName><LastName>My Last Name</LastName><StreetAdd>My Address</StreetAdd><MyInfo> .

Ihre Beispiel-XML-Dateien sind identisch, so weit wie XML betroffen ist.
Was bedeutet die Anzeige, wie ein Baum zu tun haben mit den Leerzeichen in der XML?
möglich, Duplikat der Wie kann ich pretty-print für XML-Quelle mithilfe von VB6 und MSXML?
Nicht ein Duplikat ist. Wo ist jede Erwähnung von MSXML in OP ' s Frage? Die Antworten auf diese Frage relevant sein könnte.

InformationsquelleAutor | 2012-04-18

vb6 xml

Habe ich eine kleine XML-Prettyprinter, die Recht gut funktioniert:

Sub PrettyPrint(Parent As IXMLDOMNode, Optional Level As Integer)
  Dim Node As IXMLDOMNode
  Dim Indent As IXMLDOMText

  If Not Parent.ParentNode Is Nothing And Parent.ChildNodes.Length > 0 Then
    For Each Node In Parent.ChildNodes
      Set Indent = Node.OwnerDocument.createTextNode(vbNewLine & String(Level, vbTab))

      If Node.NodeType = NODE_TEXT Then
        If Trim(Node.Text) = "" Then
          Parent.RemoveChild Node
        End If
      ElseIf Node.PreviousSibling Is Nothing Then
        Parent.InsertBefore Indent, Node
      ElseIf Node.PreviousSibling.NodeType <> NODE_TEXT Then
        Parent.InsertBefore Indent, Node
      End If
    Next Node
  End If

  If Parent.ChildNodes.Length > 0 Then
    For Each Node In Parent.ChildNodes
      If Node.NodeType <> NODE_TEXT Then PrettyPrint Node, Level + 1
    Next Node
  End If
End Sub

Dem aus Sie es aufrufen, indem in der DOMDocument Objekt und verlassen die Level parameter leer.

Sie eine in-place-änderung des Dokuments.
Verlieren Sie alle bedeutungslosen Leerzeichen (Leerzeichen zwischen XML-Elementen), die dort wohl schon.
Es verwendet ein tab Einrücken.
Es auch Einrückungen, Kommentare und processing-instructions usw.
es funktioniert mit allen Versionen von DOMDocument.

Dim XmlDoc as New MSXML2.DOMDocument40

' create/load your xml document

PrettyPrint XmlDoc

MsgBox XmlDoc.xml

Gibt es auch eine einfache Möglichkeit, es zu tun via SAX.

InformationsquelleAutor Tomalak

1

Sollten Sie wirklich sein mit einer XML-Bibliothek zu erstellen, die "richtigen" XML. Es Griffe Kodierung, Datenformate, etc
```
Set XMLDoc = New DOMDocument
Set XMLRoot = XMLDoc.appendChild(XMLDoc.createElement("Myinfo"))
XMLRoot.appendChild(XMLDoc.createElement("FirstName")).Text = "My First Name"
XMLRoot.appendChild(XMLDoc.createElement("LastName")).Text = "My Last Name"
XMLRoot.appendChild(XMLDoc.createElement("StreetAdd")).Text = "My Address"
```
XMLDoc.xml wird dann die Ausgabe gültiges XML ist, oder Sie können ziemlich drucken Sie es als Tomalak schlägt, wenn Sie es wirklich wollen.

Erbsenzählerei: Es wird erzeugen wohlgeformt "XML". Ob es gültig ist oder nicht, ist eine andere Geschichte.

InformationsquelleAutor Deanna

Müssen Sie zählen die Verschachtelung der tags und Einrückung in der Ausgabe entsprechend der Tiefe der Verschachtelung. So etwas wie (verzeihen Sie meine schlechte VB6-syntax):

Int Nesting=0
Bool LastOutputWasText=false

Sub XMLIndent
   Do I=1,Nesting
     Print " ";
   End Do
End Sub

Sub XMLOutputOpenTag(String OpenTag)
    if LastOutputWasText then
      Print
    endif
    XMLIndent
    Nesting=Nesting+1
    Print OpenTag;
    LastOutputWasText=true
End Sub

Sub XMLOutputCloseTag(String CloseTag)
    ! Always call OpenTag and CloseTag with matching Tag names
    if !LastOutputWasText then
       XMLIndent
    endif
    Print CloseTag
    Nesting=Nesting-1
    LastOutputWasText=false
End Sub

Sub XMLOutputText(String Text)
    Print Text;
    LastOutputWasText=true
End Sub

OP Links zu überarbeiten, diese in eine Datei schreiben oder wo er will, das Ergebnis.

InformationsquelleAutor Ira Baxter

Gibt es eine kleine Verbesserung Tomalak code, ich bin das hinzufügen einer vbNewLine nach dem Ende des Tags:

Private Sub FormatOuterXml(ByRef Parent As IXMLDOMNode, Optional ByVal Lvl As Long = 0)

    If Parent.ParentNode Is Nothing Or Parent.ChildNodes.Length = 0 Then Exit Sub

    Dim xn0 As IXMLDOMNode, id0 As IXMLDOMText, id1 As IXMLDOMText
    Set id0 = Parent.OwnerDocument.createTextNode(vbNewLine & String(Lvl, vbTab))

    If Lvl > 0 Then Set id1 = Parent.OwnerDocument.createTextNode(vbNewLine & String(Lvl - 1, vbTab))

    For Each xn0 In Parent.ChildNodes
        If xn0.NodeType = MSXML2.NODE_TEXT Then
            If LenB(xn0.Text) = 0 Then Parent.RemoveChild xn0
        ElseIf xn0.PreviousSibling Is Nothing Then
            Parent.InsertBefore id0.CloneNode(True), xn0
        ElseIf xn0.PreviousSibling.NodeType <> MSXML2.NODE_TEXT Then
            Parent.InsertBefore id0.CloneNode(True), xn0
        ElseIf xn0.NextSibling Is Nothing Then
            If Not id1 Is Nothing Then Parent.appendChild id1.CloneNode(True)
        End If
    Next xn0

    If Parent.ChildNodes.Length > 0 Then
        For Each xn0 In Parent.ChildNodes
            If xn0.NodeType <> MSXML2.NODE_TEXT Then FormatOuterXml xn0, Lvl + 1
       Next xn0
    End If

End Sub

Dies funktioniert nicht, wo ist FormatOuterXml Funktion
hey, es ist eine rekursive Funktion, nicht sicher warum es genannt wurde PrettyPrint2, ich habe mich verändert den Namen der Funktion zu FormatOuterXml

InformationsquelleAutor Zhenya

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.