VBA-Makro funktioniert nicht in mehrere Arbeitsblätter innerhalb der Arbeitsmappe

Arbeite ich für ein Kommunikations-Unternehmen, und ich bin versucht, code auszuführen, der auf ein Excel-Dokument kompiliert Daten über Probleme Berichte über die Produkte.

Den Makros, die ich ausführen möchten, erzeugen ein Risiko spider-Diagramm für jeden Datensatz, wenn Sie auf über die Spalten (Monate).

Das makro habe ich funktioniert in dem ersten Arbeitsblatt, aber ich kann nicht ankommen es zu wirken in dem zweiten Arbeitsblatt, wenn es im wesentlichen die gleichen Daten.

Ich würde schätzen jede Hilfe, die ich bekommen kann!!

Dies ist der code den ich habe:

Private Sub Worksheet_Calculate()

    Call UpdateTotalRatings

End Sub

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Address = "$B$14" Then
        Call UpdateTotalRatings
    End If
End Sub

Private Sub UpdateTotalRatings()

Dim Cell As Range
Dim LastCol As String

    Application.ScreenUpdating = False

    ' Ensure number of colours is valid (must be 3 or 6).
    If ActiveSheet.Range("B14").Value <> 3 And _
       ActiveSheet.Range("B14").Value <> 6 Then
        ActiveSheet.Range("B14").Value = 3
    End If

    ' Determine right-most column.
     LastCol = Mid(ActiveSheet.Cells.SpecialCells(xlCellTypeLastCell).Address, 2, 1)

    For Each Cell In Range("B13:" & LastCol & "13")
        If IsNumeric(Cell.Value) Then
            Cell.Interior.Color = ThisWorkbook.GetColour(Cell.Value, _
            ActiveSheet.Range("B14").Value)
        End If
    Next
    Application.ScreenUpdating = True

 End Sub

Haben Sie diese Ereignis-Handler in jedem Arbeitsblatt code-Modul? Ist UpdateTotal Bewertungen in einem normalen Modul?

InformationsquelleAutor user1472363 | 2012-06-21

Wenn du deinen code (mit einigen änderungen) in das Modul "DieseArbeitsmappe", es wird auf jedes Blatt der Arbeitsmappe.

Private Sub Workbook_SheetCalculate(ByVal Sh As Object)

    UpdateTotalRankings Sh

End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)

    If Target.Address = "$B$14" Then
        UpdateTotalRankings Sh
    End If

End Sub

Private Sub UpdateTotalRankings(Sh As Object)

    Dim rCell As Range
    Dim lLastCol As Long

    Application.ScreenUpdating = False

    ' Ensure number of colours is valid (must be 3 or 6).
    If Sh.Range("B14").Value <> 3 And _
        Sh.Range("B14").Value <> 6 Then

        Sh.Range("B14").Value = 3
    End If

    ' Determine right-most column.
    lLastCol = Sh.Cells.SpecialCells(xlCellTypeLastCell).Column

    For Each rCell In Sh.Range("B13").Resize(1, lLastCol - 1).Cells
        If IsNumeric(rCell.Value) Then
            rCell.Interior.Color = Me.GetColour(rCell.Value, _
                Sh.Range("B14").Value)
        End If
    Next rCell

    Application.ScreenUpdating = True

End Sub

Wenn Sie Blätter, die Sie nicht Bearbeiten möchten, können Sie den Sh-argument. Vielleicht ist es auf der Grundlage der Blatt-name

If Sh.Name Like "Report_*" Then

nur Blätter, deren Namen beginnen mit Report_. Oder

If Sh.Range("A14").Value = "Input" Then

zur überprüfung einer Zelle (wie A14), die einen bestimmten Wert zu identifizieren, die Blätter zu verarbeiten.

InformationsquelleAutor Dick Kusleika

0

Diesem Verfahren Worksheet_Change ist eine Ereignis-Prozedur.

Es soll (und kann) nur in dem entsprechenden Worksheet-Modul. Das ist, warum Ihr code funktioniert nicht für die anderen Blätter.

Um es zu bekommen, müssen Sie zu :
- verstehen, was Sie beabsichtigen zu tun mit VBA
- rufen Sie die Ereignis-Prozedur auf jedem Arbeitsblatt Modul, wo dies notwendig ist
- verwenden Sie eine main-Prozedur, die Sie speichern in eine "code" - standard-Modul (kann mich nicht erinnern, den richtigen Namen hier)
- range-Argumente übergeben werden, die Target von der Prozedur (oder zumindest die richtige Arbeitsblatt), um die main-Prozedur
----- EDIT --------

Zuerst ändern
```
Private Sub UpdateTotalRatings()
```
zu
```
Sub UpdateTotalRatings(Optional ByVal Target As Range)
```
Dann, verschieben Sie alle Sub UpdateTotalRatings(Optional ByVal Target As Range) zu einem Modul

Und jeder Arbeitsblatt Modul hinzufügen:
```
Private Sub Worksheet_Calculate()

    Call UpdateTotalRatings

End Sub

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Address = "$B$14" Then
        Call UpdateTotalRatings(Target)
    End If
End Sub
```
Wie rufe ich die Ereignis-Prozedur auf jedem Arbeitsblatt, wo ich es brauche?
Müssen Sie den Worksheet_Change auf jedes Arbeitsblatt Modul
Ich bin immer noch sehr verwirrt, sorry! In meinem VBA-code für das Arbeitsblatt brauchen diese meacro zu arbeiten ich habe genau das, was code ist oben... Also brauche ich eine andere hinzufügen Worksheet_Change?
Ich habe bearbeitet meine post, klarer zu werden. Schauen

InformationsquelleAutor JMax

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.