Spielt einen Ton mit VBA, wenn ein Fehler gefunden wird

Brauchen Sie nicht-API für diese

Können Sie Beep als gut.

Sub Sample()
    Beep
End Sub

Beispiel

WEG 1

Dieser code wird ausgeführt, wenn es änderung an beliebiger Stelle im Blatt

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell            As Range
    Dim CheckRange      As Range

    Set CheckRange = Range("C:C")

    For Each Cell In CheckRange
        If Cell.Text = "#N/A" Then
            Beep
            Exit For
        End If
    Next
End Sub

WEG 2

Alternative der obige code

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell As Range

    For Each Cell In Columns(3)
        On Error Resume Next
        If CVErr(Cell) = CVErr(2042) Then
            Beep
            Exit For
        End If
        On Error GoTo 0
    Next
End Sub

Weg 3

Wenn Sie möchten, um zu überprüfen, Col C, nur wenn es eine manuelle änderung überall in Col C

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell As Range

    If Not Intersect(Target, Columns(3)) Is Nothing Then
        For Each Cell In Columns(3)
            On Error Resume Next
            If CVErr(Cell) = CVErr(2042) Then
                Beep
                Exit For
            End If
            On Error GoTo 0
        Next
    End If
End Sub

Weg 4

Wenn Sie möchten, um zu überprüfen in einer Zelle ob es eine manuelle änderung in dieser Zelle

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell As Range

    If Not Intersect(Target, Columns(3)) Is Nothing Then
        On Error Resume Next
        If CVErr(Target) = CVErr(2042) Then
            Beep
            Exit Sub
        End If
        On Error GoTo 0
    End If
End Sub

Weg 5

Variation von Art 4

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell As Range

    If Not Intersect(Target, Columns(3)) Is Nothing Then
        If Target.Text = "#N/A" Then
            Beep
            Exit Sub
        End If
    End If
End Sub

FOLLOWUP (Kommentare)

Die aktive Zelle in Spalte b, so sollte geprüft werden, ob man rechts in der Spalte d – Sam Cousins 1 min vor

Ich denke, du meintest Col C und nicht Col D. verwenden Sie Worksheet_SelectionChange für diese

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Intersect(Target, Columns(2)) Is Nothing Then
        If Target.Offset(, 1).Text = "#N/A" Then
            Beep
        End If
    End If
End Sub

Ändern Zelle.Wert in Zelle.Text

Wenn es eine Formel, die Fehler der Zellen-Wert wird etwas entlang der Linien der Fehler 2042 aber deine if-Anweisung ist auf der Suche nach dem text "#N/A"

Ich auch vorschlagen, nur den Bereich, der statt der gesamten Spalte, da dies die Zeit verringern, die es braucht, um laufen.

Können Sie auch die Ausfahrt für sofort, wenn ein Fehler gefunden wird.

Beep wird Ihnen nicht erlauben, zu spielen, jeder Ton, aber es wird ein hörbares Geräusch und erfordert nicht einen API-Aufruf oder der computer für die angegebene audio-Datei.

- - EDIT - -
Ich habe gerade getestet ... der code unten, und es scheint, um korrekt zu funktionieren für mich.

-EDIT2-
Korrigierte code

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell As Range
    Dim CheckRange As Range

    Set CheckRange = Range(Cells(1, 3), Cells(ActiveSheet.UsedRange.Rows.Count, 3))
    For Each Cell In CheckRange
        If Cell.Text = "#N/A" Then
            Beep
            Exit For
        End If
    Next
End Sub

-EDIT3-
Arbeiten, Kopie Ihrer original-Beitrag

Option Explicit

Private Declare Function sndPlaySound32 Lib "winmm.dll" _
                                        Alias "sndPlaySoundA" (ByVal lpszSoundName _
                                                               As String, ByVal uFlags As Long) As Long

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim Cell As Range
    Dim CheckRange As Range
    Dim PlaySound As Boolean

    Set CheckRange = Range(Cells(1, 3), Cells(ActiveSheet.UsedRange.Rows.Count, 3))
    For Each Cell In CheckRange
        If Cell.Text = "#N/A" Then
            PlaySound = True
            Exit For
        End If
    Next
    If PlaySound Then
        Call sndPlaySound32("C:\windows\media\chord.wav", 1)
    End If
End Sub

Ich denke, deine If-Anweisung, die prüft den Wert des PlaySound sollte in Ihrem For-Schleife. Die Art und Weise haben Sie es geschrieben, es wird nur ein Geräusch machen, wenn die Letzte Zelle in CheckRange = "#N/A", weil PlaySound halten den letzten Wert zugewiesen, um es aus der Schleife.