Speichern von XML-Datei in eine AS3 möglich ist

Warf ich diese zusammen, und sicher genug, den Sie speichern können .XML mit die folgenden als ein minimalistisches Beispiel.

package com.hodgedev.xmlcreator
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.utils.ByteArray;
    import flash.net.FileReference;

/**
 * ...
 * @author Brian Hodge ([email protected])
 */
public class Main extends Sprite 
{
    private var _xml:XML;

    public function Main():void 
    {
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }

    private function init(e:Event = null):void 
    {
        removeEventListener(Event.ADDED_TO_STAGE, init);

        //Calling the save method requires user interaction and Flash Player 10
        stage.addEventListener(MouseEvent.MOUSE_DOWN, _onMouseDown);

        _xml= <xml>
              <test>data</test>
              </xml>;
    }
    private function _onMouseDown(e:MouseEvent):void
    {
        var ba:ByteArray = new ByteArray();
        ba.writeUTFBytes(_xml);
        //ba.

        var fr:FileReference = new FileReference();
        fr.addEventListener(Event.SELECT, _onRefSelect);
        fr.addEventListener(Event.CANCEL, _onRefCancel);

        fr.save(ba, "filename.xml");
    }
    private function _onRefSelect(e:Event):void
    {
        trace('select');
    }
    private function _onRefCancel(e:Event):void
    {
        trace('cancel');
    }
}

}

Gibt es einige Dinge zu beachten.

• Sie benötigen Flash Player 10 verwenden der save-Methode des FileReference Klasse.
• Um etwas zu tun, wird eine Eingabeaufforderung Flash-Interaktion mit dem Benutzer erforderlich, wie Tastatur-oder Maus-Eingaben.

In der oben höre ich für MouseEvent.MOUSE_DOWN auf der Bühne zu dienen, wie die INTERAKTION mit dem BENUTZER erforderlich ist, rufen die Eingabeaufforderung speichern.

Richte ich eine Basis-XML-Struktur in den code ein (dieser wird in der Regel aus externen Quelle und wird gut funktionieren in beide Richtungen.

Einen ByteArray erstellt und die XML-Datei geschrieben, um die ByteArray.

Die save-Methode des FileReference - Klasse erfordert ein ByteArray - und Standard-speichern unter-name übergeben werden, wie die beiden Parameter.

Ich hoffe, das hilft.

Tut mir Leid, Ihre Frage ist nicht ganz klar.

Werden Sie gefragt, ob Sie eine Datei speichern können, um die Festplatte in einem kompilieren der SWF in AS3 geschrieben?

Oder Fragen Sie, wenn Sie können eine raw XML-Datei in deinem AS3-Projekt, ohne zu schreiben Sie es aus, wie eine variable?

Wenn du meintest das ehemalige, nicht -- nicht ohne Adobe AIR. Sie können Daten lokal speichern, als ein SharedObject, aber nicht als eine beliebige Datei in der Datei system.

Wenn letzteres, dann ja, müssen Sie die Datei einbetten genauso, als würden Sie einbetten einer anderen Ressource (z.B. ein Bild oder ein Ton). Aber es sieht aus wie könnte es ein bug in Flash, der macht dies nicht ganz einfach, herauszufinden, wie zu tun ist.

Dieser link könnte für Sie hilfreich sein.

[Embed(source='../../../../assets/levels/test.xml', mimeType="application/octet-stream")]
public static const Level_Test:Class;

Und dann zum Parsen der XML:

var ba:ByteArray = (new Levels.Level_Test()) as ByteArray;
var s:String = ba.readUTFBytes( ba.length );
xml = new XML( s );

Entschuldigt, wenn weder diese Fragen werden, was Sie eigentlich gefragt haben.

Prost!