VBA Konvertieren und kombinieren von Datum und Zeit

Ich bin neu in VBA und arbeite ein Sie ein makro, das mir helfen wird, mich verwandeln, rufen Sie Datensätze in etwas, das nützlich für die Analyse.

Spalte E enthält das Datum des Anrufs, die formatiert ist, in der Form JJJJMMTT. Ich brauche, um zu konvertieren, um MM/DD/YYYY. (d.h. 20140101 konvertieren 1/1/2014)

Spalte F enthält die Zeit des Anrufs, die formatiert ist HHMMSS oder HMMSS je nachdem, ob die Stunde hat zwei Ziffern oder einen. Ich brauche zum konvertieren in HH:MM:SS (also 130101 oder 90101, die konvertieren muss um 13:01:01 und 9:01:01, beziehungsweise). Da die Stunde fehlt die zehnerstellen, wenn der Wert unter zehn, (unten) ich habe eine "0" am Anfang der Wert-so kann ich mit der Datum-Funktion.

Ich derzeit geben Sie die folgende Formel in die Spalte K und autofill bis zum Ende der Reihe:

=DATUM(LINKS(E2,4),MID(E2,5,2), (E2,2))+ZEIT(LINKS(WENN(LEN(F2)=5, 0&F2, F2),2),MID(IF(LEN(F2)=5, 0&F2, F2),3,2),RECHTS(WENN(LEN(F2)=5, 0&F2, F2),2))

Die Formel ergibt einen Wert wie "1/1/2013 13:01:01".

Kann mir jemand helfen, Schreibe den VBA-code, um diesen Prozess zu automatisieren?

Danke.

InformationsquelleAutor blahblahblah | 2014-01-09
  1. 4

    Erstellt separate UDFs für diese. Fügen Sie den folgenden in ein Modul.

    Function MorphDate(DateRng As Range)

    Dim DateStr As String: DateStr = DateRng.Value
    Dim Yr As String, Mt As String, Dy As String

    Yr = Left(DateStr, 4)
    Mt = Mid(DateStr, 5, 2)
    Dy = Right(DateStr, 2)

    MorphDate = Format(DateSerial(Yr, Mt, Dy), "m/dd/yyyy")

End Function

Function MorphTime(TimeRng As Range)

    Dim TimeStr As String: TimeStr = TimeRng.Value
    Dim Hh As String, Mm As String, Ss As String

    If Len(TimeStr) = 5 Then TimeStr = "0" & TimeStr

    Hh = Left(TimeStr, 2)
    Mm = Mid(TimeStr, 3, 2)
    Ss = Right(TimeStr, 2)

    MorphTime = Format(TimeSerial(Hh, Mm, Ss), "hh:mm:ss")
End Function

Function MorphDateTime(DateRng As Range, TimeRng As Range)

    Application.Volatile
    MorphDateTime = CDate(MorphDate(DateRng)) + CDate(MorphTime(TimeRng))

End Function

    Jetzt können Sie die Formeln MorphDate um das Datum zu ändern, MorphTime um die Zeit zu ändern, und MorphDateTime für eine Kombination von beiden.

    Screenshot:

    VBA Konvertieren und kombinieren von Datum und Zeit

    Lassen Sie uns wissen, ob das hilft.

    EDIT:

    Wenn Sie es verwenden möchten, im Unterprogramm, fügen Sie den folgenden code in das Modul:

    Sub MorphingTime()

    Dim DateRng As Range, Cell As Range
    Set DateRng = Range("E2:E100") '--Modify as needed.

    For Each Cell in DateRng
        Range("K" & Cell.Row).Value = MorphDateTime(Cell, Cell.Offset(0,1))
    Next Cell

End Sub

    Hoffe, das hilft.

    • Vielen, vielen Dank! Dies funktioniert Super. Als follow-up, wenn ich wollte, integrieren diese in eine Sub-routine, wie würde ich es tun? Der Bereich für Datum E2 bis zum Ende und die Zeit ist F2 bis zum Ende.
    • Überprüfen Sie den aktualisierten code. 🙂
    • Perfekt! Danke nochmal für Eure Hilfe. Ich bin eine Menge zu lernen!
    • Herzlich markieren der Antwort als angenommen, wenn diese Lösung dir geholfen. Danke. 🙂
    InformationsquelleAutor Jerome Montino
Schreibe einen Kommentar