Unterschiedliche Elemente und gruppieren

Gegeben, das folgende xml-fragment:

<Problems>
  <Problem>
    <File>file1</File>
    <Description>desc1</Description>
  </Problem>
  <Problem>
    <File>file1</File>
    <Description>desc2</Description>
  </Problem>
  <Problem>
    <File>file2</File>
    <Description>desc1</Description>
  </Problem>
</Problems>

Ich brauche, um etwas zu produzieren, wie

<html>
  <body>
    <h1>file1</h1>
    <p>des1</p>
    <p>desc2</p>
    <h1>file2</h1>
    <p>des1</p>
  </body>
</html>

Versuchte ich mit einem Schlüssel, wie

<xsl:key name="files" match="Problem" use="File"/>

aber ich weiß nicht wirklich verstehen, wie man es an den nächsten Schritt, oder wenn dann ist das auch der richtige Ansatz.

InformationsquelleAutor rjohnston | 2008-12-30

5

Hier ist, wie ich es tun würde, mit dem Muenchean Methode. Google 'xslt muenchean' für mehr info von INTELLIGENTEREN Menschen. Es könnte ein cleverer Weg, aber ich werde verlassen, dass andere.

Einen Hinweis, ich vermeiden Sie Versalien am Anfang der xml-element-Namen, z.B. 'Datei', aber das ist bis zu Ihnen.
```
<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html"/>
    <xsl:key name="files" match="/Problems/Problem/File" use="./text()"/>
    <xsl:template match="/">
        <html>
            <body>
                <xsl:apply-templates select="Problems"/>
            </body>
        </html>
    </xsl:template>
    <xsl:template match="Problems">
        <xsl:for-each select="Problem/File[generate-id(.) = generate-id(key('files', .))]">
            <xsl:sort select="."/>
            <h1>
                <xsl:value-of select="."/>
            </h1>
            <xsl:apply-templates select="../../Problem[File=current()/text()]"/>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="Problem">
        <p>
            <xsl:value-of select="Description/text()"/>
        </p>
    </xsl:template>
</xsl:stylesheet>
```
Die Idee ist, Taste jede Datei, element mit text-Wert. Dann nur die Datei anzuzeigen Werte, wenn Sie das gleiche element wie die Form-man. Um zu überprüfen, ob Sie identisch sind, verwenden Sie generate-id. Es ist ein ähnlicher Ansatz, bei dem Sie vergleichen das erste element entspricht. Ich kann Ihnen nicht sagen, welches die effizientere ist.

Getestet hab ich den code hier mit Marrowsoft Xselerator, meine Lieblings-xslt-tool, obwohl es nicht mehr verfügbar, soweit ich weiß. Das Ergebnis bekam ich ist:
```
<html>
<body>
<h1>file1</h1>
<p>desc1</p>
<p>desc2</p>
<h1>file2</h1>
<p>desc1</p>
</body>
</html>
```
Dies ist mit msxml4.

Habe ich sortiert die Ausgabe nach der Datei. Ich bin mir nicht sicher, ob Sie wollte, dass.

Ich hoffe, das hilft.
- Perfekt, vielen Dank! Und cheers für die muenchean Tipp...
- Cheers. Ich habe gar nicht gemerkt, dass Sie fellow Aussie, sonst hätte ich noch viele weitere Redensarten. 🙂
- Ich habe ein wenig sauberer und wahrscheinlich auch etwas effizientere Lösung als Richards.
InformationsquelleAutor Richard A

Diese Lösung ist etwas einfacher, effizienter und gleichzeitig mehr Allgemeine als der eine vorgestellt, die von Richard:

Diese transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!--                                            -->
 <xsl:key name="kFileByVal" match="File"
       use="." />
<!--                                            -->
 <xsl:key name="kDescByFile" match="Description"
       use="../File"/>
<!--                                            -->
    <xsl:template match="/*">
     <html>
      <body>
      <xsl:for-each select=
         "*/File[generate-id()
                =
                 generate-id(key('kFileByVal',.)[1])]">
        <h1><xsl:value-of select="."/></h1>
        <xsl:for-each select="key('kDescByFile', .)">
          <p><xsl:value-of select="."/></p>
        </xsl:for-each>
      </xsl:for-each>
      </body>
     </html>
    </xsl:template>
</xsl:stylesheet>

, wenn angewandt, um die bereitgestellten XML-Dokument:

<Problems>
    <Problem>
        <File>file1</File>
        <Description>desc1</Description>
    </Problem>
    <Problem>
        <File>file1</File>
        <Description>desc2</Description>
    </Problem>
    <Problem>
        <File>file2</File>
        <Description>desc1</Description>
    </Problem>
</Problems>

Produziert das erwartete Ergebnis:

<html>
   <body>
      <h1>file1</h1>
      <p>desc1</p>
      <p>desc2</p>
      <h1>file2</h1>
      <p>desc1</p>
   </body>
</html>

Tun, beachten Sie die simple-match Muster des ersten <xsl:key> und wie, mit Hilfe eines zweiten <xsl:key> wir suchen Sie alle " Description "- Elemente sind Geschwister von einem " File " - element mit einem vorgegebenen Wert.

Wir hätte mehr Vorlagen statt <xsl:for-each - > pull-Verarbeitung, aber das ist eine ganz einfache Fall und die Lösung, die wirklich profitiert von kürzeren, kompakteren und lesbareren code.

Beachten Sie auch, dass in XSLT 2.0 wird man in der Regel das <xsl:for-each-group> Unterricht statt der Muenchian Methode.

Ich habe immer nur die verwendeten Schlüssel für Muenchean Gruppierung. Vielen Dank für ein Beispiel der Verwendung von Ihnen in einer ausgedehnteren Weise. Außerdem habe ich noch nicht angeschaut XSLT 2.0, also das für-jeden-Gruppe ist auch interessant. Cheers und ein Glückliches Neues Jahr.
Frohes Neues Jahr für dich, Richard.

InformationsquelleAutor Dimitre Novatchev

Diese XSLT 1.0 Lösung wird auch den trick tun. Etwas kürzer als die anderen Lösungen!

  <xsl:template match="/">           
    <html><body>
      <xsl:for-each select="//File[not(.=preceding::*)]">
        <h1><xsl:value-of select="." /></h1>
        <xsl:for-each select="//Problem[File=current()]/Description">
          <p><xsl:value-of select="." /></p>
        </xsl:for-each>
      </xsl:for-each>
    </body></html>
  </xsl:template>

Ergebnis:

<html xmlns="http://www.w3.org/1999/xhtml">
  <body>
    <h1>file1</h1>
    <p>desc1</p>
    <p>desc2</p>
    <h1>file2</h1>
    <p>desc1</p>
  </body>
</html>

InformationsquelleAutor Nick Grealy

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.