VB.Net Zusammenführen mehrerer PDF-Dateien zu einer und export

Habe ich das Zusammenführen mehrerer PDF-Dateien in einer einzigen PDF-Datei.

Ich bin mit dem iText.scharfe Bibliothek und sammeln Sie konvertiert den code und versucht, es zu benutzen (aus hier)
Der eigentliche code ist in C# und ich konvertiert, die zu VB.NET.

 Private Function MergeFiles(ByVal sourceFiles As List(Of Byte())) As Byte()
    Dim mergedPdf As Byte() = Nothing
    Using ms As New MemoryStream()
        Using document As New Document()
            Using copy As New PdfCopy(document, ms)
                document.Open()
                For i As Integer = 0 To sourceFiles.Count - 1
                    Dim reader As New PdfReader(sourceFiles(i))
                    ' loop over the pages in that document
                    Dim n As Integer = reader.NumberOfPages
                    Dim page As Integer = 0
                    While page < n
                        page = page + 1
                        copy.AddPage(copy.GetImportedPage(reader, page))
                    End While
                Next
            End Using
        End Using
        mergedPdf = ms.ToArray()
    End Using
End Function

Ich jetzt immer die folgende Fehlermeldung:

"Ein Element mit demselben Schlüssel wurde bereits Hinzugefügt.

Ich habe einige debugging und verfolgte das problem auf die folgenden Zeilen:

