Starten Sie den Internet Explorer 7 in einem neuen Prozess, ohne Symbolleisten

Muss ich laufen, eine web-Anwendung im IE, so dass es zumindest so ähnlich aussieht wie ein stand-alone-Anwendung. Ich muss auch in der Lage sein, mehrere Instanzen von dieser web-Anwendung zur gleichen Zeit in separaten Sitzungen.

Zur Erreichung dieses Aussehen, ich würde wie immer starten Sie den Internet Explorer 7 in einem neuen Prozess, ohne Symbolleisten/Statusleiste über eine Verknüpfung auf dem desktop.

Habe ich versucht, ein paar Dinge. So weit der Schrank, das ich es schaffen eine Verknüpfung der folgenden vb-script,

Set objExplorer = CreateObject("InternetExplorer.Application")
objExplorer.Navigate "http://stackoverflow.com"
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Width = 1024
objExplorer.Height = 768
objExplorer.Left = 0
objExplorer.Top = 0
objExplorer.Visible = 1

Sieht genauso aus, wie ich es mir vorstelle. Allerdings, wenn Sie auf die Verknüpfung doppelklicken, es wieder tut sich ein neues Fenster öffnen sondern im gleichen Prozess (d.h. es gibt nur eine iexplore.exe Prozess im Windows Task-Manager). Da die beiden-Instanz werden innerhalb des gleichen Prozesses sind Sie teilen die gleiche session. Also, wenn Sie angemeldet sind, zu einer Instanz der Anwendung angemeldet sind, zu der anderen Instanz der Anwendung, ist das nicht gut für mich.

Ich habe auch versucht,

"Program Files\Internet Explorer\iexplore.exe" http://stackoverflow.com

welches immer startet einen neuen Prozess, aber Sie können nicht entfernen Sie nur die Symbolleisten/Statusleiste. Kiosk-Modus ("- k" - parameter) ist nicht gut für mich, wie ich es brauchen, um in einem Fenster angezeigt.

Kann mir jemand sagen, wie man immer starten Sie den Internet Explorer 7 in einem neuen Prozess, ohne Symbolleisten/Statusleiste über eine Verknüpfung auf dem desktop?

Ich bin offen für jede Art von Technologie für die Lösung.

Dank,
Everett

InformationsquelleAutor Everett Toews | 2009-06-16

internet-explorer vbscript

Können Sie eine HTML-Anwendung wie:

<html>
<head>
<title>Stack Overflow</title>
<hta:application showintaskbar="yes" singleinstance="no" sysmenu="yes" scroll="no"
icon="http://www.stackoverflow.com/favicon.ico">
<style type="text/css">
* { margin: 0px; padding: 0px; }
iframe { position: absolute; top: 0px; left: 0px; width: 100%; height: 100%; }
</style>
</head>
<body>
<IFRAME SRC="http://www.stackoverflow.com/" APPLICATION="no">
</body>
</html>

Jedoch ist es eher mess up die JS von welcher Seite ist es ohne Besondere Vorkehrungen für HTA.

Danke für die Anregung, aber wenn ich dies versuchte, hatte ich Probleme mit dem JavaScript auf meiner Seite (von denen die meisten kann ich nicht einmal touch).

InformationsquelleAutor MiffTheFox

1

Können Sie dies tun, indem Sie manipulieren die IE-COM-server. Es ist einfach in der powershell:
```
$ie = new-object -COM InternetExplorer.Application
$ie.ToolBar = $false
$ie.StatusBar = $false
$ie.Navigate2( "http://www.stackoverflow.com" )
$ie.Visible = $true
```
Wenn das war in der ie-app.ps1, dann die Verknüpfung hätte "powershell -Befehl mit der ie-app.ps1", um es aufzurufen.

Dies ist im wesentlichen die gleiche Sache, die Sie nicht mit Windows-Scripting-Host in vbscript. Sie können alles, was, die manipulieren können, die den InternetExplorer.Anwendung das COM-Objekt. Ich habe IE8 und es kann nur der Unterschied zwischen IE7 amd IE8 aber mit meinem powershell-Beispiel erhalte ich beiden Prozesse.

Danke für die Anregung, aber wenn ich versuche diese mit Windows XP und IE7 habe ich nur noch 1 Prozess.
Jubel für diesen arbeitete ein Leckerbissen.

InformationsquelleAutor Brian Reiter
1

Du nicht angeben, welche Codierung regime, das Sie verwenden möchten, um dies zu erreichen, aber Sie werden zweifellos möchten, schauen Sie in die WebBrowser-Klasse.

Ich wollte nicht angeben, ob die Technologie denn ich bin offen für jede Lösung (bearbeitet nach).

InformationsquelleAutor Ishmael

Keiner der anderen Antworten geklappt hat, also hier ist ein vb-script, das ich zusammen gebastelt aus verschiedenen Quellen (ich bin kein vb-scripter).

On Error Resume Next

AppURL = "http://www.stackoverflow.com"
AppToRun = "iexplore about:blank"
AboutBlankTitle = "Blank Page"
LoadingMessage = "Loading stackoverflow..."
ErrorMessage = "An error occurred while loading stackoverflow.  Please close the Internet Explorer with Blank Page and try again.  If the problem continues please contact IT."
EmptyTitle = ""

'Launch Internet Explorer in a separate process as a minimized window so we don't see the toolbars disappearing
dim WshShell
set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run AppToRun, 6

dim objShell
dim objShellWindows

set objShell = CreateObject("Shell.Application")
set objShellWindows = objShell.Windows

dim ieStarted
ieStarted = false

dim ieError
ieError = false

dim seconds
seconds = 0

while (not ieStarted) and (not ieError) and (seconds < 30)

    if (not objShellWindows is nothing) then
        dim objIE
        dim IE

        'For each IE object
        for each objIE in objShellWindows

            if (not objIE is nothing) then

                if isObject(objIE.Document) then
                    set IE = objIE.Document

                    'For each IE object that isn't an activex control
                    if VarType(IE) = 8 then

                        if IE.title = EmptyTitle then
                            if Err.Number = 0 then
                                IE.Write LoadingMessage

                                objIE.ToolBar = 0
                                objIE.StatusBar = 1
                                objIE.Navigate2 AppURL

                                ieStarted = true
                            else
                                'To see the full error comment out On Error Resume Next on line 1
                                MsgBox ErrorMessage
                                Err.Clear

                                ieError = true

                                Exit For
                            end if
                        end if
                    end if
                end if
            end if

            set IE = nothing
            set objIE = nothing
        Next
    end if

    WScript.sleep 1000
    seconds = seconds + 1
wend

set objShellWindows = nothing
set objShell = nothing

'Activate the IE window and restore it
success = WshShell.AppActivate(AboutBlankTitle)

if success then 
    WshShell.sendkeys "% r"  'restore 
end if

Ich bin offen für alle Verbesserungen oder Anregungen.

InformationsquelleAutor Everett Toews

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.