URL-codieren in Erlang

Ich bin mit erlang http:request zu post einige Daten auf einen remote-service. Ich habe die post arbeiten, aber die Daten, die in dem Körper() der Beitrag kommt durch, wie es ist, ohne url-Codierung, die bewirkt, dass der post zu Versagen, wenn analysiert, die remote-service.

Gibt es eine Funktion in Erlang, ist ähnlich zu CGI.Flucht in Ruby für diesen Zweck?

InformationsquelleAutor der Frage davidsmalley | 2008-09-22

  1. 8

    Können Sie finden hier die YAWS urlencode und urldecode Routinen

    Sind Sie ziemlich einfach, obwohl die Kommentare zeigen das codieren ist nicht 100% vollständig für alle Satzzeichen.

    InformationsquelleAutor der Antwort Bwooce

  2. 24

    Traf ich das fehlen dieser Funktion in der HTTP-Module.

    Es stellt sich heraus, dass diese Funktionalität eigentlich in der erlang-Verteilung, man muss nur lange genug sucht.

    > edoc_lib:escape_uri("[email protected]").
"luca%2bmore%40here.com"

    Verhält sich diese wie CGI.Flucht in Ruby, es gibt auch URI.entkommen, das verhält sich etwas anders:

    > CGI.escape("[email protected]")
 => "luca%2Bmore%40here.com" 
> URI.escape("[email protected]")
 => "[email protected]"

    edoc_lib

    InformationsquelleAutor der Antwort

  3. 8

    Zumindest R15 gibt es http_uri:Kodieren/1die nicht den job. Ich würde auch nicht empfehlen die Verwendung von edoc_lib:escape_uri als seine übersetzung von einem '=' zu einer %3d anstatt ein "%3D", die verursacht mir einige Probleme.

    InformationsquelleAutor der Antwort John-Paul Bader

  4. 5

    Hier ist eine einfache Funktion, die nicht den job. Es ist entworfen, um zu arbeiten direkt mit den inets httpc.

    %% @doc A function to URL encode form data.
%% @spec url_encode(formdata()).

-spec(url_encode(formdata()) -> string()).
url_encode(Data) ->
    url_encode(Data,"").

url_encode([],Acc) ->
    Acc;

url_encode([{Key,Value}|R],"") ->
    url_encode(R, edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value));
url_encode([{Key,Value}|R],Acc) ->
    url_encode(R, Acc ++ "&" ++ edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value)).

    Beispiel: 

    httpc:request(post, {"http://localhost:3000/foo", [], 
                    "application/x-www-form-urlencoded",
                    url_encode([{"username", "bob"}, {"password", "123456"}])}
             ,[],[]).

    InformationsquelleAutor der Antwort Rick Moynihan

  5. 4

    Beantwortung meiner eigenen Frage...ich fand diese lib in ibrowse!

    http://www.erlware.org/lib/5.6.3/ibrowse-1.4/ibrowse_lib.html#url_encode-1

    url_encode/1

url_encode(Str) -> UrlEncodedStr

Str = string()
UrlEncodedStr = string()

    URL-kodiert einen string basierend auf RFC 1738. Gibt eine flache Liste.

    Ich denke, ich kann die Codierung und trotzdem http:

    InformationsquelleAutor der Antwort davidsmalley

  6. 2

    Wenn jemand braucht, encode-uri, arbeitet mit utf-8 in erlang:

    https://gist.github.com/3796470

    Ex.

    Eshell V5.9.1  (abort with ^G)

1> c(encode_uri_rfc3986).
{ok,encode_uri_rfc3986}

2> encode_uri_rfc3986:encode("テスト").
"%e3%83%86%e3%82%b9%e3%83%88"

3> edoc_lib:escape_uri("テスト").
"%c3%86%c2%b9%c3%88" # output wrong: ƹÈ

    InformationsquelleAutor der Antwort Renato Albano

  7. 1

    Hier ist ein "fork" der edoc_lib:escape_uri-Funktion, verbessert die Unterstützung für UTF-8 und unterstützt auch die binaries. 

    escape_uri(S) when is_list(S) ->
    escape_uri(unicode:characters_to_binary(S));
escape_uri(<<C:8, Cs/binary>>) when C >= $a, C =< $z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $A, C =< $Z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $0, C =< $9 ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $. ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $- ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $_ ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) ->
    escape_byte(C) ++ escape_uri(Cs);
escape_uri(<<>>) ->
    "".

escape_byte(C) ->
    "%" ++ hex_octet(C).

hex_octet(N) when N =< 9 ->
    [$0 + N];
hex_octet(N) when N > 15 ->
    hex_octet(N bsr 4) ++ hex_octet(N band 15);
hex_octet(N) ->
    [N - 10 + $a].

    Beachten Sie, dass, wegen der Verwendung von unicode:characters_to_binary es werden nur arbeiten in R13 oder neuer.

    InformationsquelleAutor der Antwort gdamjan

  8. 0

    AFAIK gibt es keine URL-encoder im standard-Bibliotheken. Denke, dass ich 'ausgeliehen' der folgende code von YAWS, oder vielleicht einer der anderen Erlang-web-Server:

    % Utility function to convert a 'form' of name-value pairs into a URL encoded
% content string.

urlencode(Form) ->
    RevPairs = lists:foldl(fun({K,V},Acc) -> [[quote_plus(K),$=,quote_plus(V)] | Acc] end, [],Form),
    lists:flatten(revjoin(RevPairs,$&,[])).

quote_plus(Atom) when is_atom(Atom) ->
    quote_plus(atom_to_list(Atom));

quote_plus(Int) when is_integer(Int) ->
    quote_plus(integer_to_list(Int));

quote_plus(String) ->
    quote_plus(String, []).

quote_plus([], Acc) ->
    lists:reverse(Acc);

quote_plus([C | Rest], Acc) when ?QS_SAFE(C) ->
    quote_plus(Rest, [C | Acc]);

quote_plus([$\s | Rest], Acc) ->
    quote_plus(Rest, [$+ | Acc]);

quote_plus([C | Rest], Acc) ->
    <<Hi:4, Lo:4>> = <<C>>,
    quote_plus(Rest, [hexdigit(Lo), hexdigit(Hi), ?PERCENT | Acc]).

revjoin([], _Separator, Acc) ->
    Acc;

revjoin([S | Rest],Separator,[]) ->
    revjoin(Rest,Separator,[S]);

revjoin([S | Rest],Separator,Acc) ->
    revjoin(Rest,Separator,[S,Separator | Acc]).

hexdigit(C) when C < 10 -> $0 + C;
hexdigit(C) when C < 16 -> $A + (C - 10).

    InformationsquelleAutor der Antwort tonys

Schreibe einen Kommentar