copy.AddPage(copy.GetImportedPage(reader,
copy.AddPage(copy.GetImportedPage(reader, page)))

Warum ist dieser Fehler passiert?

  • eine down-vote ohne Kommentar
  • Viele Stunden": für die Suche nach Lösung für den Fehler
  • haben Sie setzen Sie Haltepunkte im code..? und trat durch den code..?
  • gehen Sie zu dieser Verknüpfung, und konvertieren Sie den C# - code aus dem link, dass Bob gebucht VB converter.telerik.com
  • Ah ja, siehe meine Antwort und mir sagen, ob das funktioniert für Sie.
  • Möglich, Duplikat der Ein Element mit dem gleichen Schlüssel wurde bereits Hinzugefügt dictionary.
  • 🙂 , ich bin nicht einverstanden
  • Ihre Frage ist eine doppelte, und soweit wir sagen können, Sie habe nicht versucht, Debuggen Sie es für mehr als fünf Minuten. Denken Sie daran, dass das Ziel der Stack-Überlauf ist ein repository für die Programmierung Fragen & Antworten; Ihre Frage nicht helfen, und dies bedeutet, dass es sein sollte duplizieren-ausgeschildert.
  • dies ist Ihrer Annahme, gehen Sie auf den hyperlink, wo der ursprüngliche Autor der Antwort bat mich, die post als separate Frage, es ist nur mir, wer weiß wie viel Zeit ich verschwendet haben, in das Debuggen und die überwindung der Fehler. Nach Ihnen, Sie sind "VB.NET braniac", und ich werde immer ein begeisterter Lerner. Vielen Dank, dass Sie Ihre wertvolle Zeit bei der Lösung meiner Abfrage.
  • Lassen Sie uns weiter, diese Diskussion im chat.

InformationsquelleAutor Vikky | 2015-10-09
  1. 2

    Habe ich eine Konsole, die überwacht einzelne Ordner in einem bestimmten Ordner muss dann alle Zusammenführen von pdf-Dateien in diesem Ordner in einer einzigen pdf-Datei. Ich übergeben Sie ein array von Dateipfaden als strings und die Ausgabe-Datei, die ich möchte.

    Dies ist die Funktion die ich verwende. 

    Public Shared Function MergePdfFiles(ByVal pdfFiles() As String, ByVal outputPath As String) As Boolean
    Dim result As Boolean = False
    Dim pdfCount As Integer = 0     'total input pdf file count
    Dim f As Integer = 0    'pointer to current input pdf file
    Dim fileName As String
    Dim reader As iTextSharp.text.pdf.PdfReader = Nothing
    Dim pageCount As Integer = 0
    Dim pdfDoc As iTextSharp.text.Document = Nothing    'the output pdf document
    Dim writer As PdfWriter = Nothing
    Dim cb As PdfContentByte = Nothing

    Dim page As PdfImportedPage = Nothing
    Dim rotation As Integer = 0

    Try
        pdfCount = pdfFiles.Length
        If pdfCount > 1 Then
            'Open the 1st item in the array PDFFiles
            fileName = pdfFiles(f)
            reader = New iTextSharp.text.pdf.PdfReader(fileName)
            'Get page count
            pageCount = reader.NumberOfPages

            pdfDoc = New iTextSharp.text.Document(reader.GetPageSizeWithRotation(1), 18, 18, 18, 18)

            writer = PdfWriter.GetInstance(pdfDoc, New FileStream(outputPath, FileMode.OpenOrCreate))


            With pdfDoc
                .Open()
            End With
            'Instantiate a PdfContentByte object
            cb = writer.DirectContent
            'Now loop thru the input pdfs
            While f < pdfCount
                'Declare a page counter variable
                Dim i As Integer = 0
                'Loop thru the current input pdf's pages starting at page 1
                While i < pageCount
                    i += 1
                    'Get the input page size
                    pdfDoc.SetPageSize(reader.GetPageSizeWithRotation(i))
                    'Create a new page on the output document
                    pdfDoc.NewPage()
                    'If it is the 1st page, we add bookmarks to the page
                    'Now we get the imported page
                    page = writer.GetImportedPage(reader, i)
                    'Read the imported page's rotation
                    rotation = reader.GetPageRotation(i)
                    'Then add the imported page to the PdfContentByte object as a template based on the page's rotation
                    If rotation = 90 Then
                        cb.AddTemplate(page, 0, -1.0F, 1.0F, 0, 0, reader.GetPageSizeWithRotation(i).Height)
                    ElseIf rotation = 270 Then
                        cb.AddTemplate(page, 0, 1.0F, -1.0F, 0, reader.GetPageSizeWithRotation(i).Width + 60, -30)
                    Else
                        cb.AddTemplate(page, 1.0F, 0, 0, 1.0F, 0, 0)
                    End If
                End While
                'Increment f and read the next input pdf file
                f += 1
                If f < pdfCount Then
                    fileName = pdfFiles(f)
                    reader = New iTextSharp.text.pdf.PdfReader(fileName)
                    pageCount = reader.NumberOfPages
                End If
            End While
            'When all done, we close the document so that the pdfwriter object can write it to the output file
            pdfDoc.Close()
            result = True
        End If
    Catch ex As Exception
        Return False
    End Try
    Return result
End Function
    • FYI: es ist Möglich, Duplikat der Ein Element mit dem gleichen Schlüssel wurde bereits Hinzugefügt dictionary.
    • es funktioniert wie ein Charme @Sean Wessell. Vielen Dank für solch eine große Hilfe
    • und wieder bin ich hier nicht in der Lage zu verstehen, die co-relation für duplicacy
    • Down-voting, weil Sie irreführend sind Menschen zu denken, dies ist der Weg, um Dokumente Zusammenführen (siehe diese Frage. Wie bereits in den Kapitel 6 in meinem Buch, Sie sind wegwerfen aller Interaktivität. Wenn die original-Dateien enthalten links, Anmerkungen,... werden Sie alle verschwunden sein, nach der Zusammenführung. Wegen Antworten wie deiner, viele Entwickler, die das falsche tun (und es ist so anstrengend für uns, um zu erklären, immer und immer wieder, was Sie falsch machen).
    • Es hängt von den Anforderungen des merge-system. Wenn die PDF-Dateien enthalten keine interaktiven Inhalte, links, Anmerkungen, etc., oder diese Elemente sind unwichtig im Kontext des Dokuments, dann, wenn in diesem code gelingt das Zusammenführen mehrerer PDF-Dateien, es ist eine akzeptable Antwort. Das einzige, was ich würde vorschlagen, für die Verbesserung der Antwort wäre zu schweigen von der Möglichkeit/Wahrscheinlichkeit, mit der Funktionen-Verlust mit dieser Methode.
    • Wenn Sie hinzufügen, die Wahrscheinlichkeit, dass der Verlust der Funktionalität, auch erwähnen, dass jede Seite Hinzugefügt, um das neue Dokument als Form XObject. Wenn dieser Vorgang wiederholt sich viele Male (das ist der Fall in einige Projekte, die ich geholfen debug), werden Sie am Ende mit XObjects bezogen auf XObjects bezogen auf XObjects. Zu viele verschachtelte XObjects kann die Ursache von performance-Problemen und sogar zu schlagen Umsetzung Grenzen der Zuschauer, die den Betrachter scheitern, um das Dokument zu Rendern oder sogar Abstürzen.
    • Absolut. Die Antwort sollte gehören beliebiger mögliche negative Nebenwirkungen führen könnte, obwohl wir alle wissen, dass wir nicht immer das bekommen (oder wissen) solche Probleme aufgeführt. Ich habe gelesen, ein Teil der Stichprobe Kapitel, die du verlinkt hast, und, wie ich bin interessiert an dem Thema, wie man am besten Zusammenführen von PDF-Dateien, werde ich wohl genauer ein. Allerdings, wenn der obige code funktioniert für ein "proof of concept" Lösung, werde ich wahrscheinlich dort anfangen.

    InformationsquelleAutor Sean Wessell
  2. 1

    den code, der war richtig markiert nicht schließen Sie alle Datei-streams, also die Dateien geöffnet bleiben innerhalb der app, und Sie werden nicht in der Lage zu löschen Sie nicht verwendete PDF-Dateien in Ihrem Projekt

    Dies ist eine bessere Lösung:

    Public Sub MergePDFFiles(ByVal outPutPDF As String) 

    Dim StartPath As String = FileArray(0) ' this is a List Array declared Globally
    Dim document = New Document()
    Dim outFile = Path.Combine(outPutPDF)' The outPutPDF varable is passed from another sub this is the output path
    Dim writer = New PdfCopy(document, New FileStream(outFile, FileMode.Create))

    Try

        document.Open()
        For Each fileName As String In FileArray

            Dim reader = New PdfReader(Path.Combine(StartPath, fileName))

            For i As Integer = 1 To reader.NumberOfPages

                Dim page = writer.GetImportedPage(reader, i)
                writer.AddPage(page)

            Next i

            reader.Close()

        Next

        writer.Close()
        document.Close()

    Catch ex As Exception
        'catch a Exception if needed

    Finally

        writer.Close()
        document.Close()

    End Try


End Sub
    • ein Schließen der Document implizit schließt die PdfWriter es nicht sinnvoll, zu schließen, der Verfasser ausdrücklich. b Wenn Sie in der Nähe der Document im Finally block sowieso, es macht keinen Sinn, auch schließen es in der Try block. c Wenn Sie wollen, stellen Sie sicher, dass in der Nähe alles, warum gehst du nicht explizit schließen Sie die Datei-stream? Man kann nach alles zu deaktivieren, das implizite schließen der Datei stream in den Brenner...
    InformationsquelleAutor Gerald Leesmann
  3. 0

    Ich weiß, ich bin ziemlich spät zu der party, aber nach dem Lesen der Kommentare von @BrunoLowagie, ich wollte sehen, ob ich könnte etwas selber zusammen verwendet, die Beispiele aus seinem verlinkten Beispiel-Kapitel. Es ist wahrscheinlich übertrieben, aber ich habe einige code, der Zusammenführung mehrerer PDF-Dateien in einer einzigen Datei, die ich gepostet auf der Code-Review SE Website (die post, VB.NET - Fehlerbehandlung in einer Generischen Klasse für PDF Merge, enthält die Klasse code). Es führt nur PDF-Dateien jetzt, aber ich bin der Planung auf das hinzufügen von Methoden, um zusätzliche Funktionalität später.

    Den "master" - Methode (gegen Ende des Class - block, in dem verlinkten post, und auch unten geschrieben für Referenz) übernimmt die eigentliche Zusammenführung der PDF-Dateien, aber die mehrere überladungen bieten eine Reihe von Optionen für, wie definieren Sie die Liste der Originaldateien. Bisher habe ich die folgenden features:

    • Die Methoden geben ein System.IO.FileInfo Objekt, wenn der merge erfolgreich ist.
    • Bieten eine System.IO.DirectoryInfo Objekt oder eine System.String identifizieren Sie einen Pfad und es sammelt alle PDF-Dateien in diesem Verzeichnis (einschließlich Unterverzeichnisse (falls angegeben) zu fusionieren.
    • Bieten eine List(Of System.String) oder eine List(Of System.IO.FileInfo) Angabe der PDFs, die Sie Zusammenführen möchten.
    • Ermitteln, wie die PDF-Dokumente müssen sortiert werden, bevor der merge (besonders nützlich, wenn Sie verwenden Sie eine der MergeAll Methoden, um alle PDF-Dateien in einem Verzeichnis).
    • Wenn die angegebene Ausgabe als PDF-Datei bereits vorhanden können Sie angeben, ob Sie diese überschreiben wollen. (Ich bin erwägt, die "Fähigkeit" zum automatischen einstellen der Ausgangs-PDF-Datei Namen, wenn es bereits vorhanden ist).
    • Warning und Error Eigenschaften bieten eine Möglichkeit, feedback zu bekommen und in die aufrufende Methode, ob oder ob nicht die Zusammenführung ist erfolgreich.

    Sobald der code ist im Ort, es kann z.B. so verwendet werden:

    Dim PDFDir As New IO.DirectoryInfo("C:\Test Data\PDF\")
Dim ResultFile As IO.FileInfo = Nothing
Dim Merger As New PDFManipulator

ResultFile = Merger.MergeAll(PDFDir, "C:\Test Data\PDF\Merged.pdf", True, PDFManipulator.PDFMergeSortOrder.FileName, True)

    Hier ist der "master" - Methode. Wie ich schon sagte, es ist wahrscheinlich übertrieben (und ich bin noch tweaking es einige), aber ich wollte mein bestes tun, um zu versuchen, um es so effektiv wie möglich. Natürlich, es erfordert einen Verweis auf die itextsharp.dll für den Zugriff auf die Funktionen der Bibliothek.

    Habe ich auskommentiert, die Verweise auf die Error und Warning Eigenschaften der Klasse für diese post, um zu helfen reduzieren Verwechslungen.

    Public Function Merge(ByVal PDFFiles As List(Of System.IO.FileInfo), ByVal OutputFileName As String, ByVal OverwriteExistingPDF As Boolean, ByVal SortOrder As PDFMergeSortOrder) As System.IO.FileInfo
    Dim ResultFile As System.IO.FileInfo = Nothing
    Dim ContinueMerge As Boolean = True

    If OverwriteExistingPDF Then
        If System.IO.File.Exists(OutputFileName) Then
            Try
                System.IO.File.Delete(OutputFileName)
            Catch ex As Exception
                ContinueMerge = False

                'If Errors Is Nothing Then
                '    Errors = New List(Of String)
                'End If

                'Errors.Add("Could not delete existing output file.")

                Throw
            End Try
        End If
    End If

    If ContinueMerge Then
        Dim OutputPDF As iTextSharp.text.Document = Nothing
        Dim Copier As iTextSharp.text.pdf.PdfCopy = Nothing
        Dim PDFStream As System.IO.FileStream = Nothing
        Dim SortedList As New List(Of System.IO.FileInfo)

        Try
            Select Case SortOrder
                Case PDFMergeSortOrder.Original
                    SortedList = PDFFiles
                Case PDFMergeSortOrder.FileDate
                    SortedList = PDFFiles.OrderBy(Function(f As System.IO.FileInfo) f.LastWriteTime).ToList
                Case PDFMergeSortOrder.FileName
                    SortedList = PDFFiles.OrderBy(Function(f As System.IO.FileInfo) f.Name).ToList
                Case PDFMergeSortOrder.FileNameWithDirectory
                    SortedList = PDFFiles.OrderBy(Function(f As System.IO.FileInfo) f.FullName).ToList
            End Select

            If Not IO.Directory.Exists(New IO.FileInfo(OutputFileName).DirectoryName) Then
                Try
                    IO.Directory.CreateDirectory(New IO.FileInfo(OutputFileName).DirectoryName)
                Catch ex As Exception
                    ContinueMerge = False

                    'If Errors Is Nothing Then
                    '    Errors = New List(Of String)
                    'End If

                    'Errors.Add("Could not create output directory.")

                    Throw
                End Try
            End If

            If ContinueMerge Then
                OutputPDF = New iTextSharp.text.Document
                PDFStream = New System.IO.FileStream(OutputFileName, System.IO.FileMode.OpenOrCreate)
                Copier = New iTextSharp.text.pdf.PdfCopy(OutputPDF, PDFStream)

                OutputPDF.Open()

                For Each PDF As System.IO.FileInfo In SortedList
                    If ContinueMerge Then
                        Dim InputReader As iTextSharp.text.pdf.PdfReader = Nothing

                        Try
                            InputReader = New iTextSharp.text.pdf.PdfReader(PDF.FullName)

                            For page As Integer = 1 To InputReader.NumberOfPages
                                Copier.AddPage(Copier.GetImportedPage(InputReader, page))
                            Next page

                            If InputReader.IsRebuilt Then
                                'If Warnings Is Nothing Then
                                '    Warnings = New List(Of String)
                                'End If

                                'Warnings.Add("Damaged PDF: " & PDF.FullName & " repaired and successfully merged into output file.")
                            End If
                        Catch InvalidEx As iTextSharp.text.exceptions.InvalidPdfException
                            'Skip this file
                            'If Errors Is Nothing Then
                            '    Errors = New List(Of String)
                            'End If

                            'Errors.Add("Invalid PDF: " & PDF.FullName & " not merged into output file.")
                        Catch FormatEx As iTextSharp.text.pdf.BadPdfFormatException
                            'Skip this file
                            'If Errors Is Nothing Then
                            '    Errors = New List(Of String)
                            'End If

                            'Errors.Add("Bad PDF Format: " & PDF.FullName & " not merged into output file.")
                        Catch PassworddEx As iTextSharp.text.exceptions.BadPasswordException
                            'Skip this file
                            'If Errors Is Nothing Then
                            '    Errors = New List(Of String)
                            'End If

                            'Errors.Add("Password-protected PDF: " & PDF.FullName & " not merged into output file.")
                        Catch OtherEx As Exception
                            ContinueMerge = False
                        Finally
                            If Not InputReader Is Nothing Then
                                InputReader.Close()
                                InputReader.Dispose()
                            End If
                        End Try
                    End If
                Next PDF
            End If
        Catch ex As iTextSharp.text.pdf.PdfException
            ResultFile = Nothing
            ContinueMerge = False

            'If Errors Is Nothing Then
            '    Errors = New List(Of String)
            'End If

            'Errors.Add("iTextSharp Error: " & ex.Message)

            If System.IO.File.Exists(OutputFileName) Then
                If Not OutputPDF Is Nothing Then
                    OutputPDF.Close()
                    OutputPDF.Dispose()
                End If

                If Not PDFStream Is Nothing Then
                    PDFStream.Close()
                    PDFStream.Dispose()
                End If

                If Not Copier Is Nothing Then
                    Copier.Close()
                    Copier.Dispose()
                End If

                System.IO.File.Delete(OutputFileName)
            End If

            Throw
        Catch other As Exception
            ResultFile = Nothing
            ContinueMerge = False

            'If Errors Is Nothing Then
            '    Errors = New List(Of String)
            'End If

            'Errors.Add("General Error: " & other.Message)

            If System.IO.File.Exists(OutputFileName) Then
                If Not OutputPDF Is Nothing Then
                    OutputPDF.Close()
                    OutputPDF.Dispose()
                End If

                If Not PDFStream Is Nothing Then
                    PDFStream.Close()
                    PDFStream.Dispose()
                End If

                If Not Copier Is Nothing Then
                    Copier.Close()
                    Copier.Dispose()
                End If

                System.IO.File.Delete(OutputFileName)
            End If

            Throw
        Finally
            If Not OutputPDF Is Nothing Then
                OutputPDF.Close()
                OutputPDF.Dispose()
            End If

            If Not PDFStream Is Nothing Then
                PDFStream.Close()
                PDFStream.Dispose()
            End If

            If Not Copier Is Nothing Then
                Copier.Close()
                Copier.Dispose()
            End If

            If System.IO.File.Exists(OutputFileName) Then
                If ContinueMerge Then
                    ResultFile = New System.IO.FileInfo(OutputFileName)

                    If ResultFile.Length <= 0 Then
                        ResultFile = Nothing

                        Try
                            System.IO.File.Delete(OutputFileName)
                        Catch ex As Exception
                            Throw
                        End Try
                    End If
                Else
                    ResultFile = Nothing

                    Try
                        System.IO.File.Delete(OutputFileName)
                    Catch ex As Exception
                        Throw
                    End Try
                End If
            Else
                ResultFile = Nothing
            End If
        End Try
    End If

    Return ResultFile
End Function
    InformationsquelleAutor G_Hosa_Phat
  4. -2

    Einige müssen möglicherweise ändern Sie den code in "writer = PdfWriter.GetInstance(pdfDoc, New FileStream(outputPath, FileMode.OpenOrCreate))" als iTextSharp unterstützen möglicherweise nicht

    Änderung:

    Dim fs As IO.FileStream = New IO.FileStream(outputPath, IO.FileMode.Create)

writer = iTextSharp.text.pdf.PdfWriter.GetInstance(pdfDoc, fs)
    InformationsquelleAutor Coder999
Schreibe einen Kommentar