So zeigen erste Kind nur mit XSL

derzeit bin ich Erhalt dieser

<root>
<event>bla</event>
</root>

Was ich will, ist nur dieses

<event>bla</event>

Mein xsl sieht so aus

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" />
<xsl:param name="Number" />
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
</xsl:template>
<xsl:template match="/root/event" />
<xsl:template match="/root/event[1]">
<xsl:copy-of select="current()" />
</xsl:template>
</xsl:stylesheet>

Ich kann nicht herausfinden, wie Zugriff auf den ersten Knoten ohne über - /root-ersten.
Pls help

InformationsquelleAutor almightyBob | 2011-12-20
  1. 3

    Diese XSLT-sollte Ihre Frage beantworten. Es gebe event Elemente, das erste Kind Ihrer Eltern-Knoten :

    <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  version="1.0">
    <xsl:template match="*">
        <xsl:apply-templates/>
    </xsl:template>
    <xsl:template match="event[1]">
        <xsl:copy-of select="."/>
    </xsl:template>
    <xsl:template match="text()"/>
</xsl:stylesheet>

    Den root element wird übersprungen, indem die match="*" Vorlage.

    Einen anderen Weg, dies zu tun (mehr einfache, aber weniger evolutive) :

    <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  version="1.0">
    <xsl:template match="/">
        <xsl:copy-of select="root/event[1]"/>
    </xsl:template>
</xsl:stylesheet>
    • Vielen Dank, die mir geholfen haben
    InformationsquelleAutor Vincent Biragnet
  2. 0

    , Weil Sie die Identität in der Regel ist es gut zu wissen, wie um es zu überschreiben, um zu erreichen maximale Flexibilität:

    .1. Überschreiben, schließt ein element, aber immer noch verarbeitet alle Knoten in seinem Unterbaum:

    <xsl:template match="root">
  <xsl:apply-templates/>
</xsl:template>

    .2. Überschreiben Sie für ein element, das schließt Sie und alle Knoten von seinem sub-Baum:

     <xsl:template match="event[position() > 1]"/>

    Diese beiden kombiniert, geben Sie uns die kompletten wollten transformation:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="root">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="event[position() > 1]"/>
</xsl:stylesheet>

    wenn diese transformation angewendet wird, auf das folgende XML-Dokument:

    <root>
    <event>bla1</event>
    <event>bla2</event>
</root>

    die wollten, das richtige Ergebnis produziert wird:

    <event>bla1</event>
    InformationsquelleAutor Dimitre Novatchev
Schreibe einen Kommentar