Überprüfen, ob ein string enthält nur ein Wort, doch nur in bestimmter position?

Ich mag Sertac Idee zum löschen von strings in Klammern eingeschlossen und auf der Suche nach einer Zeichenfolge danach. Hier ist ein code-Beispiel erweitert, indem eine Suche auf ganze Wörter und die groß-und Kleinschreibung:

function ContainsWord(const AText, AWord: string; AWholeWord: Boolean = True;
  ACaseSensitive: Boolean = False): Boolean;
var
  S: string;
  BracketEnd: Integer;
  BracketStart: Integer;
  SearchOptions: TStringSearchOptions;
begin
  S := AText;
  BracketEnd := Pos(']', S);
  BracketStart := Pos('[', S);
  while (BracketStart > 0) and (BracketEnd > 0) do
  begin
    Delete(S, BracketStart, BracketEnd - BracketStart + 1);
    BracketEnd := Pos(']', S);
    BracketStart := Pos('[', S);
  end;
  SearchOptions := [soDown];
  if AWholeWord then
    Include(SearchOptions, soWholeWord);
  if ACaseSensitive then
    Include(SearchOptions, soMatchCase);
  Result := Assigned(SearchBuf(PChar(S), StrLen(PChar(S)), 0, 0, AWord,
    SearchOptions));
end;

Hier ist eine optimierte version der Funktion, die verwendet Zeiger char iteration ohne string-manipulation. Im Vergleich zu einer früheren version dieses behandelt den Fall, wenn Sie eine Zeichenfolge, die mit einer fehlenden schließenden Klammer, wie zum Beispiel My [favorite color is. Eine solche Zeichenfolge ist es Wahr ausgewertet, da der fehlende Klammer.

Das Prinzip ist, gehen Sie durch den ganzen string char durch char und wenn, finden Sie die öffnende Klammer, schau mal ob die Halterung hat einen schließen-pair-Mädchen für sich. Wenn ja, dann überprüfen Sie, ob der substring von der gespeicherten position, bis die öffnende Klammer enthält das gesuchte Wort. Wenn ja, beenden Sie die Funktion. Wenn nicht, verschieben Sie die gespeicherte position auf die schließende Klammer. Wenn die öffnende Klammer nicht über einen eigenen schließen-pair-Mädchen, suchen Sie nach dem Wort aus der gespeicherten position bis zum Ende der gesamten Zeichenfolge und die Funktion beenden.

Für die kommentierte version dieses code Folgen Sie diesem link.

function ContainsWord(const AText, AWord: string; AWholeWord: Boolean = True;
  ACaseSensitive: Boolean = False): Boolean;
var
  CurrChr: PChar;
  TokenChr: PChar;
  TokenLen: Integer;
  SubstrChr: PChar;
  SubstrLen: Integer;
  SearchOptions: TStringSearchOptions;
begin
  Result := False;
  if (Length(AText) = 0) or (Length(AWord) = 0) then
    Exit;
  SearchOptions := [soDown];
  if AWholeWord then
    Include(SearchOptions, soWholeWord);
  if ACaseSensitive then
    Include(SearchOptions, soMatchCase);
  CurrChr := PChar(AText);
  SubstrChr := CurrChr;
  SubstrLen := 0;
  while CurrChr^ <> #0 do
  begin
    if CurrChr^ = '[' then
    begin
      TokenChr := CurrChr;
      TokenLen := 0;
      while (TokenChr^ <> #0) and (TokenChr^ <> ']') do
      begin
        Inc(TokenChr);
        Inc(TokenLen);
      end;
      if TokenChr^ = #0 then
        SubstrLen := SubstrLen + TokenLen;
      Result := Assigned(SearchBuf(SubstrChr, SubstrLen, 0, 0, AWord,
        SearchOptions));
      if Result or (TokenChr^ = #0) then
        Exit;
      CurrChr := TokenChr;
      SubstrChr := CurrChr;
      SubstrLen := 0;
    end
    else
    begin
      Inc(CurrChr);
      Inc(SubstrLen);
    end;
  end;
  Result := Assigned(SearchBuf(SubstrChr, SubstrLen, 0, 0, AWord,
    SearchOptions));
end;

InformationsquelleAutor TLama

Denke ich, kann man formulieren Sie Ihr problem als "finde eine Eintritt des mitgelieferten string nicht umgeben von eckigen Klammern." Wenn dieser beschreibt Ihr Problem, dann können Sie voran gehen und verwenden Sie einen einfachen regulären Ausdruck wie [^\[]favorite[^\]].

InformationsquelleAutor Leonardo Herrera